Perspectivas de compromiso

A continuación se describe un ejemplo de una acción personalizada para eliminar toda la actividad de un miembro del sitio de Experience Cloud. Esta acción personalizada es excelente para limpiar el sitio tras un ataque de spam.

Cree una extensión de controlador personalizada empleando una clase de Apex y utilícela en su página de Visualforce. La siguiente clase de DeleteAllActivityControllerExtension es un ejemplo de una extensión de controlador personalizada.

public with sharing class DeleteAllActivityControllerExtension {

    private List<Id> ids;
    private String retURL;
    private Database.DeleteResult[] deleteResult = null;
    private Map<String, String> resultMap;
    private String success = 'success';
    private String failure = 'failure';
    
    public DeleteAllActivityControllerExtension(ApexPages.StandardController controller) {
        resultMap = new Map<String, String>();
        /* The IDs you select on the Insights page are stored in a comma separated string of IDs. 
        This string is passed in a parameter called "idsList" */
        String idsList = ApexPages.currentPage().getParameters().get('idsList'); 
        //The return URL to the Insights page is passed in a parameter called "retURL"
        retURL = ApexPages.currentPage().getParameters().get('retURL');
        ids = idsList.split(',');
    }
    
    public PageReference deleteAllActivity() {
        deleteFeedPosts();
        deleteFeedComments();
        //Include these two lines of code to be redirected to the Insights page after you click the action.
        PageReference retPage = new PageReference(retURL);
        retPage.setRedirect(true);
        Integer failureCount = calculateFailureCount();
        Integer successCount = ids.size() - failureCount;
        retPage.getParameters().put(success, String.valueOf(successCount));
        retPage.getParameters().put(failure, String.valueOf(failureCount));
        return retPage;
   }
   
   private void deleteFeedPosts() {
        List<FeedItem> feedItems = [Select Id, CreatedById FROM FeedItem WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedItems, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedItems.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private void deleteFeedComments() {
        List<FeedComment> feedComments = [Select Id, CreatedById FROM FeedComment WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedComments, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedComments.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private Integer calculateFailureCount() {
       Integer failureCount = 0;
       for (String result : resultMap.values()) {
            if (failure == result) {
                failureCount++;
            }
        }
        return failureCount;
   }
   
}

Este código crea un botón Eliminar toda la actividad en su informe de Perspectivas. Este botón elimina todas las publicaciones y comentarios de cualquier miembro seleccionado. Si desea eliminar también todos los mensajes y archivos privados, puede ampliar el código.

Nota

• Este ejemplo de código no incluye comprobaciones de permisos. Esta acción personalizada solo funciona con administradores.
• Los Id. de los elementos que seleccionó en el informe de Perspectivas se pasan a la página de Visualforce empleando el parámetro idsList.

<apex:page standardController="User" 
extensions="DeleteAllActivityControllerExtension" action="{!deleteAllActivity}" 
/>