Insikter för engagemang

Här är ett exempel på en egen åtgärd som tar bort all aktivitet från en Experience Cloud-webbplatsmedlem. Denna egna åtgärd är bra för att rensa upp i webbplatsen efter en spamattack.

Skapa ett egen kontrolltillägg med hjälp av en Apex-klass och använd den i din Visualforce-sida. Följande DeleteAllActivityControllerExtension är ett exempel på ett eget kontrolltillägg.

public with sharing class DeleteAllActivityControllerExtension {

    private List<Id> ids;
    private String retURL;
    private Database.DeleteResult[] deleteResult = null;
    private Map<String, String> resultMap;
    private String success = 'success';
    private String failure = 'failure';
    
    public DeleteAllActivityControllerExtension(ApexPages.StandardController controller) {
        resultMap = new Map<String, String>();
        /* The IDs you select on the Insights page are stored in a comma separated string of IDs. 
        This string is passed in a parameter called "idsList" */
        String idsList = ApexPages.currentPage().getParameters().get('idsList'); 
        //The return URL to the Insights page is passed in a parameter called "retURL"
        retURL = ApexPages.currentPage().getParameters().get('retURL');
        ids = idsList.split(',');
    }
    
    public PageReference deleteAllActivity() {
        deleteFeedPosts();
        deleteFeedComments();
        //Include these two lines of code to be redirected to the Insights page after you click the action.
        PageReference retPage = new PageReference(retURL);
        retPage.setRedirect(true);
        Integer failureCount = calculateFailureCount();
        Integer successCount = ids.size() - failureCount;
        retPage.getParameters().put(success, String.valueOf(successCount));
        retPage.getParameters().put(failure, String.valueOf(failureCount));
        return retPage;
   }
   
   private void deleteFeedPosts() {
        List<FeedItem> feedItems = [Select Id, CreatedById FROM FeedItem WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedItems, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedItems.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private void deleteFeedComments() {
        List<FeedComment> feedComments = [Select Id, CreatedById FROM FeedComment WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedComments, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedComments.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private Integer calculateFailureCount() {
       Integer failureCount = 0;
       for (String result : resultMap.values()) {
            if (failure == result) {
                failureCount++;
            }
        }
        return failureCount;
   }
   
}

Denna kod skapar en Ta bort all aktivitet-knapp i din insiktsrapport. Denna knapp tar bort alla inlägg och kommentarer för de medlemmar som väljs. Om du även vill ta bort alla privata meddelanden och filer kan du utöka koden.

Anteckning

• Detta kodexempel inkluderar inga behörighetskontroller. Denna egna åtgärd fungerar endast för administratörer.
• ID för de objekt du valde i insiktsrapporten skickas till Visualforce med hjälp av parametern idsList.

<apex:page standardController="User" 
extensions="DeleteAllActivityControllerExtension" action="{!deleteAllActivity}" 
/>