Loading
Utöka Salesforce med klick och inte kod
Exempel valideringsregler för användare, roll och profil

Du är här:

  1. Salesforce-hjälp
  2. Dokument
  3. Utöka Salesforce med klick och inte kod

Exempel valideringsregler för användare, roll och profil

Exempel på hur du validerar egna användar-, roll- och profilfält.

Versioner som krävs

Tillgängliga i: både Salesforce Classic och Lightning Experience
Tillgängliga i: Utgåvorna Contact Manager, Group, Professional, Enterprise, Performance, Unlimited, Developer och Database.com

Mer information om formelfunktioner som används i de här exemplen, se Formel Operatörer och funktioner.

Rabattprocentvärdet får inte överskrida rollbaserad begränsning

Fält Värde
Beskrivning: Kontrollerar att värdet i det egna säljprojektfältet Rabattprocent inte överstiger ett maxvärde som baseras på användarrollen. Standardmaxvärdet är 15 %.
Formel: 
Discount_Percent__c > VLOOKUP(
    $ObjectType.Role_Limits__c.Fields.Limit__c,
    $ObjectType.Role_Limits__c.Fields.Name, 
    $UserRole.Name
)
Felmeddelande: Rabattprocentsatsen är högre än det tillåtna värdet för din roll.
Felplats: Rabattprocent

Utgiftsbeloppet får inte vara högre än användarens högsta tillåtna utgift

Fält Värde
Beskrivning: Jämför värdet i det egna fältet Utgiftsbelopp med värdet i det egna fältet Tillåten maxutgift.
Formel: 
Expense_Amount__c > $User.Max_Allowed_Expense__c
Felmeddelande: Beloppet får inte vara högre än värdet för högsta tillåtna utgift.
Felplats: Utgiftsbelopp

Bara postägaren kan ändra fältet

Fält Värde
Beskrivning: Säkerställer att bara postägaren kan ändra det egna fältet Personal goal.
Formel: 
AND(
   ISCHANGED( Personal_Goal__c ),
   Owner <> $User.Id 
)
Felmeddelande: Bara postägaren kan ändra värdet i fältet för personligt mål.
Felplats: Personligt mål

Bara postägaren eller administratören kan ändra fältet

Fält Värde
Beskrivning: Säkerställer att en användare endast kan göra ändringar i ett eget fält kallat Personligt mål om användaren är postägaren eller har en egen profil i “Egen: systemadmin”.
Formel: 
AND(
    ISCHANGED( Personal_Goal__c ), 
    Owner <> $User.Id, 
    $Profile.Name <> "Custom: System Admin" 
)

$Profile-kopplingsfält är endast tillgängliga i utgåvorna Enterprise, Unlimited, Performance och Developer.
Felmeddelande: Bara postägaren och administratörer kan ändra värdet i fältet för personligt mål.
Felplats: Personligt mål

Bara administratörer kan bakåtdatera avslutsdatumet för säljprojekt

Fält Värde
Beskrivning: Kontrollerar att datumet i säljprojektfältet Avslutsdatum inte infaller före den innevarande månaden, utom för användare som är kopplade till den egna profilen ”Egen: systemadmin”.
Formel: 
AND(
  OR (
     ISNEW(), 
     ISCHANGED( CloseDate )), 
  CloseDate < DATE( YEAR(TODAY()), MONTH(TODAY()), 1),
   $Profile.Name <> "Custom: System Admin"
)

$Profile-kopplingsfält är endast tillgängliga i utgåvorna Enterprise, Unlimited, Performance och Developer.
Felmeddelande: Avslutsdatumet får inte infalla före den innevarande månaden.
Felplats: Avslutsdatum
 
Laddar
Salesforce Help | Article