Du er her:
Begrensningseksempler for medisinsk
Se gjennom eksempler på begrensninger for en omfattende helseforsikringsmodell.
Disse begrensningene viser hvordan du håndhever regler basert på medlemsalder, kjønn, ekteskapelig status, relasjoner og brukerprofil. Bruk disse mønstrene til å behandle preventiv behandling, dekning av kroniske sykdommer og virkemåte for utpatienter på tvers av primære og avhengige medlemmer.
For full referanse kan du se gjennom den fullstendige Medical CML-filen.
Krev PCW- og kronisk sykdomsdekning for bestemte medlemsprofiler
Hvis det primære medlemmet har utpatientdekning og er enten en mann over 40 år eller en gift kvinne, kreves det PCW-dekning (Preventive Care & Wellness) med et fradrag på USD 5000, sammen med dekning for kroniske sykdommer.
Hva den dekker
- Begrensning med flere betingelser
- Krev dekningsbegrensning
- Betinget attributthåndhevelse
Eksempel på CML
type PrimaryMember : Member {
@(closeRelation=true, propagateUp=true, sequence=1)
relation dependentmember : Member;
@(sequence=3)
relation chronicdisease : ChronicDisease[0..1];
@(sequence=4)
relation preventivecarewellness : PreventiveCareWellness[0..1];
@(sequence=5)
relation outpatient : OutPatient[0..1];
boolean isClause1 = (Age >= 40 && Gender == "Male") || Marital_Status == "Married";
boolean isPrimaryMemberOutPatientSelected = outpatient[OutPatient] > 0;
constraint(isClause1 && isPrimaryMemberOutPatientSelected -> preventivecarewellness[PreventiveCareWellness].Deductible_Limit == 5000, "Preventive care & wellness message Deductible Limit is set 5k");
require(isClause1 && isPrimaryMemberOutPatientSelected, chronicdisease[ChronicDisease], "Auto Add ChronicDisease");
}Håndheve begrensninger basert på avhengig status og brukerprofil
Hvis det primære medlemmet er en kvinne, brukeren er en standardbruker og minst ett avhengig medlem er enkeltmedlem, skjules visse attributtverdier, og dekning kreves eller ekskluderes i henhold til dette.
Hva den dekker
- Krev dekningsbegrensning
- Ekskluder dekningsbegrensning
- Skjul attributtverdi
- Interaksjon på tvers av produkter
Eksempel på CML
@(contextPath = "SalesTransaction.UserProfile", attributeSource = "ST")
extern string UserProfile;
type PrimaryMember : Member {
@(closeRelation=true, propagateUp=true, sequence=1)
relation dependentmember : Member {
depMemberSingleMaritalStatus = count(Marital_Status == 'Single');
}
@(sequence=2)
relation criticalillnesssurgery : CriticalIllnessSurgery[0..1];
@(sequence=4)
relation preventivecarewellness : PreventiveCareWellness[0..1];
@(sequence=5)
relation outpatient : OutPatient[0..1];
boolean isClause2 = Gender == 'Female' && UserProfile == "Standard User" && dependentmember.depMemberSingleMaritalStatus > 0;
exclude(isClause2, preventivecarewellness[PreventiveCareWellness], "remove primary member PCW coverage");
}
type DependentMember : Member {
@(sequence=4)
relation dependentcriticalillnesssurgery : CriticalIllnessSurgery[0..1];
boolean parentIsClause2 = parent(isClause2);
rule(parentIsClause2, "hide", "attribute", "Gender", "value", "Female");
require(parentIsClause2, dependentcriticalillnesssurgery[CriticalIllnessSurgery], "Auto add dep member critical illness surgery");
}
@(split = false)
type OutPatient {
int Doctor_visit_copay = [0, 10, 25, 10000];
boolean getClauseFlag = parent(parentIsClause2);
rule(getClauseFlag, "hide", "attribute", "Doctor_visit_copay");
}
Krev avhengig PCW basert på alder og overordnet PCW-utledning
Hvis det avhengige medlemmet er under 30 og det primære medlemmets PCW har en grense for utledet nettverk på 250 eller mer, må det avhengige medlemmet ha PCW med en årlig grense for utsolgt-tilbud på 20000.
Hva den dekker
- Avhengighet med flere enheter
- Begrensning på tvers av produkter
- Betinget attributtinnstilling
Eksempel på CML
type PrimaryMember : Member {
@(closeRelation=true, propagateUp=true, sequence=1)
relation dependentmember : Member;
@(sequence=4)
relation preventivecarewellness : PreventiveCareWellness[0..1];
int primarymemberPCWOut_Network_Deductible_Limit = preventivecarewellness[PreventiveCareWellness].Out_Network_Deductible_Limit;
}
type DependentMember : Member {
@(sequence=2)
relation dependentpreventivecarewellness : PreventiveCareWellness[0..1];
int primmemberONDL = parent(primarymemberPCWOut_Network_Deductible_Limit);
require((Age < 30 && primmemberONDL >= 250), dependentpreventivecarewellness[PreventiveCareWellness] {Annual_Out_of_Pocket_Limit = 20000},"Preventive Care Is Required OOPM is set to 20k");
}
Krev kronisk sykdom og angi kompensasjon for standardbrukere
Hvis det primære medlemmet har utpatientdekning og brukeren er en standardbruker, må en kronisk sykdom legges til for den avhengige, og legebesøksgodtgjørelsen må settes til 10 000.
Hva den dekker
- Krev dekningsbegrensning
- Attributtstandard
- Brukerprofilbasert logikk
Eksempel på CML
@(contextPath = "SalesTransaction.UserProfile", attributeSource = "ST")
extern string UserProfile;
type PrimaryMember : Member {
@(closeRelation=true, propagateUp=true, sequence=1)
relation dependentmember : Member;
@(sequence=5)
relation outpatient : OutPatient[0..1];
boolean isClause4 = outpatient[OutPatient] > 0;
constraint(outpatient[OutPatient] > 0 && UserProfile == "Standard User" -> outpatient.Doctor_visit_copay == 10000, "If OP cover then set Doctor visit to 10k");
}
type DependentMember : Member {
@(sequence=3)
relation dependentchronicdisease : ChronicDisease[0..1];
boolean parentIsClause4 = parent(isClause4);
require(parentIsClause4 && UserProfile == "Standard User", dependentchronicdisease[ChronicDisease], "Autoadd chronic disease cov for depmember");
}Krev kronisk og utpatientdekning basert på aldersbetingelser
Hvis det primære medlemmet er over 40 og det avhengige medlemmet er under 30, må den avhengige ha utpatientdekning, og det primære medlemmet må ha dekning for kronisk sykdom.
Hva den dekker
- Aldersbasert betingelseslogikk
- Krav for flere enheter
- Sideordnet produktbegrensning
Eksempel på CML
type PrimaryMember : Member {
@(closeRelation=true, propagateUp=true, sequence=1)
relation dependentmember : Member {
depMemMaxAge = max(Age);
}
@(sequence=3)
relation chronicdisease : ChronicDisease[0..1];
require(Age > 40 && dependentmember.depMemMaxAge < 30, chronicdisease[ChronicDisease], "Auto Add ChronicDisease for Primary member");
}
type DependentMember : Member {
@(sequence=1)
relation dependentoutpatient : OutPatient[0..1];
int primmemberAge = parent(Age);
require(primmemberAge > 40 && Age < 30, dependentoutpatient[OutPatient], "Auto add OP cov for depmember");
}