Loading
Ampliar Salesforce con clics, no con programación
Reglas de validación de número de muestra

Usted está aquí:

  1. Ayuda de Salesforce
  2. Documentos
  3. Ampliar Salesforce con clics, no con programación

Reglas de validación de número de muestra

Ejemplos de cómo validar que los usuarios no pueden guardar un registro de tarjeta de tiempo con más de 40 horas en una semana laboral, los números no pueden ser negativos y los números pares o impares.

Ediciones necesarias

Disponible en: Salesforce Classic y Lightning Experience
Disponible en: Contact Manager Edition, Group Edition, Professional Edition, Enterprise Edition, Performance Edition, Unlimited Edition, Developer Edition y Database.com Edition

Si desea más información sobre cualquiera de las funciones de fórmula empleadas en estos ejemplos, consulte Operadores y funciones de fórmula.

Las fichas de tiempo deben tener en total 40 horas

Campo Valor
Descripción: Asegura que los usuarios no pueden guardar una ficha de tiempo con más de 40 horas en una semana. Este ejemplo requiere cinco campos personalizados en el objeto personalizado, uno por cada día de trabajo.
Fórmula: 
Monday_Hours__c + 
Tuesday_Hours__c + 
Wednesday_Hours__c + 
Thursday_Hours__c + 
Friday_Hours__c > 40
Mensaje de error: El total de horas no puede superar 40.
Ubicación del error: Parte superior de la página

El número no puede ser negativo

Campo Valor
Descripción: Valida que un campo personalizado denominado Horas trabajadas no sea un número negativo.
Fórmula: 
Hours_Worked__c < 0
Mensaje de error: Las horas trabajadas no pueden ser menos de cero.
Ubicación del error: Horas trabajadas

El número debe ser par

Campo Valor
Descripción: Valida que un campo personalizado denominado Pasajeros del arca sea un número par y no negativo.
Fórmula: 
OR(
   Ark_Passengers__c < 0,
   MOD( Ark_Passengers__c, 2) <> 0
)
Mensaje de error: Los pasajeros del arca deben ser un número par positivo.
Ubicación del error: Pasajeros del arca

El número debe ser impar

Campo Valor
Descripción: Valida que un campo personalizado denominado Calcetines encontrados sea un número impar y no negativo.
Fórmula: 
OR(
   Socks_Found__c < 0,
   MOD( Socks_Found__c, 2) = 0
)
Mensaje de error: Los calcetines encontrados deben ser un número impar.
Ubicación del error: Calcetines encontrados

El número debe ser un múltiplo de cinco

Campo Valor
Descripción: Valida que un campo personalizado denominado Múltiplo de 5 sea múltiplo de cinco.
Fórmula: 
MOD( Multiple_of_5__c, 5) <> 0
Mensaje de error: El número debe ser un múltiplo de cinco.
Ubicación del error: Múltiplo de 5

El número debe ser un entero

Campo Valor
Descripción: Valida que un campo personalizado denominado Mi entero sea un número entero.
Fórmula: 
FLOOR( My_Integer__c) <> My_Integer__c
Mensaje de error: Este campo debe ser un número entero.
Ubicación del error: Mi entero

El número debe tener un valor entre -50 y 50

Campo Valor
Descripción: Valida que un campo personalizado denominado Volumen tenga un valor entre -50 y 50.
Fórmula: 
ABS( Volume__c) > 50
Mensaje de error: El volumen debe tener un valor entre -50 y 50.
Ubicación del error: Volumen

Validación de intervalo de números

Campo Valor
Descripción: Valida que el intervalo entre dos campos personalizados, Salario mínimo y Salario máximo, no sea superior a 20.000 $.
Fórmula: 
(Salary_Max__c - Salary_Min__c) > 20000
Mensaje de error: El intervalo de salario debe estar dentro de 20.000 $. Ajuste los valores de salario máximo o salario mínimo.
Ubicación del error: Salario máximo

El porcentaje debe tener un valor entre cero y 100

Campo Valor
Descripción: Valida que un campo personalizado denominado Porc mixto tenga un valor entre 0 y 100%. Tenga en cuenta que los campos de porcentaje se expresan divididos entre 100 en fórmulas (100% se expresa como 1; 50% se expresa como 0,5).
Fórmula: 
OR(
   Mix_Pct__c > 1.0,
   Mix_Pct__c < 0.0
)
Mensaje de error: El porcentaje mixto debe tener un valor entre 0 y 100%.
Ubicación del error: Porc mixto
 
Cargando
Salesforce Help | Article