Grounding with Apex Merge Fields

Method Input

The method’s input parameter must have a List<Request> type. The Request class defines an InvocableVariable member for each input defined by the prompt template type. All inputs are passed from the prompt template into the invocable method. Only the first element in the list has data.

When present, the CapabilityType for a prompt template type acts as an interface for the Request input class. Each CapabilityType requires that the Request class defines specific InvocableVariable members. For example, the field generation CapabilityType requires that you define a RelatedEntity member variable in Request. If there are additional objects defined in the prompt template, an associated InvocableVariable member must be defined by using the exact spelling and case sensitivity. In this example, the prompt template defined Account as the object that the template is updating.

public class Request {
                @InvocableVariable
                public Account RelatedEntity;
        }

Note If you change the inputs for a flow or Apex class that’s used as a resource in a prompt template, the prompt template no longer works and you can’t save new versions of the prompt template. See this known issue.

Method Output

The method output has a List<Response> type containing a single string member named Prompt that’s annotated with InvocableVariable. For details, see the Apex Developer Guide.

Example Apex Class

public class ApexPromptTemplateExample1 {

    // At least one method must be annotated with InvocableMethod.
    // No CapabilityType is specified (Flex is retired; for a typed template
    // such as Sales Email or Field Generation, add e.g.
    // @InvocableMethod(CapabilityType='PromptTemplateType://einstein_gpt__salesEmail')).
    @InvocableMethod
    public static List<Response> getPrompt(List<Request> requests) {
        // Only the first element in the list has data.
        Request input = requests[0];

        List<Response> responses = new List<Response>();
        Response output = new Response();
        responses.add(output);

        // Build the prompt string returned to the template.
        output.Prompt = 'generate a summary using the following info:';
        // account_1 matches the API Name of the input in the prompt template.
        output.Prompt += '\nAccount 1: ' + input.account_1.Name;
        output.Prompt += '\nAccount 2: ' + input.account_2.Name;
        output.Prompt += '\nCase Number: ' + input.case_1.CaseNumber;

        return responses;
    }

    // Method Input: List<Request>. Define one InvocableVariable per template input.
    // The type and API Name of every variable must match the template exactly
    // (spelling and case sensitivity).
    public class Request {
        @InvocableVariable(required=true)
        public Account account_1;
        @InvocableVariable(required=true)
        public Account account_2;
        @InvocableVariable(required=true)
        public Case case_1;
    }

    // Method Output: List<Response> with a single String member named Prompt
    // annotated with InvocableVariable.
    public class Response {
        @InvocableVariable
        public String Prompt;
    }
}

Add Apex Resource to a Prompt Template

In the Prompt Template Workspace, add an Apex class to a prompt template by clicking the Resource field in the Prompt section and selecting Apex.

Note If you open the Developer Console before you preview a prompt template that uses Apex, you can see debug statements in the Developer Console. For more information, see Working with Logs in the Developer Console and debug(msg) in the Apex Developer Guide.

To use Apex in Prompt Builder, see:

• Add Apex Merge Fields to a Sales Email Prompt Template
• Add Apex Merge Fields to a Field Generation Prompt Template
• Add Apex Merge Fields to a Flex Prompt Template