절차 계획 프레임워크 사용

가격 책정을 위한 절차 계획 오케스트레이션 활성화

1. 설정에서 빠른 찾기 상자에 매출 설정을 입력한 다음, 매출 설정을 선택합니다.
2. 가격 책정을 위한 절차 계획 오케스트레이션을 찾아서 활성화합니다.
3. 기본 및 세일즈 트랜잭션 유형 가격 책정 절차 제외를 찾아서 활성화합니다.

상업 제품 만들기

1. 앱 시작 관리자에서 제품을 찾아서 선택합니다.
2. 델리 - 뉴욕이라는 상업 제품을 만듭니다.
   제품을 만드는 방법을 알아보려면 간단한 제품 만들기를 참조하고 제품 레코드 유형이 상업으로 설정되어 있는지 확인하십시오.
3. 카탈로그에 제품을 추가하고 해당 제품에 대한 가격 목록 항목을 만듭니다.
4. 설정에서 빠른 찾기 상자에서 Salesforce 가격 책정 설정을 검색하여 선택합니다.
5. 가격 책정 데이터 동기화 섹션에서 동기화를 클릭합니다.

가격 책정 절차 구축

1. 가격 책정 절차를 만들고 이름을 예약 가격 책정 절차로 지정합니다.
   가격 책정 절차를 만들려면 가격 책정 절차 구성의 첫 5단계를 따르십시오.
2. 상수를 만듭니다. 해당 상수는 가격 책정 절차에서 고정 값의 자리 표시자로 사용됩니다.

   상수 이름	데이터 유형	Default Value(기본값)
   AdjType	TEXT	퍼센트
   AdjValue	숫자	5
   재정의	TEXT	재정의
   ConvFeeAdjType	TEXT	금액
   ConvFeeAdjValue	숫자	-250

3. 다음 요소를 추가합니다.
   1. 가격 설정
   2. 정가. 가격 목록 항목 V2 결정 테이블을 사용합니다.
   3. 수동 할인. 3개의 수동 할인 요소를 추가해야 합니다.
4. 첫 번째 수동 할인 요소가 추가되어 비행의 동적 기본 요금을 계산합니다. 다음 변수를 매핑합니다.
   • 입력 변수
     • 조정 유형: 오버라이드
     • 조정 값: PartnerUnitPrice
     • 수량: LineItemQuantity
     • 입력 단가: 목록가격
   • 출력 변수
     • 순 단가: NetUnitPrice
5. 두 번째 수동 할인 요소가 추가되어 비행 예약에 대한 플랫폼 할인을 계산합니다. 다음 변수를 매핑합니다.
   • 입력 변수
     • 조정 유형: AdjType
     • 조정 값: AdjValue
     • 수량: LineItemQuantity
     • 입력 단가: PartnerUnitPrice
   • 출력 변수
     • 순 단가: NetUnitPrice
6. 마지막 수동 할인 요소는 비용을 청구하는 편의 요금을 계산하기 위해 추가되며,
   • 입력 변수
     • 조정 유형: ConvFeeAdjType
     • 조정 값: ConvFeeAdjValue
     • 수량: LineItemQuantity
     • 입력 단가: NetUnitPrice
   • 출력 변수
     • 순 단가: NetUnitPrice
7. 기본 설정을 설정하여 가격 책정 정보, 프로필 액세스 및 순위 정보를 봅니다.
8. 절차를 저장합니다.
9. 절차를 활성화합니다.

Apex 후크의 클래스 정의

1. 설정에서 빠른 찾기 상자에 Apex를 입력한 다음, Apex 클래스를 선택합니다.
2. 새로 만들기를 클릭합니다.
3. 첫 번째 Apex 클래스는 가격 책정 컨텍스트에서 모든 세일즈 트랜잭션 항목을 가져오고 외부 데이터베이스에서 가격 책정을 실행하기 전에 동적 무작위 기본 요금(990~1200)으로 PartnerUnitPrice 태그를 재정의하는 프리후크입니다.

   public class DynamicFlightBasePriceApex implements RevSignaling.SignalingApexProcessor {
   
       public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
           System.debug('Executing PREHOOK');
           String contextId = request.ctxInstanceId;
           Context.IndustriesContext industriesContext = new Context.IndustriesContext();
           
           //Query SalesTransactionItem nodes
           Map<String, Object> inputQueryItem = new Map<String, Object>{
               'contextId' => contextId,
                   'tags' => new List<String>{ 'SalesTransactionItem' }
           };
           Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
           Map<String, Object> itemQueryResult = (Map<String, Object>)itemQueryOutput.get('queryResult');
           List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');
           System.debug('QLI itemData=' + itemData);
   
           // Generate random price between 990 and 1200
           Decimal minPrice = 990;
           Decimal maxPrice = 1200;
           Decimal range = maxPrice - minPrice;
   
           // Use Crypto.getRandomInteger() to generate a secure random number
           Integer randomInt = Math.abs(Crypto.getRandomInteger());
           Decimal randomPrice = minPrice + Math.mod(randomInt, range.intValue() + 1);
   
           System.debug('Generated Random Price: ' + randomPrice);
           
           // STEP 3 - Build update list
           List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();
           for (Object itemObj : itemData) {
               Map<String, Object> itemNode = (Map<String, Object>) itemObj;
               List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
               System.debug('Full item dataPath: ' + JSON.serialize(dataPath));
   			dataPath.remove(0); // Remove contextId
   			itemNodeUpdates.add(new Map<String, Object>{
                   'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                   'attributes' => new List<Object>{
                       new Map<String, Object>{
                           'attributeName' => 'PartnerUnitPrice',
                           'attributeValue' => randomPrice
                      }
                   }
               });
           }
                  
           // STEP 4 - Submit context update
           if (!itemNodeUpdates.isEmpty()) {
               Map<String, Object> updateInput = new Map<String, Object>{
                   'contextId' => contextId,
                   'nodePathAndAttributes' => itemNodeUpdates
               };
               System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
               System.debug(JSON.serializePretty(updateInput));
               industriesContext.updateContextAttributes(updateInput);
           }
   
           // Return the response
           RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
           response.status = RevSignaling.TransactionStatus.SUCCESS;
           response.message = 'Apex executed successfully with Random Price: ' + randomPrice;
           return response;
       }
   }
   

4. 다른 Apex 클래스를 만듭니다.
   이 Apex 클래스는 가격 책정 후 NetUnitPrice 태그를 가져오고 85~86 사이의 시뮬레이션 동적 변환율을 사용하여 현지 통화인 INR(인도 루피)로 변환하는 후 판매 거래 항목 설명을 새 INR 요금으로 업데이트하여 인도 고객에게 현지화된 가격 가시성을 제공합니다.

   public class ConvertFareToINRApex implements RevSignaling.SignalingApexProcessor {
   
       public RevSignaling.TransactionResponse execute(RevSignaling.TransactionRequest request) {
           System.debug('Executing POSTHOOK');
           String contextId = request.ctxInstanceId;
           Context.IndustriesContext industriesContext = new Context.IndustriesContext();
           
           //Query SalesTransactionItem nodes
           Map<String, Object> inputQueryItem = new Map<String, Object>{
               'contextId' => contextId,
                   'tags' => new List<String>{ 'SalesTransactionItem' }
           };
           Map<String, Object> itemQueryOutput = industriesContext.queryTags(inputQueryItem);
           Map<String, Object> itemQueryResult = (Map<String, Object>)itemQueryOutput.get('queryResult');
           List<Object> itemData = (List<Object>) itemQueryResult.get('SalesTransactionItem');
           System.debug('QLI itemData=' + itemData);
           
           //Query NetUnitPrice nodes
           Map<String, Object> inputQueryItem2 = new Map<String, Object>{
               'contextId' => contextId,
                   'tags' => new List<String>{ 'NetUnitPrice' }
           };
           Map<String, Object> itemQueryOutput2 = industriesContext.queryTags(inputQueryItem2);
           Map<String, Object> itemQueryResult2 = (Map<String, Object>)itemQueryOutput2.get('queryResult');
           List<Object> itemData2 = (List<Object>) itemQueryResult2.get('NetUnitPrice');
           System.debug('NetUnitPrice itemData=' + itemData2);
           Map<String, Object> netUnitTagData = (Map<String, Object>) itemData2.get(0);
           Decimal netUnitPrice = (Decimal) netUnitTagData.get('tagValue');
           netUnitPrice = netUnitPrice.setScale(2);
           System.debug('NetUnitPrice Tag Value=' + netUnitPrice);
   
           // Generate random price between 85.00 and 86.00 with decimals
           Decimal minPrice = 85.00;
           Decimal maxPrice = 86.00;
           Decimal range = maxPrice - minPrice; 
           Integer randomInt = Math.abs(Crypto.getRandomInteger());
           Integer randomDecimalInt = Math.mod(randomInt, 100);
           Decimal randomFraction = Decimal.valueOf(randomDecimalInt) / 100;
           Decimal usdToInrRate = minPrice + randomFraction;
           if (usdToInrRate > maxPrice) { 
               usdToInrRate = maxPrice;
           }
           
           // Calculate NetUnitPrice in INR
           Decimal fareInInr = (netUnitPrice * usdToInrRate).setScale(2);
           
           String fareMessage = 'The Flight fare in INR is: ' + fareInInr + 
                        ' (USD ' + netUnitPrice + 
                        ' at rate ' + usdToInrRate + ')';
           System.debug(fareMessage);
           
           // STEP 3 - Build update list
           List<Map<String, Object>> itemNodeUpdates = new List<Map<String, Object>>();
           for (Object itemObj : itemData) {
               Map<String, Object> itemNode = (Map<String, Object>) itemObj;
               List<Object> dataPath = (List<Object>) itemNode.get('dataPath');
               System.debug('Full item dataPath: ' + JSON.serialize(dataPath));
   			dataPath.remove(0); // Remove contextId
   			itemNodeUpdates.add(new Map<String, Object>{
                   'nodePath' => new Map<String, Object>{ 'dataPath' => dataPath },
                   'attributes' => new List<Object>{
                       new Map<String, Object>{
                           'attributeName' => 'SalesTrxnItemDescription',
                           'attributeValue' => fareMessage
                      }
                   }
               });
           }
               
           
           // STEP 4 - Submit context update
           if (!itemNodeUpdates.isEmpty()) {
               Map<String, Object> updateInput = new Map<String, Object>{
                   'contextId' => contextId,
                   'nodePathAndAttributes' => itemNodeUpdates
               };
               System.debug('--- PREHOOK: SUBMITTING CONTEXT UPDATE ---');
               System.debug(JSON.serializePretty(updateInput));
               industriesContext.updateContextAttributes(updateInput);
           }
   
           // Return the response
           RevSignaling.TransactionResponse response = new RevSignaling.TransactionResponse();
           response.status = RevSignaling.TransactionStatus.SUCCESS;
           response.message = 'Apex executed successfully with Price in INR: ' + fareInInr;
           return response;
       }
   }
   

사용자 정의 절차 계획 정의 구성

1. 설정에서 빠른 찾기 상자에서 절차 계획 정의를 검색하여 선택합니다.
2. 새로 만들기를 클릭합니다.
3. 다음 세부 사항을 지정합니다.
   1. 제목: Flight Booking Procedure Plan.
      탭을 눌러 개발자 이름을 자동으로 채웁니다.
   2. 프로세스 유형: Revenue Cloud.
   3. 주 목적: 견적서.
   4. 컨텍스트 정의: <Context 정의 이름>.
      사용 사례에 맞게 설계된 컨텍스트 정의를 선택해야 합니다. 그러나 가격 책정 절차를 구축할 때 사용한 컨텍스트 정의와 동일해야 합니다.
   5. 변경 사항을 저장합니다.
4. 새로 생성된 절차 계획 정의 레코드를 엽니다.
5. 절차 계획 섹션에 원하는 절차를 추가하려면 추가를 선택합니다.
6. 첫 번째 섹션을 추가하여 비행의 동적 기본 가격을 확인합니다. 다음 세부 사항을 지정합니다.
   1. 유형: 표준.
   2. 이름: DynamicBasePriceApex.
   3. 섹션 유형: Apex.
   4. 섹션이 추가되면 를 클릭하고 다음 세부 사항을 지정합니다.
      1. 단계: 가격 책정
      2. 해상도 유형: 기본값
      3. Apex: DynamicFlightBasePriceApex
      다음과 같이 표시됩니다.
      
7. 마찬가지로 다른 섹션을 추가하여 가격 책정을 계산하고 Apex 프리후크를 사용하여 생성한 가격으로 기본 가격을 재정의합니다. 다음 값을 지정합니다.
   1. 유형: 표준.
   2. 이름: FlightPriceCalculation.
   3. 섹션 유형: 가격 책정 절차 .
   4. 를 클릭하고 다음 세부 사항을 지정합니다.
      1. 단계: 가격 책정
      2. 해상도 유형: 기본값
      3. 절차: Flight_Booking_Pricing_Procedure
8. 마지막으로, 청구지 국가가 인도로 설정된 사용자를 위해 이 Apex 포스트후크를 추가하여 가격을 USD에서 INR로 변환하는 섹션을 추가합니다.
   1. 유형: 표준.
   2. 이름: ConvertFareToINR.
   3. 섹션 유형: Apex.
   4. 를 클릭하고 다음 세부 사항을 지정합니다.
      1. 단계: 가격 책정
      2. 해결 유형: 규칙 기반
      3. 조건 요구 사항: 모든 조건 충족 (AND)
      4. 자원: 청구지 국가
      5. 연산자: Equals
      6. 출력 값: 인도
      7. Apex: ConvertFareToINRApex
9. 저장한 다음, 절차 계획 정의를 활성화합니다.

절차 계획 실행 확인

설정한 순서대로 절차 계획이 실행되고 가격이 정확한지 확인하려면 견적서를 만들어야 합니다.

1. 견적서 작성
   청구지 국가 필드에 인도를 입력합니다.
2. 변경 사항을 저장합니다.
3. 캐탈로그 찾아보기 를 클릭하고 Delhi - New York 제품을 견적서에 추가합니다.
4. 순 단가 값 위로 마우스를 이동하면 가격 폭포 세부 사항이 표시됩니다.
   절차 계획의 적용과 가격 책정 절차에서 구성한 할인 및 추가 항목을 확인할 수 있습니다.
   
5. 견적서 행 항목의 변환된 요금을 보려면 견적서 행 항목 행 에서 을 클릭하고 보기를 선택합니다.
6. 행 항목 설명에 비행의 현지화된 가격이 표시됩니다.