Exemples de formules de lien d'image
Visualisez la priorité de la requête, l'ancienneté de la requête, le statut du projet, les scores et les scores avec des images telles que des indicateurs, des indicateurs colorés, des étoiles et des barres proportionnelles.
Éditions requises
| Disponible avec : Salesforce Classic et Lightning Experience |
| Disponible avec : Essentials Edition, Group Edition, Professional Edition, Enterprise Edition, Performance Edition, Unlimited Edition et Developer Edition |
Pour plus d'informations sur l'utilisation des fonctions contenues dans ces exemples, consultez Opérateurs et fonctions de formule par contexte.
Yahoo! Instant Messenger™
Cette formule affiche une image indiquant si un contact ou un utilisateur est connecté à Yahoo! Messenger. Un clic sur l'image ouvre la fenêtre Yahoo! Instant Messenger. Cette formule utilise un champ de texte personnalisé appelé Nom Yahoo pour stocker le Yahoo! du contact ou de l'utilisateur. ID.
IF(ISBLANK(Yahoo_Name__c),"", HYPERLINK("ymsgr:sendIM?" & Yahoo_Name__c,
IMAGE("http://opi.yahoo.com/online?u=" & Yahoo_Name__c & "&m=g&t=0", " ")))Indicateurs de priorité de requête
Cette formule affiche une image d'indicateur vert, jaune ou rouge pour indiquer un priorité de la requête.
IMAGE(
CASE( Priority,
"Low", "/img/samples/flag_green.gif",
"Medium", "/img/samples/flag_yellow.gif",
"High", "/img/samples/flag_red.gif",
"/s.gif"),
"Priority Flag")
Couleurs d'ancienneté des requêtes
Cette formule affiche une image rouge, jaune ou vert de 30 x 30 pixels en fonction de la valeur d'un champ numérique personnalisé Ancienneté de la requête.
IF( Case_Age__c > 20,
IMAGE("/img/samples/color_red.gif", "red", 30, 30),
IF( Case_Age__c > 10,
IMAGE("/img/samples/color_yellow.gif", "yellow", 30, 30),
IMAGE("/img/samples/color_green.gif", "green", 30, 30)
))Indicateurs de statut
Cette formule affiche des images de feu vert, jaune ou rouge pour indiquer le statut, en utilisant un champ de liste de sélection personnalisé appelé Statut du projet. Utilisez cette formule dans des vues de liste et des rapports pour créer une vue de tableau de bord « Récapitulatif du statut ».
IMAGE(
CASE(Project_Status__c,
"Green", "/img/samples/light_green.gif",
"Yellow", "/img/samples/light_yellow.gif",
"Red", "/img/samples/light_red.gif",
"/s.gif"),
"status color")
Étoiles d'évaluation
Cette formule affiche une série composée d'une à cinq étoiles pour indiquer une évaluation ou un score.
IMAGE(
CASE(Rating__c,
"1", "/img/samples/stars_100.gif",
"2", "/img/samples/stars_200.gif",
"3", "/img/samples/stars_300.gif",
"4", "/img/samples/stars_400.gif",
"5", "/img/samples/stars_500.gif",
"/img/samples/stars_000.gif"),
"rating")Consumer Reports™ : style des cercles de couleur d'évaluation
Cette formule affiche un cercle de couleur pour indiquer une évaluation sur une échelle de un à cinq, sur laquelle rouge continu correspond à un, moitié rouge correspond à deux, contour noir correspond à trois, moitié noir correspond à quatre et noir continu correspond à cinq.
IMAGE(
CASE(Rating__c,
"1", "/img/samples/rating1.gif",
"2", "/img/samples/rating2.gif",
"3", "/img/samples/rating3.gif",
"4", "/img/samples/rating4.gif",
"5", "/img/samples/rating5.gif",
"/s.gif"),
"rating")
Barres horizontales de score
Cette formule affiche une barre de couleur horizontale (verte sur fond blanc) d'une longueur proportionnelle à un score numérique. Dans cet exemple, la longueur maximale de la barre est de 200 pixels.
IMAGE("/img/samples/color_green.gif", "green", 15, Industry_Score__c * 2) &
IMAGE("/s.gif", "white", 15,
200 - (Industry_Score__c * 2))
