Loading
코드가 아닌 클릭을 통해 Salesforce 확장
샘플 기회 관리 확인 규칙

위치:

  1. Salesforce 도움말
  2. 문서
  3. 코드가 아닌 클릭을 통해 Salesforce 확장

샘플 기회 관리 확인 규칙

기회의 사용자 정의 필드 및 기타 필드를 확인하는 방법에 대한 예

필수 Edition

지원 제품: Salesforce Classic 및 Lightning Experience 모두
지원 제품: Contact Manager, Group, Professional, Enterprise, Performance, Unlimited, Developer 및 Database.com Edition

이러한 예에서 사용되는 수식 함수에 대한 자세한 내용은 수식 연산자 및 함수를 참조하십시오.

기회 단계에 따른 조건부 필수 필드

필드 값
설명: 기회가 완료됨 - 수주 또는 협상/검토 단계로 진행된 경우 배달 날짜 사용자 정의 필드가 제공되는지 확인합니다.
수식: 
AND (
  OR (
     ISPICKVAL(StageName, "Closed Won"),
     ISPICKVAL(StageName, "Negotiation/Review")),
ISBLANK(Delivery_Date__c)
)
오류 메시지: 배달 날짜는 이 단계의 필수 항목입니다.
오류 위치: 배달 날짜

완료 날짜는 반드시 현재 월 이후

필드 값
설명: 기회의 완료 날짜가 현재 월보다 이전 월에 속하지 않는지 확인합니다. 기회가 만들어지거나 완료 날짜 필드가 나중에 수정되는 경우에만 조건을 확인하도록 이 수식에서는 ISNEW 및 ISCHANGED 필드를 사용합니다.
수식: 
AND(
  OR (
     ISNEW(),
     ISCHANGED( CloseDate )),
  CloseDate < DATE( YEAR(TODAY()), MONTH(TODAY()), 1) )
오류 메시지: 완료 날짜는 현재 월보다 이전일 수 없습니다.
오류 위치: 완료 일자

완료 날짜는 미래 날짜여야 합니다.

필드 값
설명: 사용자가 기회의 완료 날짜를 과거 날짜로 변경하지 않도록 합니다.
수식: 
SampleDate < TODAY()
오류 메시지: 완료 날짜는 과거 날짜가 될 수 없습니다.
오류 위치: 완료 일자

기회에 대한 할인

필드 값
설명: 사용자 정의 할인율 필드가 0과 40% 사이인지 확인합니다.
수식: OR(Discount_Rate__c < 0, Discount_Rate__c > 0.40)
오류 메시지: 할인율은 40%를 넘을 수 없습니다.
오류 위치: 할인율

중요한 기회는 반드시 마감 이전에 승인 필요

필드 값
설명: 금액이 $50,000보다 큰 기회인 경우 완료됨 - 수주 또는 완료됨 - 실패로 단계를 변경하려면 승인됨 사용자 정의 확인란 필드를 선택해야 합니다. 이 과정을 자동화하려면 승인됨 확인란의 필드 수준 보안을 사용자 정의 승인 프로세스를 통해서만 확인할 수 있도록 설정합니다(Enterprise Edition, Unlimited Edition 또는 Performance Edition).
수식: 
AND(
   OR(
      ISPICKVAL(StageName,"Closed Won"),
      ISPICKVAL(StageName,"Closed Lost")),
(Amount > 50000),
NOT(ISPICKVAL(Approval_Status__c ,"Approved")))
오류 메시지: 모든 중요한 기회는 마감하려면 승인이 필요합니다. 마감 요청 단추를 클릭합니다.
오류 위치: 페이지 맨 위

기회 금액은 반드시 100억 달러 이하

필드 값
설명: 기회 금액이 양수이고 100억 달러를 초과하지 않는지 확인합니다. 이 제한은 오타를 식별하기 위한 것입니다.
수식: 
OR(
   Amount < 0,
   Amount > 10000000
)
오류 메시지: 금액은 100억 달러를 초과할 수 없습니다.
오류 위치: 금액

제품에 대한 기회 확인

필드 값
설명: 사용자가 기회에 대한 변경 사항을 저장하려면 기회에 하나 이상의 기회 제품이 있어야 합니다.
수식: 
NOT(OR(ISNEW(),HasOpportunityLineItem))
오류 메시지: 저장하기 전에 제품을 이 기회에 추가해야 합니다.
오류 위치: 페이지 맨 위

“수요 분석” 단계 이후인 경우 기회에 제품 필요

필드 값
설명: 단계가 수요 분석 이후 단계로 이동하려면 기회에 기회 제품이 있어야 합니다.
수식: 
AND (
  CASE( StageName,
     "Value Proposition", 1,
     "Id. Decision Makers", 1,
     "Perception Analysis", 1,
     "Proposal/Price Quote", 1,
     "Negotiation/Review", 1,
     "Closed Won", 1,
     0) = 1,
  NOT(HasOpportunityLineItem)
)
오류 메시지: 수요 분석 단계 이후로 진행하려면 기회 제품이 필요합니다.
오류 위치: 페이지 맨 위

기회 이름 형식

필드 값
설명: “[Account] – [Amount]” 기회 명명 규칙을 적용하는 방법으로 기회에 하이픈이 포함되어 있는지 확인합니다.
수식: 
FIND( " - ", Name ) = 0
오류 메시지: 기회 이름은 “[Account] - [Amount]” 형식을 사용해야 합니다.
오류 위치: 기회 이름

판매 담당자가 기회 단계를 뒤로 이동하지 못하도록 금지

필드 값
설명: 사용자 정의 승인 프로세스를 통해 기회를 승인한 경우 판매 담당자가 기회 단계를 특정 값 “이전” 단계로 변경하지 못하도록 금지합니다. 승인 프로세스에서는 사용자 정의 승인됨 플래그 확인란을 True로 설정합니다.
수식: 
AND(
   Accepted_Flag__c,
   OR ( ISPICKVAL( StageName, "Stage 1"), ISPICKVAL( StageName, "Stage 2"))
)
오류 메시지: 승인된 기회에 대한 단계가 잘못되었습니다.
오류 위치: 단계

수주한 기회에 대한 성공 확률은 반드시 100%

필드 값
설명: 수주한 기회에 대한 성공 확률이 100%로 제대로 설정되어 있는지 확인합니다. 이는 데이터를 정리 및 보고하는 데 유용합니다.
수식: 
AND (
     ISPICKVAL( StageName, "Closed Won"),
     Probability <> 1)
오류 메시지: 수주한 기회에 대한 성공 확률은 100%이어야 합니다.
오류 위치: 성공 확률

실패한 기회에 대한 성공 확률은 반드시 0

필드 값
설명: 실패한 기회에 대한 성공 확률이 0으로 제대로 설정되어 있는지 확인합니다. 이는 데이터를 정리 및 보고하는 데 유용합니다.
수식: 
AND (
     ISPICKVAL( StageName, "Closed Lost"),
     Probability <> 0)
오류 메시지: 실패한 기회에 대한 성공 확률은 0%이어야 합니다.
오류 위치: 성공 확률

프로젝트 시작 일자

필드 값
설명: 다른 필드의 값에 따라 필드가 조건부로 필요한지 확인합니다. 이 확인 수식을 사용하여 완료됨/수주 기회에 대해 사용자가 프로젝트 시작 일자를 포함했는지 확인합니다.
수식: 
AND(ISPICKVAL(StageName, "Closed Won"),
  ISNULL(Project_Start_Date__c))
오류 메시지: 수주된 기회에는 프로젝트 시작 일자가 필요합니다.
오류 위치: 프로젝트 시작 일자
 
로드 중
Salesforce Help | Article