Marketing Cloud Engagement의 데이터 검토

다음은 이 활성화 사용 사례를 기반으로 하는 데이터 확장입니다.

처음 4개의 열은 활성화 유형(SMS)에 따라 필요합니다. FirstName 열은 선택된 직접 특성입니다. 마지막 열에는 하나의 데이터 확장 필드에 JSON 코드 블록으로 서식이 지정된 관련 특성이 포함됩니다. 열 이름 Loyalty_Program_Member는 관련 특성의 기본 DMO의 API 이름을 따라 명명됩니다.

• 프로그램 이름
• 이전 충성도 계층
• 충성도 계층

이러한 특성은 JSON 코드 블록에 제공됩니다.

[
  {
    "program_name": "Premiere Plus",
    "Loyalty_Member_Tier": [
      {
        "previous_loyalty_tier": "Silver",
        "loyalty_tier": "Gold"
      }
    ]
  }
]

이 데이터를 SSJS, AMPscript 또는 GTL로 구문 분석할 수 있습니다. 다음은 SSJS로 구문 분석하는 예입니다.

<script runat="server">
    Platform.Load("core","1");
  
    //Get First Name from Data Extension
    var First_Name = Platform.Recipient.GetAttributeValue("FirstName");
    Variable.SetValue("@First_Name", First_Name);

    //Get and Parse JSON Block from Data Extension
    var JSONblock = Platform.Recipient.GetAttributeValue("Loyalty_Program_Member");
    var JSONObj = Platform.Function.ParseJSON(JSONblock);

    //Read JSON Block variables
    Variable.SetValue("@program_name", JSONObj[0]["program_name"]);
    Variable.SetValue("@loyalty_tier", JSONObj[0]["Loyalty_Member_Tier"][0]["loyalty_tier"]);
</script>

Congrats, %%=v(@First_Name)=%%!! Your %%=v(@program_name)=%% loyalty status level has changed to
%%=v(@loyalty_tier)=%%!

다음은 AMPscript로 구문 분석하는 예입니다.

%%[
var @ProgramRowset, @ProgramRow, @ProgramName, @LoyaltyTierRowset, @LoyaltyTierRow, @LoyaltyTier


/* Query the first JSON object from the related attributes array. */
set @ProgramRowset=BuildRowsetFromJson(Loyalty_Program_Member,"$.[0]", false)


/* Get the program_name value. */
set @ProgramRow=row(@ProgramRowset, 1)
set @ProgramName=field(@ProgramRow, "program_name")


/* Query the first Loyalty_Member_Tier object inside of the first object. */
set @LoyaltyTierRowset=BuildRowsetFromJson(Loyalty_Program_Member,"$.[0]['Loyalty_Member_Tier'][0]", false)


/* Get the loyalty_tier value */
set @LoyaltyTierRow=row(@LoyaltyTierRowset, 1)
set @LoyaltyTier=field(@LoyaltyTierRow, "loyalty_tier")


/* Print the message */
OutputLine(concat("Congrats, ", FirstName, "!! Your ", @ProgramName, " loyalty status level has changed to ", @LoyaltyTier, "!"))
]%%

</script>