Personnalisation de vos plans de procédure avec les hooks Apex

Vous êtes ici :

Personnalisation de vos plans de procédure avec les hooks Apex

Pour prendre en charge des scénarios de tarification uniques, ajoutez une logique Apex personnalisée à vos plans de procédure tarifaire. Vous pouvez utiliser des hooks Apex pour appliquer une logique métier personnalisée qui modifie le contexte de tarification après la configuration d'une ligne de devis. Utilisez un pré-crochet Apex pour ajuster la tarification en fonction des attributs du produit avant que le prix soit calculé, et un post-crochet Apex pour gérer les changements de tarification des groupes et des autres éléments d'objet Devis après la tarification. Lorsqu'un commercial configure un produit ou modifie un groupe d'éléments de ligne de devis, le plan de procédure tarifaire modifie la tarification en fonction des instructions figurant dans Apex.

Éditions requises

Disponible avec : Lightning Experience

Disponible avec : Éditions Enterprise, Unlimited et Developer de Revenue Cloud dans lesquelles Tarification Salesforce est activée

Autorisations utilisateur requises
Pour créer, mettre à jour et supprimer des procédures de tarification et des plans de procédure :	Accès à l'utilisateur ou au plan de procédure du temps de conception de la tarification Salesforce
Pour utiliser des procédures de tarification :	Utilisateur de Salesforce Pricing Run Time
Pour créer, modifier, supprimer, définir la sécurité et définir les paramètres de version de classes Apex :	Auteur Apex

Important

Lors de l'utilisation du type de processus Revenue Cloud, toute logique Apex que vous ajoutez doit être le premier ou le dernier élément de la séquence d'exécution Plan de procédure.
Les appels externes à partir d ' un hook Apex sont pris en charge uniquement lorsque la requête Transaction de lieu de vente est déclenchée via l ' interface utilisateur Salesforce ou l ' API Transaction de lieu de vente. Ils ne sont pas pris en charge lorsque la requête est déclenchée depuis Apex ou Flux.
Les appels externes dans les hooks Apex ne sont pas pris en charge lorsque le mode Persistance double est activé. Pour des conseils supplémentaires, contactez le Support client de Salesforce.
Les appels externes dans les hooks Apex peuvent affecter les performances. Par conséquent, les objectifs de niveau de service (SLO) prévisibles ne peuvent pas être garantis.

Assurez-vous que l'option Orchestration du plan de procédure pour la tarification est activée.
1. Dans Configuration, saisissez Paramètres de revenu dans la case Recherche rapide, puis sélectionnez Paramètres de revenu.
2. Recherchez et activez si nécessaire le paramètre Orchestration du plan de procédure pour la tarification.
3. Laissez le paramètre Exclure les procédures de tarification par défaut et par type de transaction commerciale désactivé.

Définissez des classes pour les hooks Apex à ajouter à vos procédures de tarification.

Dans Configuration, saisissez Apex dans la case Recherche rapide, puis sélectionnez Classes Apex.
Sélectionnez Nouveau pour créer une classe Apex.

Dans l'éditeur de classe, saisissez la définition de la classe.

Par exemple, ce prehook (ApexDmAttributePreHook) met à jour les valeurs des attributs dynamiques sous le nom Display_Size en fonction de leur taille d'affichage. D'autres exemples de classes sont affichés à la fin de ces étapes dans Exemples de classes pour les hooks de tarification Apex.

global class ApexDmlAttributePreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        // STEP 1 - Query SalesTransactionItemAttribute and extract Display_Size values
        Map<String, Object> inputQueryItemAttr = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItemAttribute' }
        };
        Map<String, Object> itemAttrQueryOutput = industriesContext.queryTags(inputQueryItemAttr);
        Map<String, Object> itemAttrQueryResult = (Map<String, Object>) itemAttrQueryOutput.get('queryResult');
        List<Object> itemAttrData = (List<Object>) itemAttrQueryResult.get('SalesTransactionItemAttribute');

        Map<String, Decimal> parentCtxIdToDisplaySize = new Map<String, Decimal>();

        for (Object attrObj : itemAttrData) {
            Map<String, Object> attrNode = (Map<String, Object>) attrObj;
            Map<String, Object> tagMap = (Map<String, Object>) attrNode.get('tagValue');

            String attributeName = null;
            String attributeValueStr = null;
            String parentCtxId = null;

            if (tagMap.containsKey('Attribute')) {
                attributeName = (String)((Map<String, Object>) tagMap.get('Attribute')).get('tagValue');
            }
            if (tagMap.containsKey('AttributeValue')) {
                attributeValueStr = (String)((Map<String, Object>) tagMap.get('AttributeValue')).get('tagValue');
            }
            if (tagMap.containsKey('SalesTransactionItemAttrParent')) {
                parentCtxId = (String)((Map<String, Object>) tagMap.get('SalesTransactionItemAttrParent')).get('tagValue');
            }

            if (attributeName == 'Display_Size' && attributeValueStr != null && parentCtxId != null) {
                Decimal sizeValue = Decimal.valueOf(attributeValueStr.split(' ')[0]);
                parentCtxIdToDisplaySize.put(parentCtxId, sizeValue);
                System.debug('DisplaySize=' + sizeValue);
                System.debug('Matched itemCtxId=' + parentCtxId);
            }
        }

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            for (String ctxKey : parentCtxIdToDisplaySize.keySet()) {
                if (dataPath.contains(ctxKey)) {
                    Decimal newPrice = parentCtxIdToDisplaySize.get(ctxKey);
                    System.debug('DisplaySize match found for item ' + ctxKey);
                    dataPath.remove(0); // Remove contextId

                    itemNodeUpdates.add(new Map<String, Object>{
                        'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                        'attributes' => new List<Object>{
                            new Map<String, Object>{
                                'attributeName' => 'UnitPrice',
                                'attributeValue' => newPrice
                            }
                        }
                    });
                    matched = true;
                    break;
                }
            }

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
    
}

Enregistrez la définition de la classe.

Dans Configuration, saisissez Plan de procédure dans la case Recherche rapide, puis sélectionnez Définitions de plan de procédure.
Dans la colonne Noms de définition, sélectionnez une définition de plan de procédure à modifier.
Dans la définition du plan de procédure, dans Sections du plan de procédure, sélectionnez Ajouter pour ajouter une nouvelle section.
1. Sélectionnez Standard.
2. Nommez la section, par exemple Pre Apex pour un prehook Apex.
3. Dans Type de section, sélectionnez Apex puis Enregistrer.
4. Agrandissez la nouvelle section.
5. Pour Phases, sélectionnez Tarification et pour Type de résolution sélectionnez Par défaut.
6. Dans la case de sélection Apex qui s'affiche, saisissez la classe Apex que vous avez définie ci-dessus, par exemple ApexDmlAttributePreHook, puis sélectionnez Enregistrer.
7. Ajoutez des pré-crochets et des post-crochets supplémentaires si nécessaire.
Sélectionnez Gérer les sections pour réorganiser les prehooks au-dessus de la section Procédure de tarification et les posthooks sous celle-ci.
Enregistrez vos modifications dans la définition du Plan de procédure.

Exemple Exemples de classes pour les hooks de tarification Apex

Pré-crochet : Mettez à jour le pourcentage de remise à 2 % sur toutes les lignes du contexte (par exemple, les lignes de devis).


global class ApexDmlDiscountUpdatePreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        Integer randomDiscountPercentage = 2;

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        System.debug('QLI itemData=' + itemData);

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            dataPath.remove(0); // Remove contextId

            itemNodeUpdates.add(new Map<String, Object>{
                'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                'attributes' => new List<Object>{
                    new Map<String, Object>{
                        'attributeName' => 'Discount',
                        'attributeValue' => randomDiscountPercentage
                    }
                }
            });
            matched = true;

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
}

Pré-crochet : Appelez une ressource externe pour récupérer une valeur de quantité.


global class ApexDmlQuantityCalloutPreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        // STEP 1 - External Callout Test
        Integer randomNumber = getRandomNumber();
        System.debug(' Random Number from API: ' + randomNumber);

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        System.debug('QLI itemData=' + itemData);

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            dataPath.remove(0); // Remove contextId
    
            itemNodeUpdates.add(new Map<String, Object>{
                'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                'attributes' => new List<Object>{
                    new Map<String, Object>{
                        'attributeName' => 'Quantity',
                        'attributeValue' => randomNumber
                    }
                }
            });
            matched = true;

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
    
    // External callout
    private Integer getRandomNumber() {
        String endpoint = 'https://www.random.org/integers/?num=1&min=1&max=100&col=1&base=10&format=plain&rnd=new';
        Http http = new Http();
        HttpRequest req = new HttpRequest();
        req.setEndpoint(endpoint);
        req.setMethod('GET');
        req.setTimeout(5000);

        try {
            HttpResponse res = http.send(req);
            if (res.getStatusCode() == 200) {
                System.debug('Fetched prices from external service');
                return Integer.valueOf(res.getBody().trim());
            } else {
                System.debug(' Callout failed: ' + res.getStatus());
            }
        } catch (Exception ex) {
            System.debug(' Exception during callout: ' + ex.getMessage());
        }
        return 10;
    }
}

Pré-crochet : Déclenchez une mise à jour du prix d'un produit si son Nom d'attribut est Affichage et sa Valeur d'attribut est Affichage intégré 1080p, ou si son Nom d'attribut est Imprimante et sa Valeur d'attribut est Laser.


global class ApexDmlMultiAttributePreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        // STEP 1 - Query SalesTransactionItemAttribute and extract Display_Size values
        Map<String, Object> inputQueryItemAttr = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItemAttribute' }
        };
        Map<String, Object> itemAttrQueryOutput = industriesContext.queryTags(inputQueryItemAttr);
        Map<String, Object> itemAttrQueryResult = (Map<String, Object>) itemAttrQueryOutput.get('queryResult');
        List<Object> itemAttrData = (List<Object>) itemAttrQueryResult.get('SalesTransactionItemAttribute');

        Map<String, Decimal> parentCtxIdToAttribute = new Map<String, Decimal>();

        for (Object attrObj : itemAttrData) {
            Map<String, Object> attrNode = (Map<String, Object>) attrObj;
            Map<String, Object> tagMap = (Map<String, Object>) attrNode.get('tagValue');

            String attributeName = null;
            String attributeValueStr = null;
            String parentCtxId = null;

            System.debug('TagMap ' + tagMap);
            if (tagMap.containsKey('Attribute')) {
                attributeName = (String)((Map<String, Object>) tagMap.get('Attribute')).get('tagValue');
            }
            if (tagMap.containsKey('AttributeValue')) {
                attributeValueStr = (String)((Map<String, Object>) tagMap.get('AttributeValue')).get('tagValue');
            }
            if (tagMap.containsKey('SalesTransactionItemAttrParent')) {
                parentCtxId = (String)((Map<String, Object>) tagMap.get('SalesTransactionItemAttrParent')).get('tagValue');
            }
            
            if (attributeName == 'Display' && attributeValueStr == '1080p Built-in Display' && parentCtxId != null) {
               Decimal defaultDisplayCost = 1000.00;
               parentCtxIdToAttribute.put(parentCtxId, defaultDisplayCost);
               System.debug('Display=' + defaultDisplayCost);
               System.debug('Matched itemCtxId=' + parentCtxId);
            }
            
            if (attributeName == 'Printer' && attributeValueStr == 'Laser' && parentCtxId != null) {
               Decimal defaultLaserPrinterCost = 500.00;
               parentCtxIdToAttribute.put(parentCtxId, defaultLaserPrinterCost);
               System.debug('Printer=' + defaultLaserPrinterCost);
               System.debug('Matched itemCtxId=' + parentCtxId);
            }
        }

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            for (String ctxKey : parentCtxIdToAttribute.keySet()) {
                if (dataPath.contains(ctxKey)) {
                    Decimal newPrice = parentCtxIdToAttribute.get(ctxKey);
                    System.debug('Attribute match found for item ' + ctxKey);
                    System.debug('Attribue with new price ' + newPrice);
                    dataPath.remove(0); // Remove contextId

                    itemNodeUpdates.add(new Map<String, Object>{
                        'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                        'attributes' => new List<Object>{
                            new Map<String, Object>{
                                'attributeName' => 'UnitPrice',
                                'attributeValue' => newPrice
                            }
                        }
                    });
                    matched = true;
                    break;
                }
            }

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
    
}

Pré-crochet : Appliquez un pourcentage de remise aléatoire à toutes les lignes du contexte.


global class ApexDmlRandomDiscountPreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        Integer randomDiscountPercentage = getRandomNumber();

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        System.debug('QLI itemData=' + itemData);

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            dataPath.remove(0); // Remove contextId

            itemNodeUpdates.add(new Map<String, Object>{
                'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                'attributes' => new List<Object>{
                    new Map<String, Object>{
                        'attributeName' => 'Discount',
                        'attributeValue' => randomDiscountPercentage
                    }
                }
            });
            matched = true;

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
        // External callout
    public static Integer getRandomNumber() {
        String endpoint = 'https://www.random.org/integers/?num=1&min=1&max=100&col=1&base=10&format=plain&rnd=new';
        Http http = new Http();
        HttpRequest req = new HttpRequest();
        req.setEndpoint(endpoint);
        req.setMethod('GET');
        req.setTimeout(5000);

        try {
            HttpResponse res = http.send(req);
            if (res.getStatusCode() == 200) {
                System.debug('Fetched prices from external service');
                return Integer.valueOf(res.getBody().trim());
            } else {
                System.debug(' Callout failed: ' + res.getStatus());
            }
        } catch (Exception ex) {
            System.debug(' Exception during callout: ' + ex.getMessage());
        }
        return 10;
    }

}

Pré-crochet : Mettez à jour une valeur d'attribut dynamique avec une valeur aléatoire depuis un appel externe vers une ressource externe.


global class ApexDmlAttributeExternalCalloutPreHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing PREHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        // STEP 1 - Query SalesTransactionItemAttribute and extract Display_Size values
        Map<String, Object> inputQueryItemAttr = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItemAttribute' }
        };
        Map<String, Object> itemAttrQueryOutput = industriesContext.queryTags(inputQueryItemAttr);
        Map<String, Object> itemAttrQueryResult = (Map<String, Object>) itemAttrQueryOutput.get('queryResult');
        List<Object> itemAttrData = (List<Object>) itemAttrQueryResult.get('SalesTransactionItemAttribute');

        Map<String, Decimal> parentCtxIdToDisplaySize = new Map<String, Decimal>();

        for (Object attrObj : itemAttrData) {
            Map<String, Object> attrNode = (Map<String, Object>) attrObj;
            Map<String, Object> tagMap = (Map<String, Object>) attrNode.get('tagValue');

            String attributeName = null;
            String attributeValueStr = null;
            String parentCtxId = null;

            if (tagMap.containsKey('Attribute')) {
                attributeName = (String)((Map<String, Object>) tagMap.get('Attribute')).get('tagValue');
            }
            if (tagMap.containsKey('AttributeValue')) {
                attributeValueStr = (String)((Map<String, Object>) tagMap.get('AttributeValue')).get('tagValue');
            }
            if (tagMap.containsKey('SalesTransactionItemAttrParent')) {
                parentCtxId = (String)((Map<String, Object>) tagMap.get('SalesTransactionItemAttrParent')).get('tagValue');
            }

            if (attributeName == 'Display_Size' && attributeValueStr != null && parentCtxId != null) {
                Decimal sizeValue = getRandomNumber();
                parentCtxIdToDisplaySize.put(parentCtxId, sizeValue);
                System.debug('DisplaySize=' + sizeValue);
                System.debug('Matched itemCtxId=' + parentCtxId);
            }
        }

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            for (String ctxKey : parentCtxIdToDisplaySize.keySet()) {
                if (dataPath.contains(ctxKey)) {
                    Decimal newPrice = parentCtxIdToDisplaySize.get(ctxKey);
                    System.debug('DisplaySize match found for item ' + ctxKey);
                    dataPath.remove(0); // Remove contextId

                    itemNodeUpdates.add(new Map<String, Object>{
                        'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                        'attributes' => new List<Object>{
                            new Map<String, Object>{
                                'attributeName' => 'UnitPrice',
                                'attributeValue' => newPrice
                            }
                        }
                    });
                    matched = true;
                    break;
                }
            }

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
    
        // External callout
    private Integer getRandomNumber() {
        String endpoint = 'https://www.random.org/integers/?num=1&min=1&max=100&col=1&base=10&format=plain&rnd=new';
        Http http = new Http();
        HttpRequest req = new HttpRequest();
        req.setEndpoint(endpoint);
        req.setMethod('GET');
        req.setTimeout(5000);

        try {
            HttpResponse res = http.send(req);
            if (res.getStatusCode() == 200) {
                System.debug('Fetched prices from external service');
                return Integer.valueOf(res.getBody().trim());
            } else {
                System.debug(' Callout failed: ' + res.getStatus());
            }
        } catch (Exception ex) {
            System.debug(' Exception during callout: ' + ex.getMessage());
        }
        return 10;
    }
}

Posthook : Mettez à jour la description de chaque ligne dans le contexte.


global class ApexDmlDescriptionPostHook implements RevSignaling.SignalingApexProcessor {

    public virtual class BaseException extends Exception {}
    public class OtherException extends BaseException {}
    
    public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
        System.debug('Executing POSTHOOK');
        
        String contextId = request.ctxInstanceId;
        Context.IndustriesContext industriesContext = new Context.IndustriesContext();
        
        String randomDescription = 'via Post Apex Pricing Hook';

        // STEP 2 - Query SalesTransactionItem nodes
        Map<String, Object> inputQueryItem = new Map<String, Object>{
            'contextId' => contextId,
            'tags' => new List<String>{ 'SalesTransactionItem' }
        };
        Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
        Map<String, Object> itemQueryResult = (Map<String, Object>) itemQueryOutput.get('queryResult');
        List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');

        System.debug('QLI itemData=' + itemData);

        // STEP 3 - Build update list
        List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();

        for (Object itemObj : itemData) {
            Map<String, Object> itemNode = (Map<String, Object>) itemObj;
            List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
            System.debug('Full item dataPath: ' + JSON.serialize(dataPath));

            Boolean matched = false;
            dataPath.remove(0); // Remove contextId

            itemNodeUpdates.add(new Map<String, Object>{
                'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                'attributes' => new List<Object>{
                    new Map<String, Object>{
                        'attributeName' => 'SalesTrxnItemDescription',
                        'attributeValue' => randomDescription
                    }
                }
            });
            matched = true;

            if (!matched) {
                String itemCtxId = dataPath.size() > 1 ? String.valueOf(dataPath[1]) : 'UNKNOWN';
                System.debug('No DisplaySize match found for item ' + itemCtxId);
            }
        }

        // STEP 4 - Submit context update
        if (!itemNodeUpdates.isEmpty()) {
            Map<String, Object> updateInput = new Map<String, Object>{
                'contextId' => contextId,
                'nodePathAndAttributes' => itemNodeUpdates
            };

            System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
            System.debug(JSON.serializePretty(updateInput));
            industriesContext.updateContextAttributes(updateInput);
        }

        RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
        response.status = RevSignaling.TransactionStatus.SUCCESS;
        //response.status = RevSignaling.TransactionStatus.FAILED;
        //response.message = 'An error occurred during the processing...';
        return response;
    }
}

Cet article a-t-il résolu votre problème ?

Dites-nous ce que nous pouvons améliorer !

Ce texte a été traduit à l’aide du système de traduction automatique de Salesforce. Plus de détails, consultez <cette page.

Personnalisation de vos plans de procédure avec les hooks Apex

Éditions requises

General Information

Required Cookies

Functional Cookies

Advertising Cookies

General Information

Required Cookies

Functional Cookies

Advertising Cookies

Cookie List

Ce texte a été traduit à l’aide du système de traduction automatique de Salesforce. Plus de détails, consultez <cette page.Basculer vers la page en anglaisPas maintenant

Gamme de produits

Impact des fonctionnalités

Edition

Expérience

Personnalisation de vos plans de procédure avec les hooks Apex

Éditions requises

Ce texte a été traduit à l’aide du système de traduction automatique de Salesforce. Plus de détails, consultez <cette page.