Amostras de regras diversas de validação

PRIORVALUE(Commit_Amount__c) > Commit_Amount__c

AND(
MailingState = "CA",
NOT(REGEX(Drivers_License__c, "([A-Z]\\d{7})?"))
)

AND(
    NOT( I_accept_terms__c  ),
    Number_of_Days__c > $User.PTO_Balance__c
)

AND(
   NOT( ISNEW() ),
   ISCHANGED( Guaranteed_Rate__c )
)

Verifica se um campo de texto personalizado chamado CPF tem o formato numérico 999-99-9999 (se não estiver em branco). O padrão especifica:

• Três dígitos (0-9):\\d{3}
• Um traço
• Dois dígitos (0-9):\\d{2}
• Um traço
• Quatro dígitos (0-9):\\d{4}

NOT(
OR(
ISBLANK(Social_Security_Number__c),
REGEX( Social_Security_Number__c , "[0-9]{3}-[0-9]{2}-[0-9]{4}")
)
)

CASE(CurrencyIsoCode,
  "USD", 1,
  "EUR", 1,
  "GBP", 1,
  "JPY", 1,
   0) = 0

Verifica se um campo de texto personalizado chamado Número do cartão de crédito tem o formato numérico 9999-9999-9999 ou 9999999999999999, se não estiver em branco. O padrão especifica:

• Quatro dígitos (0-9) seguidos de um traço: \\d{4}-
• O padrão acima mencionado é repetido três vezes, agrupando-o em {3}
• Quatro dígitos (0-9)
• O caractere OR (|) permite um padrão alternativo de 16 dígitos, de zero a nove, sem traços: \\d{16}

NOT( REGEX( Credit_Card_Number__c , "(((\\d{4}-){3}\\d{4})|\\d{16})?"))

NOT(
REGEX( IP_Address__c,
"^((25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\\.)
{3}(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)$" ))

AND(
   RIGHT( Web_Site__c, 4) <> ".COM",
   RIGHT( Web_Site__c, 4) <> ".com",
   RIGHT( Web_Site__c, 4) <> ".ORG",
   RIGHT( Web_Site__c, 4) <> ".org",
   RIGHT( Web_Site__c, 4) <> ".NET",
   RIGHT( Web_Site__c, 4) <> ".net",
   RIGHT( Web_Site__c, 6) <> ".CO.UK",
   RIGHT( Web_Site__c, 6) <> ".co.uk"
)