Vous êtes ici :
Exemples de contraintes pour AutoSilver
Examinez les exemples de contraintes conçues pour le modèle de produit AutoSilver afin de prendre en charge une logique d'assurance automobile complexe.
Utilisez ces exemples de contraintes pour comprendre comment appliquer une logique conditionnelle à travers les caractéristiques des véhicules, les sélections de couverture et les interactions entre les produits.
Pour référence complète, vous pouvez consulter le fichier AutoSilver CML complet.
Demander une couverture médicale pour les voitures anciennes de grande valeur
Si la voiture la plus chère dépasse 50 000 $ et que la voiture la plus ancienne date d'avant 2020, une couverture de paiement médical avec une limite de 2000 $ est requise.
Ce qu'il couvre
- Contrainte multi-instances
- Demander une contrainte de couverture
- Contrainte inter-produits
Exemple CML
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxAutoValue = max(Auto_Value);
minAutoYear = min(Year);
}
boolean constraint1 = auto.maxAutoValue >= 50000 && auto.minAutoYear < 2020;
require(constraint1, medicalpayments[MedicalPayments], "Auto add Medical Payments");
constraint(constraint1 && medicalpayments[MedicalPayments] > 0 -> medicalpayments[MedicalPayments].Limit == 2000, "Medical coverage set to $2000 for older high-value vehicles");
}
type Auto {
@(configurable = false)
decimal(2) Auto_Value;
int Year = [1980..2026];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
Demander une couverture anticollision pour les véhicules récents
Ajoute la couverture Collision avec une limite de 5000 € pour les véhicules récents avant 2023.
Qu'est-ce que les couvertures
- Demander une contrainte de couverture
- Contrainte inter-produits
Exemple CML
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
relation collision : Collision[0..1];
boolean constraint2 = Year > 2023;
constraint(constraint2 -> collision[Collision], "auto add collision coverage");
constraint(constraint2 && collision[Collision] > 0 -> collision[Collision].Limit == 5000, "set collision limit to 5000");
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
} Exclusion de la protection des automobilistes non assurés pour les véhicules plus anciens
Empêche la sélection de la couverture Automobiliste non assuré lorsqu’un véhicule a plus de 2020 et que la couverture Collision avec une franchise de 200 $ est sélectionnée.
Ce qu'il couvre
- Exclure la contrainte de couverture
- Contrainte inter-produits
Exemple CML
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
@(sequence = 4)
relation comprehensive : Comprehensive[0..1];
@(sequence = 3)
relation uninsuredMotorist : UninsuredMotorist[0..1];
boolean constraint3 = collision[Collision] > 0 && collision[Collision].Deductible == 200 && Year < 2020;
exclude(constraint3, uninsuredMotorist[UninsuredMotorist]);
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
@(domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
}
@(split = false)
type UninsuredMotorist;
Validation de l'âge du permis de conduire
Garantit que l'âge du conducteur et son âge au premier permis sont tous deux supérieurs à 16 ans.
Ce qu'il couvre
- Contrainte de base
Exemple CML
type Driver {
@(configurable = false)
int Age = [0..100];
int Age_First_Licensed = [0..100];
message(Age_First_Licensed < 16, "Don’t know who gave you license to driver before 16, legally!", "Warning");
message(Age < 16, "Error”: Driver is underaged to be added to the quote", "Error");
}
Demander la DPBI lorsque certaines conditions sont remplies
Cette contrainte nécessite une couverture BIPD lorsque certaines conditions de véhicule, de conducteur et de prix sont remplies, et que Paiements médicaux ne sont pas sélectionnés. Il masque également les attributs et les valeurs dans la couverture BIPD.
Ce qu'il couvre
- Contrainte multi-instances
- Demander une contrainte de couverture
- Contrainte de cardinalité
- Contrainte de cardinalité parente
- Contrainte inter-produits
- Contrainte des produits petit-enfant
- Contrainte des produits des frères et sœurs
Exemple CML
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxDriverAccPoint1 = max(maxDriverAccPoint);
autoHasAntiTheft = count(Has_Anti_Theft > 0);
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
}
@(tagName = "ItemTotalPrice")
decimal(2) totalPrice;
boolean autoCondition = auto[Vehicle] > 0 && !auto.autoHasAntiTheft;
boolean driverCondition = auto.maxDriverAccPoint1 > 5;
boolean totalPriceCondition = totalPrice > 10;
boolean constraint5 = autoCondition && driverCondition && totalPriceCondition && medicalpayments[MedicalPayments] == 0;
@(abort = true)
require(constraint5, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when Auto IsElectricVehicle and Antitheft is false and Driver accident points > 5 and Collision is selected and MedicalPayments is NOT selected");
}
type Auto {
boolean Has_Anti_Theft;
}
type Vehicle : Auto {
int maxDriverAccPoint = driver.maxDriverAccPoint;
@(closeRelation = true, propagateUp = true, sequence = 1)
relation driver : AutoDriver[0..5] {
maxDriverAccPoint = max(Driver_Accident_Points);
}
type Driver {
int Driver_Accident_Points = [0..10];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Property_Damage_Per_Accident_Limit = [500, 1000, 1500, 2000];
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Accident_Limit = [500, 1000, 1500, 2000];
boolean rootconstraint5 = parent(constraint5);
rule(rootconstraint5, "hide", "attribute", "Property_Damage_Per_Accident_Limit");
rule(rootconstraint5, "hide", "attribute", "Bodily_Injury_Per_Accident_Limit","value", 2000);
}Demander la DPIB pour les utilisateurs standard avec des paiements médicaux
Ajoute la couverture de la DPBI avec une limite de 1000 € en dommages corporels par personne lorsqu'un utilisateur standard sélectionne une couverture Paiement médical avec une limite de 1000 € et un prix unitaire élevé.
Ce qu'il couvre
- Demander une contrainte de couverture
- Contrainte de cardinalité
- Contrainte inter-produits
- Contrainte des produits des frères et sœurs
Exemple CML
@(contextPath = "SalesTransaction.UserProfile", attributeSource = "ST")
extern string UserProfile;
type AutoSilver {
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
medicalInputUnitPrice = inputUnitPrice;
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
boolean constraint6 = medicalpayments[MedicalPayments] == 1 && medicalpayments.medicalDeductible == 500 && UserProfile == "Standard User" && medicalpayments.medicalInputUnitPrice > 220;
require(constraint6, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when MedicalPayments is selected at 1k limit");
constraint(constraint6 && bodilyinjurypropertydamage[BodilyInjuryPropertyDamage] -> bodilyinjurypropertydamage[BodilyInjuryPropertyDamage].Bodily_Injury_Per_Person_Limit == 1000);
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Person_Limit = [500, 1000, 1500, 2000];
}
@(split = false)
type MedicalPayments {
@(defaultValue = "100", domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
@(tagName = "InputUnitPrice")
decimal(2) inputUnitPrice;
}
