Fórmulas de gestión de contactos de muestra

Si desea información detallada sobre el uso de funciones incluidas en estas muestras, consulte Operadores y funciones de fórmulas.

Porcentaje de descuento de cuenta de contacto

Esta fórmula de porcentaje muestra el campo Porcentaje de descuento en la página de contactos.

Account.Discount_Percent__c

Nombre de la cuenta del contacto

Esta fórmula de porcentaje muestra el campo Nombre de la cuenta estándar en la página de contactos.

Account.Name

Teléfono de la cuenta del contacto

Esta fórmula muestra el campo Teléfono de la cuenta estándar en la página de contactos.

Account.Phone

Valoración de la cuenta del contacto

Use esta fórmula para mostrar el campo Valoración de la cuenta en la página de contactos.

CASE(Account.Rating, "Hot", "Hot", "Warm", "Warm", "Cold", "Cold", "Not Rated")

Sitio web de la cuenta del contacto

Esta fórmula muestra el campo Sitio web de la cuenta estándar en la página de contactos.

Account.Website

IF(Account.Website="", "",
	IF(
		OR(LEFT(Account.Website, 7) = "http://",LEFT(Account.Website, 8) = "https://"), 
		HYPERLINK( Account.Website , "Click Here" ), 
		HYPERLINK( "https://" & Account.Website , "Click Here" )
	)
)

Esta fórmula también agrega el "https://" necesario antes de una URL si “http://” o “https://” no se incluyó anteriormente en el campo de URL.

Perfil de LinkedIn™ del contacto

Puede configurar un vínculo que aparece en la página de perfil de su contacto y que le envía a su perfil de LinkedIn. Para ello:

1. Desde los parámetros de gestión de objetos para contactos, vaya a Botones, Vínculos y Acciones.
2. Haga clic en Botón o vínculo nuevo.
3. Escriba una Etiqueta para este vínculo, como VínculoLinkedIn.
4. Ingrese esta fórmula el cuadro de contenido:

   https://www.linkedin.com/search/fpsearch?type=people&keywords
   ={!Contact.FirstName}+{!Contact.LastName} 

5. Haga clic en Guardar.

Recuerde agregar este vínculo al formato de la página Contacto para que aparezca.

Número de identificación del contacto

Esta fórmula muestra los cinco primeros caracteres del nombre y los cuatro últimos caracteres de un número de seguridad social separados por un guión. Este ejemplo utiliza un campo personalizado de texto denominado SSN.

TRIM(LEFT(LastName, 5)) &
                    "-" & TRIM(RIGHT(SSN__c, 4))

Teléfono de contacto preferido

Esta fórmula muestra el método de contacto preferido del contacto en una lista relacionada de contactos (teléfono del trabajo, de casa o móvil) en función de una opción seleccionada en la lista de selección personalizada Teléfono preferido.

CASE(Preferred_Phone__c, 
"Work", "w. " & Phone, 
"Home", "h. " & HomePhone, 
"Mobile", "m. " & MobilePhone, 
"No Preferred Phone")

Prioridad de contacto

Esta fórmula evalúa la importancia de un contacto en función de la valoración de la cuenta y el título del contacto. Si la valoración de la cuenta es Hot o el título contiene la palabra Executive, la prioridad es alta (P1). Si la valoración de la cuenta es Warm o el título comienza por VP, la prioridad será media (P2), y si la valoración es Cold, la prioridad será baja (P3).

IF(OR(ISPICKVAL(Account.Rating, "Hot"), CONTAINS(Title, "Executive")), "P1", 

IF(OR(ISPICKVAL(Account.Rating, "Warm"), CONTAINS(Title, "VP")), "P2", 

IF(ISPICKVAL(Account.Rating, "Cold"), "P3", 

"P3")
)
)

Id. de Yahoo! ID

Esta fórmula muestra un icono de Yahoo! Messenger interactivo que indica si la persona está conectada al servicio. Los usuarios pueden hacer clic en el icono para iniciar una plática mediante Yahoo! Messenger con esa persona. Este ejemplo utiliza un campo de texto personalizado llamado Yahoo Name en los contactos donde puede almacenar el Id. de usuario de Yahoo! Messenger.

HYPERLINK("ymsgr:sendIM?" & Yahoo_Name__c,
                    IMAGE("https://opi.yahoo.com/online?u=" & Yahoo_Name__c &
                    "&m;=g&t;=0", "Yahoo"))

Formato de dirección dinámica

Este campo de fórmula muestra una dirección de envío con formato para un contacto en formato estándar, incluyendo los espacios y saltos de línea adecuados dependiendo del país.

CASE(ShippingCountry, 
"USA", 
  ShippingStreet & BR() &
  ShippingCity & ", 
  " & ShippingState & " " & 
  ShippingPostalCode & BR() 
  & ShippingCountry, 
"France", 
  ShippingStreet & BR() & 
  ShippingPostalCode & " " & 
  ShippingCity & BR() & 
  ShippingCountry, "etc")

Código de país de teléfono

Esta fórmula determina el código telefónico de país de un contacto en función de Dirección postal: País de la dirección de correo.

CASE(MailingCountry, 
"USA", "1", 
"Canada", "1", 
"France", "33", 
"UK", "44", 
"Australia", "61", 
"Japan", "81", 
"?")

Número de teléfono sin formato

Esta fórmula elimina el paréntesis y los caracteres de guión de los números de teléfono en EE. UU. Esta fórmula es necesaria para algunos programas de software de marcación automática.

IF(Country_Code__c = "1", MID( Phone ,2, 3) & MID(Phone,7,3) & MID(Phone,11,4), Phone)