Usted está aquí:
Casos de uso para dar prioridad a citas de Field Service
La priorización efectiva es crucial en Salesforce Field Service para optimizar la asignación de recursos cuando la capacidad de su equipo está limitada. Revise los casos de uso para obtener información acerca de cómo definir prioridades de citas de servicio y asegúrese de que el trabajo más importante se soluciona rápidamente.
Salesforce Field Service admite una escala de prioridad de 1-100. Sin embargo, recomendamos que comience con la escala predeterminada de 1-10. Este intervalo proporciona suficiente granularidad para la mayoría de los casos de uso y simplifica la configuración inicial.
Puede establecer la prioridad de citas de servicio utilizando varios métodos.
- Fórmulas: cree campos de fórmula en el objeto Cita de servicio para calcular la prioridad basándose en otros datos.
- Automatización: emplee herramientas como Flow o Apex Code para actualizar dinámicamente la prioridad.
Los ejemplos de campo de fórmula se utilizan aquí para mayor claridad, pero los principios subyacentes se aplican también a enfoques basados en automatización.
Ejemplo 1: Priorización (básica) por fecha de vencimiento
Una empresa desea dar prioridad a citas de servicio basándose solo en la fecha de vencimiento, utilizando un desglose de prioridad más detallado.
- Las citas que vencen en el plazo de un día reciben prioridad 1 (máxima).
- Las citas que vencen en un plazo de tres días reciben prioridad 2.
- Las citas que vencen en un plazo de cinco días reciben prioridad 3.
- Las citas que vencen en un plazo de siete días reciben prioridad 4.
- Las citas que vencen en 14 días reciben prioridad 5.
- El resto de citas reciben la prioridad 6 (menor).
Utilice esta fórmula para garantizar la finalización puntual de citas, el cumplimiento de acuerdos de nivel de servicio (SLA) y obtener una priorización más granular basándose en DueDate (un campo estándar en el objeto Cita de servicio).
IF( DueDate - TODAY() < 1, 1,
IF( DueDate - TODAY() < 3, 2,
IF( DueDate - TODAY() < 5, 3,
IF( DueDate - TODAY() < 7, 4,
IF( DueDate - TODAY() < 14, 5, 6)
)
)
)
)
Ejemplo 2: Priorización (intermedia) por tipo de trabajo
Una empresa desea dar prioridad a citas de servicio basándose en el tipo de trabajo que se está realizando.
- Reparación de emergencia recibe prioridad 1 (máxima).
- La instalación recibe prioridad 2.
- Mantenimiento preventivo recibe prioridad 4.
- Inspección rutinaria recibe prioridad 5.
- Cualquier otro tipo de trabajo recibe la prioridad 10 (la más baja).
Utilice esta fórmula para asegurarse de que los tipos de trabajo críticos se priorizan basándose en el WorkType.Name (un campo estándar en el objeto Tipo de trabajo), optimizando la asignación de recursos y minimizando el tiempo de inactividad.
CASE(WorkType.Name,
"Emergency Repair", 1,
"Installation", 2,
"Preventive Maintenance", 4,
"Routine Inspection", 5,
10
)
Ejemplo 3: Priorización (intermedia) por fecha de vencimiento y tipo de trabajo combinados
Una empresa programa instalaciones (prioridad alta), mantenimiento (prioridad media), reparaciones (prioridad alta) e inspecciones de campo (prioridad baja). Aunque las reparaciones de averías e instalaciones suelen tener prioridad, acercarse a fechas de vencimiento puede aumentar la urgencia de otros tipos de trabajo.
- La prioridad del tipo de trabajo (derivada de
WorkType.Nameque utilizanCASE) tiene una ponderación del 70%. La fecha de vencimiento tiene un peso del 30%. - Las fechas de vencimiento más cercanas a hoy dan como resultado una contribución de mayor prioridad.
Utilice esta fórmula para garantizar una prioridad final entre 1-10. Esta fórmula equilibra la prioridad inherente de los tipos de trabajo con la necesidad de cumplir los plazos, optimizando la asignación de recursos y la satisfacción del cliente basándose en DueDate (un campo estándar en el objeto Cita de servicio) y WorkType.Name (un campo estándar en el objeto Tipo de trabajo).
ROUND(
CASE(WorkType.Name,
"Emergency Repair", 1,
"Installation", 2,
"Preventive Maintenance", 4,
"Routine Inspection", 5,
10
) * 0.7 +
(11 - IF( DueDate - TODAY() < 2, 10,
IF( DueDate - TODAY() < 7, 7, 4)
)
) * 0.3
, 0)
Ejemplo 4: Priorización (avanzada) por disponibilidad de activos y fecha de vencimiento
Una empresa de servicios de fabricación desea dar prioridad al trabajo en base a la disponibilidad de activos (impacto del tiempo de inactividad) y las fechas de vencimiento.
- La disponibilidad de activos (70% en peso) y la fecha de vencimiento (30% en peso) contribuyen cada una a la prioridad final. La menor disponibilidad de activos aumenta la prioridad.
Utilice esta fórmula para garantizar una prioridad final entre 1-10. Minimice el tiempo de inactividad para activos críticos y garantice la finalización puntual del trabajo, equilibrando estos dos factores importantes basándose enDueDate (un campo estándar el objeto Cita de servicio) y el campo Availability derivado del activo relacionado. La disponibilidad de activos es el porcentaje de tiempo de disponibilidad esperado que un activo está disponible para su uso. Como no hay ningún campo de búsqueda estándar en el objeto Activo, suponemos que se creó uno para este ejemplo. Para crear campos de búsqueda personalizados, consulte Crear un campo personalizado.
ROUND(
((101 - Asset__c.Availability) / 10) * 0.7 +
(11 - IF(DueDate - TODAY() < 3, 10,
IF(DueDate - TODAY() < 7, 7, 4)
)
) * 0.3
, 0)Ejemplo 5: Priorización (avanzada) por nivel de cuenta y fecha de vencimiento
Una empresa de servicio desea dar prioridad a citas de servicio basándose en el valor de la cuenta del cliente y la fecha de vencimiento.
- La prioridad de nivel de cuenta (derivada de
Account.Account_Tier__cque utilizanCASE) tiene una ponderación del 70% y la fecha de vencimiento tiene una ponderación del 30%. - Las cuentas Diamond reciben prioridad 1 (máxima).
- Las cuentas Platinum reciben prioridad 2.
- Las cuentas Gold reciben prioridad 4.
- Las cuentas Silver reciben prioridad 7.
- El resto de cuentas reciben prioridad 10.
- Las fechas de vencimiento más cercanas a hoy dan como resultado una contribución de mayor prioridad. En este caso, si el trabajo vence en los próximos dos días, la prioridad es alta, si el trabajo vence en los próximos siete días, la prioridad aumenta en un margen más pequeño y si el trabajo vence después de siete días, no se prioriza.
Utilice esta fórmula para garantizar una prioridad final entre 1-10. Proporcione un servicio premium a clientes de alto valor y garantice la finalización puntual de todo el trabajo. Equilibre el valor de cliente y la urgencia basándose en DueDate (un campo estándar el objeto Cita de servicio) y Account.Tier__c (un campo de lista de selección personalizado en el objeto Cuenta con valores: Diamante = 1, Platino = 2, Oro = 4, Plata = 7). Como no hay un campo de lista de selección Nivel de cuenta estándar en Cuentas, suponemos que se creó uno para este ejemplo. Para crear campos de búsqueda personalizados, consulte Crear un campo personalizado.
ROUND(
CASE(Account.Account_Tier__c,
"Diamond", 1,
"Platinum", 2,
"Gold", 4,
"Silver", 7,
10
) * 0.7 +
(11 - IF(DueDate - TODAY() < 3, 10,
IF(DueDate - TODAY() < 7, 7, 4)
)
) * 0.3
, 0)
