1단계:

1. 데이터 패널에서 마우스 오른쪽 단추를 클릭하고 매개 변수 만들기를 선택합니다. 
2. 매개 변수 이름을 Day Open Hour로 지정하고 다음 값을 입력한 다음 확인을 클릭합니다. 
   • 데이터 유형: 정수
   • 허용 가능한 값: 범위
   • 최소값: 1 
   • 최대값: 12 
   • 단계 크기: 1 
3. 데이터 패널에서 마우스 오른쪽 단추를 클릭하고 매개 변수 만들기를 선택합니다.
4. 매개 변수 이름을 Day Open Minute로 지정하고 다음 값을 입력한 다음 확인을 클릭합니다. 
   • 데이터 유형: 문자열 
   • 허용 가능한 값: 목록 
   • 값 목록: "00", "15", "30" 및 "45" 
5. Day Close Hour 및 Day Close Minute을 사용하여 위 두 단계를 반복합니다. 

2단계:

1. 분석 > 계산된 필드 만들기를 선택합니다.
2. 필드 이름을 "Action Start: Rounded"로 지정하고 다음 계산을 입력한 다음 확인을 클릭합니다. 
    

   IF (DATEPART('hour', [Action Start]) * 60) + DATEPART('minute', [Action Start])  > (60 * (12 + [Day Close Hour]) ) + INT([Day Close Minute])
   THEN
   // created after End of Day so round to start of next business day
   DATEADD('minute', (60 * (24 + [Day Open Hour])) + INT([Day Open Minute]), DATETRUNC('day',[Action Start])) 
   ELSEIF
   (DATEPART('hour', [Action Start]) * 60) + DATEPART('minute', [Action Start])  < (60 * [Day Open Hour]) + INT([Day Open Minute])
   THEN
   // created before Start of Day so round to start of business day
   DATEADD('minute', (60 * [Day Open Hour]) + INT([Day Open Minute]), DATETRUNC('day',[Action Start])) 
   ELSE
   [Action Start]
   END

3. 분석 > 계산된 필드 만들기를 선택하고 필드 이름을 "Action Start: Round to Weekday"로 지정한 다음 반올림된 새 타임스탬프가 주말에 속하는지 여부를 확인하는 다음과 같은 계산을 입력합니다.

   IF DATENAME('weekday',[Action Start : Rounded]) = "Saturday" 
   THEN 
   // move to start of day monday by adding two days (48 hrs) and the monday morning hours
   DATEADD('minute', (60 * (48 + [Day Open Hour])) + INT([Day Open Minute]), DATETRUNC('day', [Action Start : Rounded]))
   ELSEIF DATENAME('weekday',[Action Start : Rounded]) = "Sunday" 
   THEN
   // move to start of day monday by adding a day (24 hrs) and the monday morning hours
   DATEADD('minute', (60 * (24 + [Day Open Hour])) + INT([Day Open Minute]), DATETRUNC('day', [Action Start : Rounded]))
   ELSE 
   [Action Start : Rounded]
   END

4. [Action End]에 대해 위 두 계산을 반복합니다.

3단계:

1. 아래 계산을 만들고 이름을 "Start: Time to end of day"로 지정합니다.

   DATEDIFF(  'minute',
       [Action Start: Round to Weekdays], 
       DATEADD('minute', (60 * (12 + [Day Close Hour])) + INT([Day Close Minute]), DATETRUNC('day',[Action Start: Round to Weekdays]))
   )

2. Day Open Hour 및 Minute을 사용하여 위 계산을 반복하고 이름을 "End: Time from Start Of Day"로 지정합니다.
3. 최종 결과를 쉽게 계산할 수 있도록 분, 일, 및 주에 대해 하나씩 세 개의 DATEDIFF 계산을 만듭니다.
   "DateDiff Days"

   DATEDIFF('day', [Action Start: Round to Weekdays], [Action End : Round to Weekdays])

   "DateDiff minutes"

   DATEDIFF('minute', [Action Start: Round to Weekdays], [Action End : Round to Weekdays])

   "DateDiff weeks"

   DATEDIFF('week', [Action Start: Round to Weekdays], [Action End : Round to Weekdays])

4. 근무일당 분 수를 추적하는 계산을 만들고 이름을 "minutes per workday"라고 지정합니다. 

   (60 * (12 + [Day Close Hour (pm)] - [Day Open Hour (am)]) + INT([Day Close Minute (pm)]) - 
   INT([Day Open Minute (am)]))

5. 모든 계산을 하나로 묶어 최종 계산 하나를 만듭니다.
    

   IF DATETRUNC('day', [Action Start: Round to Weekdays]) = DATETRUNC('day', [Action End : Round to Weekdays])
   THEN
   // the same day so just return the minutes between the two times on the same day
   [DateDiff minutes]
   ELSEIF DATETRUNC('week', [Action Start: Round to Weekdays]) = DATETRUNC('week', [Action End : Round to Weekdays])
   THEN
   // the two days are in the same week, so add the time on the created day, the time on the end day, plus a full day for each day between
   (([DateDiff days] - 1) * [Minutes per workday] ) + [Start: Time to end of day] + [End : Time from start of day ]
   ELSE
   // the days are in two different weeks, so get the same calc as above, and subtract the weekends between
   // weekends between would be datediff weeks * 2 * work minutes per day
   (([DateDiff days] - 1 - ([DateDiff weeks] * 2)) * [Minutes per workday] ) + [Start: Time to end of day] + [End: Time from start of day ]
   END