Вы находитесь здесь:
Примеры ограничений для AutoSilver
Просмотрите примеры ограничений, созданных для модели продукта AutoSilver для поддержки сложной логики автострахования.
Используйте эти примеры ограничений, чтобы понять, как применить условную логику в характеристиках транспортного средства, выборках покрытия и кросс-продуктовых взаимодействиях.
Для получения полной информации просмотрите полный файл AutoSilver CML.
Требовать медицинское покрытие для дорогостоящих старых автомобилей
Если самый дорогой автомобиль стоит более 50 000 долларов, а самый старый автомобиль до 2020 года, необходимо медицинское покрытие оплаты с ограничением 2000 долларов.
Что он охватывает
- Ограничение для нескольких экземпляров
- Требовать ограничение покрытия
- Межпродуктовое ограничение
Пример CML
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxAutoValue = max(Auto_Value);
minAutoYear = min(Year);
}
boolean constraint1 = auto.maxAutoValue >= 50000 && auto.minAutoYear < 2020;
require(constraint1, medicalpayments[MedicalPayments], "Auto add Medical Payments");
constraint(constraint1 && medicalpayments[MedicalPayments] > 0 -> medicalpayments[MedicalPayments].Limit == 2000, "Medical coverage set to $2000 for older high-value vehicles");
}
type Auto {
@(configurable = false)
decimal(2) Auto_Value;
int Year = [1980..2026];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
Требовать покрытие столкновения для новых транспортных средств
Добавляет покрытие столкновения с ограничением $5000 для транспортных средств более новых 2023 года.
Что такое обложки
- Требовать ограничение покрытия
- Межпродуктовое ограничение
Пример CML
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
relation collision : Collision[0..1];
boolean constraint2 = Year > 2023;
constraint(constraint2 -> collision[Collision], "auto add collision coverage");
constraint(constraint2 && collision[Collision] > 0 -> collision[Collision].Limit == 5000, "set collision limit to 5000");
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
} Исключение незастрахованного покрытия автомобилиста для старых транспортных средств
Запрещает выбор покрытия «Незастрахованный автомобилист», если транспортное средство старше 2020 года и выбрано покрытие «Столкновение» с вычетом $200.
Что он охватывает
- Исключить ограничение покрытия
- Межпродуктовое ограничение
Пример CML
type Auto {
int Year = [1980..2026];
}
type Vehicle : Auto {
@(sequence = 4)
relation comprehensive : Comprehensive[0..1];
@(sequence = 3)
relation uninsuredMotorist : UninsuredMotorist[0..1];
boolean constraint3 = collision[Collision] > 0 && collision[Collision].Deductible == 200 && Year < 2020;
exclude(constraint3, uninsuredMotorist[UninsuredMotorist]);
}
@(split = false)
type Collision {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
@(domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
}
@(split = false)
type UninsuredMotorist;
Проверка возраста водительских прав
Обеспечивает возраст водителя и возраст при получении первых прав более 16 лет.
Что он охватывает
- Базовое ограничение
Пример CML
type Driver {
@(configurable = false)
int Age = [0..100];
int Age_First_Licensed = [0..100];
message(Age_First_Licensed < 16, "Don’t know who gave you license to driver before 16, legally!", "Warning");
message(Age < 16, "Error”: Driver is underaged to be added to the quote", "Error");
}
Требовать BIPD при соблюдении определенных условий
Это ограничение требует покрытия BIPD, если определенные условия транспортного средства, водителя и цены соблюдены, а медицинские платежи не выбраны. Он также скрывает атрибуты и значения в покрытии BIPD.
Что он охватывает
- Ограничение для нескольких экземпляров
- Требовать ограничение покрытия
- Ограничение кардинальности
- Ограничение кардинальности родителей
- Межпродуктовое ограничение
- Ограничение для внуков
- Ограничение продуктов братьев и сестер
Пример CML
type AutoSilver {
@(closeRelation = true, propagateUp = true, sequence = 1)
relation auto : Vehicle {
maxDriverAccPoint1 = max(maxDriverAccPoint);
autoHasAntiTheft = count(Has_Anti_Theft > 0);
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
}
@(tagName = "ItemTotalPrice")
decimal(2) totalPrice;
boolean autoCondition = auto[Vehicle] > 0 && !auto.autoHasAntiTheft;
boolean driverCondition = auto.maxDriverAccPoint1 > 5;
boolean totalPriceCondition = totalPrice > 10;
boolean constraint5 = autoCondition && driverCondition && totalPriceCondition && medicalpayments[MedicalPayments] == 0;
@(abort = true)
require(constraint5, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when Auto IsElectricVehicle and Antitheft is false and Driver accident points > 5 and Collision is selected and MedicalPayments is NOT selected");
}
type Auto {
boolean Has_Anti_Theft;
}
type Vehicle : Auto {
int maxDriverAccPoint = driver.maxDriverAccPoint;
@(closeRelation = true, propagateUp = true, sequence = 1)
relation driver : AutoDriver[0..5] {
maxDriverAccPoint = max(Driver_Accident_Points);
}
type Driver {
int Driver_Accident_Points = [0..10];
}
type MedicalPayments {
@(defaultValue = "1000", domainComputation = false)
int Limit = [1000, 2000, 5000, 10000, 25000, 50000];
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Property_Damage_Per_Accident_Limit = [500, 1000, 1500, 2000];
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Accident_Limit = [500, 1000, 1500, 2000];
boolean rootconstraint5 = parent(constraint5);
rule(rootconstraint5, "hide", "attribute", "Property_Damage_Per_Accident_Limit");
rule(rootconstraint5, "hide", "attribute", "Bodily_Injury_Per_Accident_Limit","value", 2000);
}Требовать BIPD для стандартных пользователей с оплатой медицинских услуг
Добавляет покрытие BIPD с ограничением $1000 телесных повреждений на человека, когда стандартный пользователь выбирает покрытие Medical Payment с ограничением $1000 и высокой ценой единицы продукции.
Что он охватывает
- Требовать ограничение покрытия
- Ограничение кардинальности
- Межпродуктовое ограничение
- Ограничение продуктов братьев и сестер
Пример CML
@(contextPath = "SalesTransaction.UserProfile", attributeSource = "ST")
extern string UserProfile;
type AutoSilver {
@(sequence = 3)
relation medicalpayments : MedicalPayments[0..1] {
medicalLimit = Limit;
medicalDeductible = Deductible;
medicalInputUnitPrice = inputUnitPrice;
}
@(sequence = 2)
relation bodilyinjurypropertydamage : BodilyInjuryPropertyDamage[0..1];
boolean constraint6 = medicalpayments[MedicalPayments] == 1 && medicalpayments.medicalDeductible == 500 && UserProfile == "Standard User" && medicalpayments.medicalInputUnitPrice > 220;
require(constraint6, bodilyinjurypropertydamage[BodilyInjuryPropertyDamage], "BIPD is required when MedicalPayments is selected at 1k limit");
constraint(constraint6 && bodilyinjurypropertydamage[BodilyInjuryPropertyDamage] -> bodilyinjurypropertydamage[BodilyInjuryPropertyDamage].Bodily_Injury_Per_Person_Limit == 1000);
}
@(split = false)
type BodilyInjuryPropertyDamage {
@(defaultValue = "1000", domainComputation = false)
int Bodily_Injury_Per_Person_Limit = [500, 1000, 1500, 2000];
}
@(split = false)
type MedicalPayments {
@(defaultValue = "100", domainComputation = false)
int Deductible = [0, 50, 100, 200, 500];
@(tagName = "InputUnitPrice")
decimal(2) inputUnitPrice;
}
