Fórmulas de vínculos de imágenes de muestra

Si desea información detallada sobre el uso de funciones incluidas en estas muestras, consulte Operadores y funciones de fórmulas por contexto.

Búsqueda en Yahoo! Instant Messenger™

Esta fórmula muestra una imagen que indica si un contacto o usuario ha iniciado sesión en Yahoo! Instant Messenger. Al hacer clic en la imagen se inicia la ventana de Yahoo! Instant Messenger. Esta fórmula usa un campo de texto personalizado llamado Nombre de Yahoo para almacenar el Id. de Yahoo! del usuario o contacto.

IF(ISBLANK(Yahoo_Name__c),"", HYPERLINK("ymsgr:sendIM?" & Yahoo_Name__c, 
IMAGE("http://opi.yahoo.com/online?u=" & Yahoo_Name__c & "&m=g&t=0", " ")))

Etiquetas para prioridad de casos

Esta fórmula muestra una imagen de etiqueta verde, amarilla o roja que indica la prioridad de un caso.

IMAGE( 
CASE( Priority, 
"Low", "/img/samples/flag_green.gif",
"Medium", "/img/samples/flag_yellow.gif",
"High", "/img/samples/flag_red.gif", 
"/s.gif"), 
"Priority Flag")

Cuadrados de color para antigüedad de un caso

Este fórmula muestra una imagen de 30 x 30 píxeles en rojo, amarillo o verde en función del valor de un campo numérico personalizado Antigüedad de caso.

IF( Case_Age__c > 20, 
IMAGE("/img/samples/color_red.gif", "red", 30, 30),
IF( Case_Age__c > 10,
IMAGE("/img/samples/color_yellow.gif", "yellow", 30, 30),
IMAGE("/img/samples/color_green.gif", "green", 30, 30)
))

Semáforos de estado

Esta fórmula muestra la imagen de un semáforo en verde, amarillo o rojo para indicar el estado, usando un campo de lista de selección personalizado llamado Estado del proyecto. Use esta fórmula en vistas de lista y reportes para crear una vista de tablero “Resumen de estado”.

IMAGE( 
CASE(Project_Status__c, 
"Green", "/img/samples/light_green.gif",
"Yellow", "/img/samples/light_yellow.gif",
"Red", "/img/samples/light_red.gif", 
"/s.gif"), 
"status color")

Estrellas de valoración

Esta fórmula muestra un conjunto de una a cinco estrellas para indicar un puntuaje o valoración.

IMAGE( 
CASE(Rating__c, 
"1", "/img/samples/stars_100.gif",
"2", "/img/samples/stars_200.gif",
"3", "/img/samples/stars_300.gif", 
"4", "/img/samples/stars_400.gif", 
"5", "/img/samples/stars_500.gif", 
"/img/samples/stars_000.gif"), 
"rating")

Consumer Reports™: círculos de color de estilo para las valoraciones

Esta fórmula muestra un círculo de color para indicar una valoración en una escala de uno a cinco, donde el rojo completo es uno, medio rojo es dos, el contorno negro es tres, medio negro es cuatro y negro completo es cinco.

IMAGE( 
CASE(Rating__c, 
"1", "/img/samples/rating1.gif",
"2", "/img/samples/rating2.gif",
"3", "/img/samples/rating3.gif", 
"4", "/img/samples/rating4.gif", 
"5", "/img/samples/rating5.gif", 
"/s.gif"), 
"rating") 

Barras horizontales para indicar el puntuaje

Esta fórmula muestra un barra de color horizontal (verde sobre fondo blanco) de una longitud proporcional a un puntuaje numérico. En este ejemplo, la longitud máxima de la barra es de 200 píxeles.

IMAGE("/img/samples/color_green.gif", "green", 15, Industry_Score__c * 2) & 
IMAGE("/s.gif", "white", 15, 
200 - (Industry_Score__c * 2))