Loading
Erweitern von Salesforce mit Klicks, ohne Code
Beispiele für Kontaktvalidierungsregeln

Sie befinden sich hier:

  1. Salesforce-Hilfe
  2. Dokumente
  3. Erweitern von Salesforce mit Klicks, ohne Code

Beispiele für Kontaktvalidierungsregeln

Validierungsregeln für verschiedene Anwendungsfälle, beispielsweise Felder für Postanschrift, Postanschrift und Postleitzahl.

Erforderliche Editionen

Verfügbarkeit: Salesforce Classic und Lightning Experience
Verfügbarkeit: Contact Manager, Group, Professional, Enterprise, Performance, Unlimited, Developer und Database.com Edition

Weitere Informationen zu den Formelfunktionen, die in diesen Beispielen verwendet werden, finden Sie unter Formeloperatoren und -funktionen.

Postanschriftfelder sind erforderlich

Feld Wert
Beschreibung: Stellt sicher, dass die Angaben Straße (Postanschrift), Stadt (Postanschrift) und Land (Postanschrift) für den Kontakt gemacht werden.
Formel: 
OR(
   ISBLANK( MailingStreet ),
   ISBLANK( MailingCity ),
   ISBLANK( MailingCountry )
)
Fehlermeldung: Straße, Stadt und Land der Postanschrift sind erforderlich.
Fehlerposition: Seitenanfang

Straße (Postanschrift) ist erforderlich

Feld Wert
Beschreibung: Stellt sicher, dass die Angabe Straße (Postanschrift) für den Kontakt gemacht wird.
Formel: 
ISBLANK( MailingStreet )
Fehlermeldung: Straße (Postanschrift) ist erforderlich.
Fehlerposition: Straße (Postanschrift)

PLZ (Postanschrift)

Feld Wert
Beschreibung: Stellt sicher, dass die PLZ (Postanschrift) für den Kontakt im Format 99999 bzw. 99999-9999 vorliegt, falls für Land (Postanschrift) USA angegeben oder keine Angabe gemacht wurde.
Formel: 
AND(
 OR(MailingCountry = "USA", ISBLANK(MailingCountry)),
  OR( 
   AND(LEN(MailingPostalCode) <>5, 
   LEN(MailingPostalCode) <> 10),
   NOT(CONTAINS("0123456789", 
      LEFT( MailingPostalCode, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 2, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 3, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 4, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 5, 1))),
   AND(
    LEN(MailingPostalCode) = 10,
   OR(
    MID( MailingPostalCode , 6, 1) <> "-",
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 7, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 8, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 9, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 10, 1)))
   )
  )
 )
)

In diesem Beispiel wird ein Land, für das keine Angabe gemacht wurde, als USA interpretiert. Um dieses Beispiel für andere Länder zu verwenden, den Satz entfernen, der die Länge des Länderfelds prüft. Außerdem wird bei den Kriterien der Validierungsregeln nach Groß- und Kleinschreibung unterschieden, sodass diese Regel nur dann erzwungen wird, wenn für das Land keine Angabe gemacht wurde oder “USA” in Großbuchstaben angegeben ist. Die Regel wird nicht erzwungen, wenn das Land “usa” ist.

Außerdem können Sie Postleitzahlen mithilfe regulärere Ausdrücke überprüfen. Ein Beispiel für eine Formel mit einem regulären Ausdruck finden Sie unter REGEX.
Fehlermeldung: Die Postleitzahl muss im Format 99999 bzw. 99999-99999 vorliegen.
Fehlerposition: Postanschrift PLZ

Telefonnummer weist internationales Format auf

Feld Wert
Beschreibung: Stellt sicher, dass die Zahl im Feld Telefon mit einem Pluszeichen (+) für den Ländercode beginnt. Beachten Sie, dass diese Validierungsregel in Konflikt mit der Regel für zehn Stellen steht.
Formel: 
LEFT(Phone, 1) <> "+"
Fehlermeldung: Die Telefonnummer muss mit + (Ländercode) beginnen.
Fehlerposition: Telefon

US-Telefonnummer weist zehn Stellen auf

Feld Wert
Beschreibung: Stellt sicher, dass die Zahl im Feld Telefon im Format (999) 999-9999 vorliegt. Hierfür wird die REGEX-Funktion eingesetzt, die sicherstellt, dass die Zahl zehn Stellen im Format (999) 999-9999 aufweist.
Formel: 
NOT(REGEX(Phone, "\\D*?(\\d\\D*?){10}"))
Fehlermeldung: US-Telefonnummern müssen in folgendem Format vorliegen: (999) 999-9999.
Fehlerposition: Telefon
 
Laden
Salesforce Help | Article