Loading
通过单击（而不是节点）展开 Salesforce
其他示例验证规则

您在此处：

  1. Salesforce 帮助
  2. 文档
  3. 通过单击（而不是节点）展开 Salesforce

其他示例验证规则

有关如何验证信用卡号码或驾照的某些数字格式的示例。

所需的 Edition

适用于 Salesforce Classic 和 Lightning Experience
适用于：Contact Manager、Group、Professional、Enterprise、Performance、Unlimited、Developer 和 Database.com Edition

有关这些示例中使用的任何公式函数的详细信息，请参阅按上下文划分的公式运算符和函数。

允许数字增加，但不允许减少

字段 值
说明： 允许名为提交金额的自定义字段在初次创建后增加，但不允许减少。该规则使用 PRIORVALUE() 函数将字段的更新值与更新前的字段值进行比较。
公式： 
PRIORVALUE(Commit_Amount__c) > Commit_Amount__c
错误消息： 提交金额不能减少。
错误位置： 提交金额

加州驾驶执照

字段 值
说明： 在邮寄地址 - 州为加州（“CA”）时，确保名为驾驶执照的自定义字段具有正确的 A9999999 格式。
公式： 
AND(
MailingState = "CA",
NOT(REGEX(Drivers_License__c, "([A-Z]\\d{7})?"))
)
错误消息： 无效的加州驾驶执照格式。
错误位置： 驾驶执照

强制用户选取“我接受条款”以输入特定值

字段 值
说明： 使用标记为“我接受条款”的复选框强制用户选取复选框，以便用户输入超过其带薪假期 (PTO) 剩余可用天数的名为天数的一个值。
公式： 
AND(
    NOT( I_accept_terms__c  ),
    Number_of_Days__c > $User.PTO_Balance__c
)
错误消息： 请求会导致 PTO 负剩余天数。您必须接受“PTO 负剩余天数”条款。
错误位置： 我接受条款

禁止在字段保存后更改字段

字段 值
说明： 防止用户在第一次保存名为承诺价格的自定义字段后对该字段执行更改。
公式： 
AND(
   NOT( ISNEW() ),
   ISCHANGED( Guaranteed_Rate__c )
)
错误消息： 承诺价格无法更改。
错误位置： 承诺价格

社会保险编号的格式

字段 值
说明：

验证名为 SSN 的自定义文本字段的格式是 999-99-9999 数字格式（如果非空）。该模式规定：

  • 三个十进制数字 (0-9):\\d{3}
  • 一个连字符
  • 两个十进制数字 (0-9):\\d{2}
  • 一个连字符
  • 四个十进制数字 (0-9):\\d{4}
公式： 
NOT(
OR(
ISBLANK(Social_Security_Number__c),
REGEX( Social_Security_Number__c , "[0-9]{3}-[0-9]{2}-[0-9]{4}")
)
)
错误消息： SSN 必须为此格式：999-99-9999。
错误位置： SSN

有效币种

字段 值
说明： 通过使用币种选项列表验证选定币种是否明确属于贵组织内的有效币种的子集。对于某些特定类型的记录，如果您仅允许应用组织内的某些有效货币，请使用此示例。
公式： 
CASE(CurrencyIsoCode,
  "USD", 1,
  "EUR", 1,
  "GBP", 1,
  "JPY", 1,
   0) = 0
错误消息： 货币必须为 USD、EUR、GBP 或 JPY。
错误位置： 币种

有效的信用卡号码

字段 值
说明：

验证名为信用卡号码的自定义文本字段的格式为 9999-9999-9999-9999 或 9999999999999999 数字格式（如果非空）。该模式规定：

  • 四个十进制数字 (0-9) 后跟一个连字符：\\d{4}-
  • 上述模式重复三次，用 {3} 包装
  • 四个十进制数字 (0-9)
  • “或”字符 (|) 允许 16 位十进制数字 (0-9)，且中间无连字符：\\d{16}
公式： 
NOT( REGEX( Credit_Card_Number__c , "(((\\d{4}-){3}\\d{4})|\\d{16})?"))
错误消息： 信用卡号码格式应为：9999-9999-9999-9999 或 9999999999999999。
错误位置： 信用卡号码

有效的 IP 地址

字段 值
说明： 确保名为 IP 地址的自定义字段具有正确的格式：四组三位十进制数字 (0-255)，每组之间以句点格开。
公式： 
NOT(
REGEX( IP_Address__c,
"^((25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\\.)
{3}(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)$" ))
错误消息： 错误：IP 地址必须为 999.999.999.999 格式，且每个部分为从 0 到 255 的数字。
错误位置： IP 地址

网址扩展名

字段 值
说明： 验证名为网址的自定义字段，以确保其最后四位字符明确属于有效网址扩展名集合。
公式： 
AND(
   RIGHT( Web_Site__c, 4) <> ".COM",
   RIGHT( Web_Site__c, 4) <> ".com",
   RIGHT( Web_Site__c, 4) <> ".ORG",
   RIGHT( Web_Site__c, 4) <> ".org",
   RIGHT( Web_Site__c, 4) <> ".NET",
   RIGHT( Web_Site__c, 4) <> ".net",
   RIGHT( Web_Site__c, 6) <> ".CO.UK",
   RIGHT( Web_Site__c, 6) <> ".co.uk"
)
错误消息： 网址的扩展名必须为 .com、.org、.net 或 .co.uk。
错误位置： 网址
 
正在加载
Salesforce Help | Article