Approfondimenti per la partecipazione

Segue un esempio di un'azione personalizzata per eliminare tutte le attività di un membro del sito Experience Cloud. Questa azione personalizzata è ideale per ripulire il sito dopo un attacco spam.

Creare un'estensione di controller personalizzata mediante una classe Apex e utilizzarla nella pagina Visualforce. La classe DeleteAllActivityControllerExtension seguente è un esempio di estensione di controller personalizzata.

public with sharing class DeleteAllActivityControllerExtension {

    private List<Id> ids;
    private String retURL;
    private Database.DeleteResult[] deleteResult = null;
    private Map<String, String> resultMap;
    private String success = 'success';
    private String failure = 'failure';
    
    public DeleteAllActivityControllerExtension(ApexPages.StandardController controller) {
        resultMap = new Map<String, String>();
        /* The IDs you select on the Insights page are stored in a comma separated string of IDs. 
        This string is passed in a parameter called "idsList" */
        String idsList = ApexPages.currentPage().getParameters().get('idsList'); 
        //The return URL to the Insights page is passed in a parameter called "retURL"
        retURL = ApexPages.currentPage().getParameters().get('retURL');
        ids = idsList.split(',');
    }
    
    public PageReference deleteAllActivity() {
        deleteFeedPosts();
        deleteFeedComments();
        //Include these two lines of code to be redirected to the Insights page after you click the action.
        PageReference retPage = new PageReference(retURL);
        retPage.setRedirect(true);
        Integer failureCount = calculateFailureCount();
        Integer successCount = ids.size() - failureCount;
        retPage.getParameters().put(success, String.valueOf(successCount));
        retPage.getParameters().put(failure, String.valueOf(failureCount));
        return retPage;
   }
   
   private void deleteFeedPosts() {
        List<FeedItem> feedItems = [Select Id, CreatedById FROM FeedItem WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedItems, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedItems.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private void deleteFeedComments() {
        List<FeedComment> feedComments = [Select Id, CreatedById FROM FeedComment WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedComments, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedComments.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private Integer calculateFailureCount() {
       Integer failureCount = 0;
       for (String result : resultMap.values()) {
            if (failure == result) {
                failureCount++;
            }
        }
        return failureCount;
   }
   
}

Questo codice crea un pulsante Delete All Activity (Elimina tutte le attività) nel rapporto Approfondimenti. Questo pulsante consente di eliminare tutti i post e i commenti di qualsiasi membro selezionato. Se si desidera eliminare anche tutti i messaggi e i file privati, è possibile espandere il codice.

Nota

• Questo esempio di codice non include alcun controllo delle autorizzazioni. Questa azione personalizzata si applica solo agli amministratori.
• Gli ID degli elementi selezionati nel rapporto Approfondimenti vengono passati alla pagina Visualforce utilizzando il parametro idsList.

<apex:page standardController="User" 
extensions="DeleteAllActivityControllerExtension" action="{!deleteAllActivity}" 
/>