breadcrumbDescription
Begræns eksempler for AutoSilver
Gennemse eksempelbegrænsninger, der er designet til AutoSilver-produktmodellen for at understøtte kompleks automatisk forsikringslogik.
Brug disse begrænsningseksempler til at forstå, hvordan du anvender betinget logik på tværs af køretøjsegenskaber, dækningsvalg og krydsproduktinteraktioner.
For fuld reference kan du gennemse den fuldstændige AutoSilver CML-fil.
Kræv medicinsk dækning for ældre biler af høj værdi
Hvis den dyreste bil er over $50.000, og den ældste bil er fra før 2020, kræves der Medicinsk betalingsdækning med en grænse på $2.000.
Hvad den dækker
- Begrænsning for flere forekomster
- Kræv dækningsbegrænsning
- Krydsproduktbegrænsning
CML-eksempel
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxAutoValue = max(Auto_Value);
minAutoYear = min(Year);
}
boolean constraint1 = auto.maxAutoValue >= 50000 && auto.minAutoYear < 2020;
require(constraint1, medicalpayments[MedicalPayments], "Auto add Medical Payments");
constraint(constraint1 && medicalpayments[MedicalPayments] > 0 -> medicalpayments[MedicalPayments].Limit == 2000, "Medical coverage set to $2000 for older high-value vehicles");
}
type Auto {
@(configurable = false)
decimal(2) Auto_Value;
int Year = [1980..2026];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
Kræv kollisionsdækning for nyere køretøjer
Tilføjer kollisionsdækning med en grænse på $5000 for køretøjer, der er nyere end 2023.
Hvad dækker
- Kræv dækningsbegrænsning
- Krydsproduktbegrænsning
CML-eksempel
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
relation collision : Collision[0..1];
boolean constraint2 = Year > 2023;
constraint(constraint2 -> collision[Collision], "auto add collision coverage");
constraint(constraint2 && collision[Collision] > 0 -> collision[Collision].Limit == 5000, "set collision limit to 5000");
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
} Udelad dækning for ikke-forsikret chauffør for ældre køretøjer
Forhindrer valget af Dækning for ikke-forsikret chauffør, når et køretøj er ældre end 2020, og Dækning for kollision med en $200-reduktion er valgt.
Hvad den dækker
- Udelad dækningsbegrænsning
- Krydsproduktbegrænsning
CML-eksempel
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
@(sequence = 4)
relation comprehensive : Comprehensive[0..1];
@(sequence = 3)
relation uninsuredMotorist : UninsuredMotorist[0..1];
boolean constraint3 = collision[Collision] > 0 && collision[Collision].Deductible == 200 && Year < 2020;
exclude(constraint3, uninsuredMotorist[UninsuredMotorist]);
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
@(domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
}
@(split = false)
type UninsuredMotorist;
Validering af alder for kørekort
Sikrer, at en førers alder og alder ved første licens er større end 16.
Hvad den dækker
- Basisbegrænsning
CML-eksempel
type Driver {
@(configurable = false)
int Age = [0..100];
int Age_First_Licensed = [0..100];
message(Age_First_Licensed < 16, "Don’t know who gave you license to driver before 16, legally!", "Warning");
message(Age < 16, "Error”: Driver is underaged to be added to the quote", "Error");
}
Kræv BIPD, når bestemte betingelser er opfyldt
Denne begrænsning kræver BIPD-dækning, når bestemte køretøjs-, chauffør- og prisbetingelser er opfyldt, og Medicinske betalinger ikke er valgt. Den skjuler også attributter og værdier i BIPD-dækningen.
Hvad den dækker
- Begrænsning for flere forekomster
- Kræv dækningsbegrænsning
- Kardinalitetsbegrænsning
- Overordnet kardinalitetsbegrænsning
- Krydsproduktbegrænsning
- Begrænsning for underunderordnede produkter
- Begrænsning for sidestillede produkter
CML-eksempel
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxDriverAccPoint1 = max(maxDriverAccPoint);
autoHasAntiTheft = count(Has_Anti_Theft > 0);
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
}
@(tagName = "ItemTotalPrice")
decimal(2) totalPrice;
boolean autoCondition = auto[Vehicle] > 0 && !auto.autoHasAntiTheft;
boolean driverCondition = auto.maxDriverAccPoint1 > 5;
boolean totalPriceCondition = totalPrice > 10;
boolean constraint5 = autoCondition && driverCondition && totalPriceCondition && medicalpayments[MedicalPayments] == 0;
@(abort = true)
require(constraint5, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when Auto IsElectricVehicle and Antitheft is false and Driver accident points > 5 and Collision is selected and MedicalPayments is NOT selected");
}
type Auto {
boolean Has_Anti_Theft;
}
type Vehicle : Auto {
int maxDriverAccPoint = driver.maxDriverAccPoint;
@(closeRelation = true, propagateUp = true, sequence = 1)
relation driver : AutoDriver[0..5] {
maxDriverAccPoint = max(Driver_Accident_Points);
}
type Driver {
int Driver_Accident_Points = [0..10];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Property_Damage_Per_Accident_Limit = [500, 1000, 1500, 2000];
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Accident_Limit = [500, 1000, 1500, 2000];
boolean rootconstraint5 = parent(constraint5);
rule(rootconstraint5, "hide", "attribute", "Property_Damage_Per_Accident_Limit");
rule(rootconstraint5, "hide", "attribute", "Bodily_Injury_Per_Accident_Limit","value", 2000);
}Kræv BIPD for standardbrugere med medicinske betalinger
Tilføjer BIPD-dækning med en grænse på $1000 for personskade pr. person, når en standardbruger vælger Medicinsk betalingsdækning med en grænse på $1000 og en høj enhedspris.
Hvad den dækker
- Kræv dækningsbegrænsning
- Kardinalitetsbegrænsning
- Krydsproduktbegrænsning
- Begrænsning for sidestillede produkter
CML-eksempel
@(contextPath = "SalesTransaction.UserProfile", attributeSource = "ST")
extern string UserProfile;
type AutoSilver {
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
medicalInputUnitPrice = inputUnitPrice;
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
boolean constraint6 = medicalpayments[MedicalPayments] == 1 && medicalpayments.medicalDeductible == 500 && UserProfile == "Standard User" && medicalpayments.medicalInputUnitPrice > 220;
require(constraint6, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when MedicalPayments is selected at 1k limit");
constraint(constraint6 && bodilyinjurypropertydamage[BodilyInjuryPropertyDamage] -> bodilyinjurypropertydamage[BodilyInjuryPropertyDamage].Bodily_Injury_Per_Person_Limit == 1000);
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Person_Limit = [500, 1000, 1500, 2000];
}
@(split = false)
type MedicalPayments {
@(defaultValue = "100", domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
@(tagName = "InputUnitPrice")
decimal(2) inputUnitPrice;
}
