Loading
Utvide Salesforce med klikk, ikke kode
Innhold
Filtrer etter (0)Legg til
Velg filtre

          Ingen resultater
          Ingen resultater
          Her er noen søketips

          Kontroller stavemåten i søkeordene.
          Bruk mer generelle søkebegreper.
          Velg færre filtre for å utvide søket.

            Søk i all Salesforce Hjelp
            Søk i all Salesforce Hjelp
            Eksempler på valideringsregler for kontakt

            Du er her:

            1. Salesforce Hjelp
            2. Dokumenter
            3. Utvide Salesforce med klikk, ikke kode

            Eksempler på valideringsregler for kontakt

            Valideringsregler for ulike brukstilfeller, som å kreve felt for postadresse, post gateadresse og postnummer.

            Nødvendige utgaver

            Tilgjengelig i både Salesforce Classic og Lightning Experience
            Tilgjengelig i Contact Manager, Group, Professional, Enterprise, Performance, Unlimited, Developer og Database.com Edition

            Du finner flere opplysninger om alle formelfunksjonene som er brukt i disse eksemplene, under Operatorer og funksjoner i formler.

            Postadressefelt er nødvendig

            Felt Verdi
            Beskrivelse: Validerer om kontaktens Gateadresse, Poststed og Land er angitt.
            Formel: 
            OR(
   ISBLANK( MailingStreet ),
   ISBLANK( MailingCity ),
   ISBLANK( MailingCountry )
)
            Feilmelding: Gateadresse, Poststed og Land er nødvendig.
            Feilsted: Øverst på siden

            Gateadresse er nødvendig

            Felt Verdi
            Beskrivelse: Validerer om kontaktens Gateadresse er angitt.
            Formel: 
            ISBLANK( MailingStreet )
            Feilmelding: Gateadresse er nødvendig.
            Feilsted: Post, gateadresse

            Postnummer

            Felt Verdi
            Beskrivelse: Kontrollerer om kontaktens Postnummer er på formatet 9999 99999-9999 når Land er USA eller tomt.
            Formel: 
            AND(
 OR(MailingCountry = "USA", ISBLANK(MailingCountry)),
  OR( 
   AND(LEN(MailingPostalCode) <>5, 
   LEN(MailingPostalCode) <> 10),
   NOT(CONTAINS("0123456789", 
      LEFT( MailingPostalCode, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 2, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 3, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 4, 1))),
   NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 5, 1))),
   AND(
    LEN(MailingPostalCode) = 10,
   OR(
    MID( MailingPostalCode , 6, 1) <> "-",
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 7, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 8, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 9, 1))),
    NOT(CONTAINS("0123456789", 
      MID( MailingPostalCode , 10, 1)))
   )
  )
 )
)

            I dette eksemplet tolkes et tomt land som å være US Hvis du vil bruke dette eksemplet for andre land, må du fjerne betingelsen som kontrollerer lengden på feltet land. Valideringsregelkriterier skiller også mellom store og små bokstaver, så regelen håndheves bare hvis det ikke er angitt noe land, eller hvis USA er skrevet med store bokstaver. Regelen håndheves ikke hvis land er angitt som usa.

            Du kan også validere postnumre ved bruk av et alminnelig uttrykk, for eksempel en formel som bruker et regulært uttrykk. Se REGEX.
            Feilmelding: Postnummeret må være på formen 99999 eller 99999-9999
            Feilsted: Postnummer

            Telefonnummer har internasjonalt format

            Felt Verdi
            Beskrivelse: Validerer om Telefonnummeret begynner med tegnet pluss (+) for landskode. Legg merke til at denne valideringsregelen er i konflikt med tisiffersregelen.
            Formel: 
            LEFT(Phone, 1) <> "+"
            Feilmelding: Telefonnummer må begynne med + (landskode)
            Feilsted: Telefon

            Amerikanske telefonnumre har ti sifre

            Felt Verdi
            Beskrivelse: Validerer om Telefon-nummeret er på formatet (999) 999-9999. Dette virker ved å bruke REGEX-funksjonen til å kontrollere om nummeret har ti sifre på formatet (999) 999-9999.
            Formel: 
            NOT(REGEX(Phone, "\\D*?(\\d\\D*?){10}"))
            Feilmelding: Amerikanske telefonnumre skal være på formatet (999) 999-9999. (999) 999-9999
            Feilsted: Telefon
             
            Laster
            Salesforce Help | Article