Loading
Salgsproduktivitet
Fjerne prospekter fra kadenser automatisk med Prosessbygger og Apex

Du er her:

  1. Salesforce Hjelp
  2. Dokumenter
  3. Sælgerproduktivitet

Fjerne prospekter fra kadenser automatisk med Prosessbygger og Apex

Lagre selgerne et trinn når de oppdager at et prospekt ikke er klart til å kjøpes. Opprett en Apex og en prosess for å automatisk fjerne prospekter når representanter endrer statusen sin til Ukvalifisert.

Nødvendige utgaver

Tilgjengelig i Lightning Experience
Tilgjengelig med Sales Engagement, som er inkludert i Sales in Performance, Einstein 1 og Unlimited Edition, og tilgjengelig mot en ekstra kostnad i Professional og Enterprise Edition. Salgsengasjement er også tilgjengelig mot en ekstra kostnad i Service og Lightning Platform.
Nødvendige brukertillatelser
For å opprette, redigere eller vise prosesser:

Behandle flyt

OG

Vise alle data
For å definere Apex-utløsere: Forfatter for Apex
For å fjerne prospekter fra kadenser:

Salgsengasjementsbruker eller Salgsengasjementsbruker inkludert

ELLER

Opprett salgsengasjementskadens ELLER Salgsengasjementsbruker inkludert
Merk
Merk Du kan ikke legge til Apex direkte i Salesforce-produksjonsorganisasjoner. Bare Developer-, Trial- og Sandbox-organisasjoner støtter direkte Apex i Oppsett. Hvis du vil distribuere Apex i en produksjonsorganisasjon, legger du den først til i en Sandbox-organisasjon, tester den og promoterer den deretter til produksjonsorganisasjonen.

Dette eksemplet bruker RemoveTargetFromSalesCadence-handlingen. Du kan også bygge prosesser med AssignTargetToSalesCadence-handlingen.

Angi at prosessen skal starte når poster opprettes eller redigeres.

  1. Opprett Apex.
    1. Velg Developer Console fra Oppsett-menyen.
    2. Velg Ny | Apex-klasse fra Fil-menyen.
    3. Skriv inn FremoveTargetFromSalesCadence som klassenavn. Klikk på OK.
    4. I Developer Console erstatter du koden du ser, med følgende Apex. 
      public class RemoveTargetFromSalesCadence {

   @InvocableMethod(label='Remove Target From Cadence' description='Uses REST Invocable Action to remove a Target to a Cadence')
   public static void removeTarget(List<RemoveTargetRequest> targetsToRemove) {
       System.debug('*** Targets to remove *** ' + targetsToRemove);
       if (targetsToRemove != null) {
           for (RemoveTargetRequest req : targetsToRemove) {
               System.debug('*** request *** ' + req);
               System.debug('\ttarget: ' + req.targetId);
               System.debug('\tcompletion reason code: ' + req.completionReasonCode);
               sendRequest(req.targetId, req.completionReasonCode);
           }
       } else {
           System.debug('*** null targetsToRemove received ***');
       }
   }

   @future(callout = true)
   private static void sendRequest(String targetId, String completionReasonCode) {
       String sfdcURL = URL.getSalesforceBaseUrl().toExternalForm();
       String actionsRestURL = sfdcURL + '/services/data/v45.0/actions';
       String removeTargetRESTUrl = actionsRestURL + '/standard/removeTargetFromSalesCadence';

       HttpRequest httpReq = new HttpRequest();
       httpReq.setMethod('POST');
       httpReq.setHeader('Authorization', 'OAuth ' + UserInfo.getSessionId());
       httpReq.setHeader('Authorization', 'Bearer ' + UserInfo.getSessionId());
       httpReq.setEndpoint(removeTargetRESTUrl);
       httpReq.setHeader('Content-Type', 'application/json');
       httpReq.setBody('{"inputs" : [{"completionReasonCode" : "' + completionReasonCode + '", "targetId" : "' + targetId + '"}]}');

       String response = '';
       try {
           Http http = new Http();
           HttpResponse httpResponse = http.send(httpReq);
           if (httpResponse.getStatusCode() == 200) {
               response = JSON.serializePretty(JSON.deserializeUntyped(httpResponse.getBody()));
           } else {
               System.debug('http response: ' + httpResponse.getBody());
               throw new CalloutException(httpResponse.getBody());
           }
       } catch (System.Exception e) {
           System.debug('ERROR! ' + e);
           throw e;
       }

       System.debug('response: ' + response);
   }

   public class RemoveTargetRequest {
       @InvocableVariable(required=true)
       public Id targetId;

       @InvocableVariable(required=true)
       public String completionReasonCode;
   }
}
    5. Lagre Apex.
  2. Opprett en prosess.
    1. Skriv inn Process Builder i Hurtigsøk-feltet i Oppsett. Klikk deretter på Prosessbygger.
    2. Klikk på Ny.
    3. Gi prosessen et navn.
    4. Klikk på Prosessen starter når, og velg En post endres.
    5. Klikk på Lagre.
    6. Klikk på Legg til objekt-noden i Prosessbygger.
    7. Velg Salgsemne, Kontakt eller Personkonto fra Objekt-menyen i høyre rute.
    8. Velg når en post opprettes eller redigeres under Start prosessen.
    9. Klikk på Lagre.
    10. Klikk på +Legg til kriterier-noden i Prosessbygger.
    11. Gi kriteriene et navn i høyre rute.
      Kall det for eksempel noe som utløser kadensfjerning.
    12. Klikk på Formel evalueres til sann under Kriterier for utførelse av handlinger.
    13. Sett inn følgende formel under Bygg formel. 
      NOT(ISNEW()) && ISPICKVAL([Lead].Status,"Unqualified")
      NOT(ISNEW())-setningen brukes til å evaluere poster som ikke har blitt lagt til nylig i organisasjonen. Denne kodeblokken forutsetter også at du vil bruke Salgsemnestatus-verdien Ikke kvalifisert som kriterier for fjerning av et salgsemne fra kadenser. Erstatt denne verdien (eller dette feltet) slik at den passer til dine egne forretningsprosesser.
    14. Klikk på Lagre.
    15. Klikk på +Legg til handling i Noden Umiddelbare handlinger til høyre for kriterienoden du nettopp la til.
    16. Velg disse innstillingene i høyre rute.
      • Action Type (Handlingstype): Apex
      • Handlingsnavn: Skriv inn et navn på handlingen.
      • Apex Class (Apex-klasse): Velg Apex du opprettet tidligere.
      • CompletionReasonCode: Skriv inn ManuallyRemoved i Verdi.
      • TargetId : Velg Feltreferanse i Type. I Verdi klikker du på feltet og søker etter Lead.Id, Contact.Id eller Account.Id avhengig av om du vil fjerne salgsemne-, kontakt- eller personkontoposter fra kadensen.
    17. Klikk på Lagre.
    18. Klikk på Aktiver og deretter på Bekreft.
 
Laster
Salesforce Help | Article