Loading
Agentforce Field Service and Operations
Cas d'utilisation pour prioriser les rendez-vous Field Service

Vous êtes ici :

  1. Aide de Salesforce
  2. Documents
  3. Agentforce Field Service and Operations

Cas d'utilisation pour prioriser les rendez-vous Field Service

Une priorisation efficace est essentielle dans Salesforce Field Service pour optimiser l'allocation des ressources lorsque les capacités de votre équipe sont limitées. Examinez les cas d'utilisation pour apprendre à définir les priorités des rendez-vous de service et assurez-vous que les tâches les plus critiques sont traitées rapidement.

Salesforce Field Service prend en charge une échelle de priorité de 1 à 100. Cependant, nous recommandons de commencer avec l'échelle par défaut de 1 à 10. Cette plage offre suffisamment de granularité pour la plupart des cas d'utilisation et simplifie la configuration initiale.

Vous pouvez définir la priorité du rendez-vous de service en utilisant diverses méthodes.

  • Formules : créez des champs de formule dans l'objet Rendez-vous de service pour calculer la priorité en fonction d'autres données.
  • Automatisation : utilisez des outils tels que Flux ou code Apex pour mettre dynamiquement à jour la priorité.

Les exemples de champ de formule sont utilisés ici pour plus de clarté, mais les principes sous-jacents s'appliquent également aux approches basées sur l'automatisation.

Exemple 1 : (base) Priorisation par date d'échéance

Une entreprise souhaite prioriser les rendez-vous de service uniquement en fonction de leur échéance, en utilisant une répartition des priorités plus détaillée.

  • Les rendez-vous dus dans la journée reçoivent la priorité 1 (la plus élevée).
  • Les rendez-vous dus dans les trois jours reçoivent la priorité 2.
  • Les rendez-vous dus dans les cinq jours reçoivent la priorité 3.
  • Les rendez-vous dus dans les sept jours reçoivent la priorité 4.
  • Les rendez-vous dus dans les 14 jours reçoivent la priorité 5.
  • Tous les autres rendez-vous reçoivent la priorité 6 (la plus faible).

Utilisez cette formule pour garantir la réalisation en temps voulu des rendez-vous, le respect des accords de niveau de service (SLA) et une priorisation plus précise basée sur DueDate (un champ standard dans l'objet Rendez-vous de service). 

IF( DueDate - TODAY() < 1, 1,
  IF( DueDate - TODAY() < 3, 2,
    IF( DueDate - TODAY() < 5, 3,
      IF( DueDate - TODAY() < 7, 4,
        IF( DueDate - TODAY() < 14, 5, 6)
      )
    )
  )
)

Exemple 2 : (intermédiaire) Priorisation par type de travail

Une entreprise souhaite prioriser les rendez-vous de service en fonction du type de travail effectué.

  • Réparation d'urgence reçoit la priorité 1 (la plus élevée).
  • L'installation reçoit la priorité 2.
  • La maintenance préventive reçoit la priorité 4.
  • L'Inspection régulière reçoit la priorité 5.
  • Tout autre type de travail reçoit la priorité 10 (la plus faible).

Utilisez cette formule pour vous assurer que les types de travail critiques sont prioritaires en fonction de la WorkType.Name (un champ standard dans l'objet Type de travail), en optimisant l'allocation des ressources et en réduisant les temps d'arrêt. 

CASE(WorkType.Name,
  "Emergency Repair", 1,
  "Installation", 2,
  "Preventive Maintenance", 4,
  "Routine Inspection", 5,
  10
)

Exemple 3 : Priorisation (intermédiaire) par date d'échéance et type de travail combinés

Une entreprise planifie les installations (priorité élevée), la maintenance (priorité moyenne), la réparation (priorité élevée) et les inspections sur site (priorité faible). Bien que les réparations et les installations soient généralement prioritaires, l'approche des dates d'échéance peut accroître l'urgence d'autres types de travail.

  • La priorité du type de travail (dérivée de WorkType.Name utilisant CASE) a une pondération de 70 %. La date d'échéance a un poids de 30 %.
  • Les dates d'échéance plus proches d'aujourd'hui entraînent une contribution plus prioritaire.

Utilisez cette formule pour garantir une priorité finale de 1 à 10. Cette formule équilibre la priorité inhérente aux types de travail avec la nécessité de respecter les délais, en optimisant l'allocation des ressources et la satisfaction client en fonction de la DueDate (un champ standard dans l'objet Rendez-vous de service) et de la WorkType.Name (un champ standard dans l'objet Type de travail). 

ROUND(
  CASE(WorkType.Name,
    "Emergency Repair", 1,
    "Installation", 2,
    "Preventive Maintenance", 4,
    "Routine Inspection", 5,
    10
  ) * 0.7 +
  (11 - IF( DueDate - TODAY() < 2, 10,
        IF( DueDate - TODAY() < 7, 7, 4)
      )
   ) * 0.3
, 0)

Exemple 4 : (avancé) Priorisation par disponibilité des actifs et date d'échéance

Une entreprise de services de fabrication souhaite prioriser les travaux en fonction de la disponibilité des actifs (impact sur les temps d'arrêt) et des dates d'échéance.

  • La disponibilité des actifs (pondération de 70 %) et la date d'échéance (30 %) contribuent chacune à la priorité finale. La diminution de la disponibilité des actifs augmente la priorité.

Réduisez les temps d'arrêt pour les actifs critiques et assurez-vous que le travail est terminé en temps opportun, en équilibrant ces deux facteurs importants en fonction deDueDate (un champ standard, l'objet Rendez-vous de service) et du champ de Availability dérivé de l'actif associé. La disponibilité de l'actif est le pourcentage de temps de fonctionnement attendu auquel un actif peut être utilisé. Comme il n'existe pas de champ de référence standard dans l'objet Actif, nous supposons qu'un champ a été créé pour cet exemple. Pour créer des champs de référence personnalisés, consultez Création d'un champ personnalisé.

ROUND(
   ((101 - Asset__c.Availability) / 10) * 0.7 +
   (11 - IF(DueDate - TODAY() < 3, 10,
         IF(DueDate - TODAY() < 7, 7, 4)
       )
    ) * 0.3
, 0)

Exemple 5 : (avancé) Priorisation par niveau de compte et date d'échéance

Une entreprise de services souhaite prioriser les rendez-vous de service en fonction de la valeur du compte du client et de la date d'échéance.

  • La priorité au niveau du compte (dérivée de Account.Account_Tier__c utilisant CASE) a une pondération de 70 % et la date d'échéance a une pondération de 30 %.
  • Les comptes diamant reçoivent la priorité 1 (la plus élevée).
  • Les comptes Platinum reçoivent la priorité 2.
  • Les comptes Gold reçoivent la priorité 4.
  • Les comptes Silver reçoivent la priorité 7.
  • Tous les autres comptes reçoivent la priorité 10.
  • Les dates d'échéance plus proches d'aujourd'hui entraînent une contribution plus prioritaire. Dans ce cas, si le travail est dû dans les deux prochains jours, la priorité est élevée, si le travail est dû dans les sept prochains jours, la priorité augmente d'une marge plus faible et si le travail est dû après sept jours, il n'est pas prioritaire.

Utilisez cette formule pour garantir une priorité finale de 1 à 10. Offrez un service premium aux clients de grande valeur et assurez-vous que tous les travaux sont effectués en temps voulu. Équilibrez la valeur client et l'urgence en fonction de la DueDate (un champ standard, l'objet Rendez-vous de service) et de la Account.Tier__c (un champ de liste de sélection personnalisé dans l'objet Compte avec des valeurs : Diamant = 1, Platine = 2, Or = 4, Argent = 7). Comme il n'existe pas de champ de liste de sélection standard Niveau du compte dans Comptes, nous supposons qu'un champ a été créé pour cet exemple. Pour créer des champs de référence personnalisés, consultez Création d'un champ personnalisé.

ROUND(
   CASE(Account.Account_Tier__c,
     "Diamond", 1,
     "Platinum", 2,
     "Gold", 4,
     "Silver", 7,
     10
   ) * 0.7 +
   (11 - IF(DueDate - TODAY() < 3, 10,
         IF(DueDate - TODAY() < 7, 7, 4)
       )
    ) * 0.3
, 0)
 
Chargement
Salesforce Help | Article