Sample Flow to Extract and Store Text in Records

public class TransformDocumentDetailsRequest {
   	@InvocableVariable (required=true)
    public String key;
    
    @InvocableVariable (required=true)
    public String targetObjectApiName;
  
    @InvocableVariable (required=true)
    public String contentDocumentID;
    
    @InvocableVariable(required=true) 
    public string origin; 
    
    @InvocableVariable(required=true) 
    public string status; 
    
    @InvocableVariable(required=true) 
    public string subject; 
        
}

public class TransformDocument {
    private static final String KEY_VALUE_PAIR = 'keyValuePair';
    private static final String TEXT = 'text';
    
    @InvocableMethod(label='Create Case Record' description='Creates a Case Record using the extracted values fetched from the document')
    public static void transform(List<TransformDocumentDetailsRequest> requestList) {
        // Get the OcrDocumentScanResult (ODSR) response for document uploaded in the flow
        List<OcrDocumentScanResult> odsrResponse = getOdsrResponse(requestList[0].contentDocumentID);
        
		// Pass key for which value should be fetched
        String value = getValue(odsrResponse, requestList[0].key);
        System.debug('key and value fetched: key:'+ requestList[0].key + ' value: ' + value);
        
		// Add appropriate required fields here. These particular fields are for Case Record. 	
		Map<String, String> requiredFields = new Map<String, String>();
        requiredFields.put('Status', requestList[0].status);
        requiredFields.put('Subject', requestList[0].subject);
        requiredFields.put('Origin', requestList[0].origin);
        saveExtractedValuesInTargetObject(requestList[0].key, value, requestList[0].targetObjectApiName, requiredFields);
    }

    /**
    * This method returns the extractedValues for the given content Document ID
    */ 
    private static List<OcrDocumentScanResult> getOdsrResponse(String ContentDocumentID) {
        List<OcrDocumentScanResult> ocrScanResults = [SELECT ExtractedValues FROM OcrDocumentScanResult WHERE ContentDocumentId =: ContentDocumentID];
        return ocrScanResults;
    }
    
    /**
    * This method returns the value corresponding to the key in the response.
    * The response contains separate OcrDocumentScanResult records for each page in the document.
    * Extract the output keys and values for each page and search for the required key.
    */ 
    private static String getValue(List<OcrDocumentScanResult> ocrDocumentScanResults, String key) {
        String value = '';
        for (OcrDocumentScanResult ocrScanResult : ocrDocumentScanResults) {
            String response = ocrScanResult.ExtractedValues;
            Map<String, Object> jsonMap = (Map<String, Object>) JSON.deserializeUntyped(response);
            List<Object> keyValuePairList = (List<Object>) jsonMap.get(KEY_VALUE_PAIR);
            List<Map<String, Object>> keyValuePairMapList = new List<Map<String, Object>>();
            for (Object keyValuePair : keyValuePairList) {
                Map<String, Object> keyValuePairMap = (Map<String, Object>) keyValuePair;
                keyValuePairMapList.add(keyValuePairMap);
            }        
            for (Map<String, Object> keyValuePair : keyValuePairMapList) {
                Map<String, Object> keyMap = (Map<String, Object>) keyValuePair.get('key');
                if (keyMap.get(TEXT).equals(key)) {
                    Map<String, Object> valueMap = (Map<String, Object>) keyValuePair.get('value');
                    if(valueMap != null) {
                        value = (String) valueMap.get(TEXT);
                        break;
                    }
                }
            }
        }
        return value;
    }

    /**
    * This method creates a new record of objectType target object and saves values in one of 
    * the fields of the target object.
    * Since some target objects require mandatory fields for a record to be created,
    * we use requiredFields map that has keys as mandatory fields' API names
    * and values as per the usecase requirement.
    */
    private static void saveExtractedValuesInTargetObject(String key_extract, String value_extracted, String objectType, Map<String, String> requiredFields) {
        SObject newRecord = (SObject) Type.forName(objectType).newInstance();
        // Required field for record-creation
        for (String key : requiredFields.keySet()) {
            String val = requiredFields.get(key);
            newRecord.put(key, val);
        }
        newRecord.put(key_extract, value_extracted);
        insert newRecord;
    }
}