Loading
Agentforce Field Service und Vorgänge
Anwendungsfälle zum Priorisieren von Field Service-Terminen

Sie befinden sich hier:

  1. Salesforce-Hilfe
  2. Dokumente
  3. Agentforce Field Service und Vorgänge

Anwendungsfälle zum Priorisieren von Field Service-Terminen

Eine effektive Priorisierung ist in Salesforce Field Service entscheidend, um die Ressourcenzuteilung zu optimieren, wenn die Kapazität Ihres Teams begrenzt ist. Sehen Sie sich die Anwendungsfälle an, um zu erfahren, wie Sie Serviceterminprioritäten definieren und sicherstellen, dass die wichtigsten Arbeiten umgehend bearbeitet werden.

Salesforce Field Service unterstützt eine Prioritätsskala von 1 bis 100. Sie sollten jedoch mit der Standardskala von 1 bis 10 beginnen. Dieser Bereich bietet genügend Granularität für die meisten Anwendungsfälle und vereinfacht die anfängliche Konfiguration.

Sie können die Serviceterminpriorität mit verschiedenen Methoden festlegen.

  • Formeln: Erstellen Sie Formelfelder im Objekt "Servicetermin", um die Priorität anhand anderer Daten zu berechnen.
  • Automatisierung: Verwenden Sie Tools wie Flow oder Apex Code, um die Priorität dynamisch zu aktualisieren.

Formelfeldbeispiele werden hier zur Verdeutlichung verwendet. Die zugrunde liegenden Prinzipien gelten jedoch auch für automatisierungsbasierte Ansätze.

Beispiel 1: (Grundlegendes) Priorisieren nach Fälligkeitsdatum

Ein Unternehmen möchte Servicetermine nur anhand ihrer Fälligkeit priorisieren, indem es eine detailliertere Aufschlüsselung der Priorität verwendet.

  • Termine, die innerhalb eines Tages fällig werden, erhalten Priorität 1 (höchste).
  • Termine, die innerhalb von drei Tagen fällig werden, erhalten Priorität 2.
  • Termine, die innerhalb von fünf Tagen fällig werden, erhalten Priorität 3.
  • Termine, die innerhalb von sieben Tagen fällig werden, erhalten Priorität 4.
  • Termine, die innerhalb von 14 Tagen fällig werden, erhalten Priorität 5.
  • Alle anderen Termine erhalten Priorität 6 (niedrigster Wert).

Verwenden Sie diese Formel, um sicherzustellen, dass Termine rechtzeitig abgeschlossen werden, Service Level Agreements (SLAs) eingehalten werden und eine detailliertere Priorisierung anhand von DueDate (einem Standardfeld im Objekt "Servicetermin") erfolgt. 

IF( DueDate - TODAY() < 1, 1,
  IF( DueDate - TODAY() < 3, 2,
    IF( DueDate - TODAY() < 5, 3,
      IF( DueDate - TODAY() < 7, 4,
        IF( DueDate - TODAY() < 14, 5, 6)
      )
    )
  )
)

Beispiel 2: (Mittelstufe) Priorisieren nach Arbeitstyp

Ein Unternehmen möchte Servicetermine anhand der Art der ausgeführten Arbeit priorisieren.

  • Notfallreparatur erhält Priorität 1 (höchste).
  • Die Installation erhält Priorität 2.
  • Vorbeugende Wartung erhält Priorität 4.
  • Routineprüfung erhält Priorität 5.
  • Jeder andere Arbeitstyp erhält Priorität 10 (niedrigster).

Verwenden Sie diese Formel, um sicherzustellen, dass wichtige Arbeitstypen anhand der WorkType.Name (eines Standardfelds im Objekt "Arbeitstyp") priorisiert werden, wodurch die Ressourcenzuteilung optimiert und Ausfallzeiten minimiert werden. 

CASE(WorkType.Name,
  "Emergency Repair", 1,
  "Installation", 2,
  "Preventive Maintenance", 4,
  "Routine Inspection", 5,
  10
)

Beispiel 3: (Zwischen-)Priorisierung nach kombiniertem Fälligkeitsdatum und Arbeitstyp

Ein Unternehmen plant Installationen (hohe Priorität), Wartungen (mittlere Priorität), Fehlerbehebungen (hohe Priorität) und Außendienstinspektionen (niedrige Priorität). Fehlerbehebungen und Installationen werden zwar im Allgemeinen priorisiert, doch näher rückende Fälligkeitsdaten können die Dringlichkeit anderer Arbeitstypen erhöhen.

  • Die Arbeitstyppriorität (abgeleitet von WorkType.Name mithilfe von CASE) weist eine Gewichtung von 70 % auf. Das Fälligkeitsdatum hat ein Gewicht von 30 %.
  • Fälligkeitsdaten, die näher am heutigen Tag liegen, führen zu einem Beitrag mit höherer Priorität.

Verwenden Sie diese Formel, um eine endgültige Priorität zwischen 1 und 10 zu gewährleisten. Diese Formel gleicht die inhärente Priorität von Arbeitstypen mit der Notwendigkeit der Einhaltung von Fristen aus und optimiert die Ressourcenzuteilung und die Kundenzufriedenheit anhand von DueDate (einem Standardfeld im Objekt "Servicetermin") und WorkType.Name (einem Standardfeld im Objekt "Arbeitstyp"). 

ROUND(
  CASE(WorkType.Name,
    "Emergency Repair", 1,
    "Installation", 2,
    "Preventive Maintenance", 4,
    "Routine Inspection", 5,
    10
  ) * 0.7 +
  (11 - IF( DueDate - TODAY() < 2, 10,
        IF( DueDate - TODAY() < 7, 7, 4)
      )
   ) * 0.3
, 0)

Beispiel 4: (Erweitert) Priorisieren nach Vermögenswertverfügbarkeit und Fälligkeitsdatum

Ein Fertigungsserviceunternehmen möchte die Arbeit anhand der Vermögenswertverfügbarkeit (Auswirkungen auf Ausfallzeiten) und des Fälligkeitsdatums priorisieren.

  • Die Vermögenswertverfügbarkeit (70 % Gewicht) und das Fälligkeitsdatum (30 % Gewicht) tragen jeweils zur endgültigen Priorität bei. Eine geringere Vermögenswertverfügbarkeit erhöht die Priorität.

Verwenden Sie diese Formel, um eine endgültige Priorität zwischen 1 und 10 zu gewährleisten. Minimieren Sie Ausfallzeiten für wichtige Vermögenswerte und stellen Sie sicher, dass die Arbeit rechtzeitig abgeschlossen wird, indem Sie diese beiden wichtigen Faktoren basierend aufDueDate (einem Standardfeld des Objekts "Servicetermin") und dem aus dem zugehörigen Vermögenswert abgeleiteten Availability abwägen. Die Vermögenswertverfügbarkeit ist der Prozentsatz der erwarteten Betriebszeit, die ein Vermögenswert zur Verwendung zur Verfügung steht. Da für das Vermögenswertobjekt kein Standard-Nachschlagefeld vorhanden ist, wird davon ausgegangen, dass eines für dieses Beispiel erstellt wurde. Informationen zum Erstellen benutzerdefinierter Nachschlagefelder finden Sie unter Erstellen eines benutzerdefinierten Felds.

ROUND(
   ((101 - Asset__c.Availability) / 10) * 0.7 +
   (11 - IF(DueDate - TODAY() < 3, 10,
         IF(DueDate - TODAY() < 7, 7, 4)
       )
    ) * 0.3
, 0)

Beispiel 5: (Erweitert) Priorisieren nach Accountstufe und Fälligkeitsdatum

Ein Serviceunternehmen möchte Servicetermine anhand des Werts des Kundenaccounts und des Fälligkeitsdatums priorisieren.

  • Die Accountstufenpriorität (abgeleitet von Account.Account_Tier__c mithilfe von CASE) hat eine Gewichtung von 70 % und das Fälligkeitsdatum eine Gewichtung von 30 %.
  • Diamant-Accounts erhalten Priorität 1 (höchste).
  • Platin-Accounts erhalten Priorität 2.
  • Gold-Accounts erhalten Priorität 4.
  • Silber-Accounts erhalten Priorität 7.
  • Alle anderen Accounts erhalten Priorität 10.
  • Fälligkeitsdaten, die näher am heutigen Tag liegen, führen zu einem Beitrag mit höherer Priorität. Wenn die Arbeit in den nächsten zwei Tagen fällig ist, ist die Priorität in diesem Fall hoch. Wenn die Arbeit in den nächsten sieben Tagen fällig ist, erhöht sich die Priorität um einen geringeren Betrag. Wenn die Arbeit nach sieben Tagen fällig ist, wird sie nicht priorisiert.

Verwenden Sie diese Formel, um eine endgültige Priorität zwischen 1 und 10 zu gewährleisten. Stellen Sie Kunden mit hohem Wert einen Premium-Service bereit und stellen Sie sicher, dass alle Arbeiten rechtzeitig abgeschlossen werden. Gleichen Sie Kundenwert und Dringlichkeit auf der Grundlage von DueDate (einem Standardfeld, dem Objekt "Servicetermin") und Account.Tier__c (einem benutzerdefinierten Auswahllistenfeld im Objekt "Account" mit Werten: Diamant = 1, Platin = 2, Gold = 4, Silber = 7). Da für Accounts kein standardmäßiges Auswahllistenfeld für Accountstufe vorhanden ist, wird davon ausgegangen, dass eines für dieses Beispiel erstellt wurde. Informationen zum Erstellen benutzerdefinierter Nachschlagefelder finden Sie unter Erstellen eines benutzerdefinierten Felds.

ROUND(
   CASE(Account.Account_Tier__c,
     "Diamond", 1,
     "Platinum", 2,
     "Gold", 4,
     "Silver", 7,
     10
   ) * 0.7 +
   (11 - IF(DueDate - TODAY() < 3, 10,
         IF(DueDate - TODAY() < 7, 7, 4)
       )
    ) * 0.3
, 0)
 
Laden
Salesforce Help | Article