How to use recursion in DataWeave

%dw 1.0
%output application/json

%var data = {
    "VersionNo": "1.1",
    "Program": "points program xx",
    "Items": [
         {
            "ID": "456",
            "Field1": 5,
            "Field2": "xy"
         },
         {
            "ID": "123",
            "Field1": 2,
            "Field2": "yz"
        }
    ]
}

%function formatAllValues (input, formatter)
    input match {
        :array -> input map (value,index) -> formatAllValues(value, formatter),
        :object -> input mapObject (value,key) -> {
            (key) : formatAllValues (value, formatter)
        },
        :string -> formatter(input),
        default -> input
    }

---

formatAllValues(data, (str) -> upper str)

• The formatAllValues function receives as parameters a data structure and a lambda
• It uses the the match operator to decide between the possible types of the received structure
• If the type is an array, it calls recursively to each element of the array
• If it is an object, it calls recursively to each property of the object
• For the base cases, if the data is a string it applies the received lambda, otherwise it returns the received value.