Arkiver Apex

Et getNextPage efter (scrollId != -1) inkluderes, da størrelsen på resultaterne er begrænset i performArchiverGlobalSearch.

string sObjectName = 'Account';
list<SF_Archive.SearchFilter>request = new list<SF_Archive.SearchFilter>();
SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('Name', 'test');
request.add(filter1);
SF_Archive.dateRange range = new SF_Archive.dateRange('CreatedDate', system.today()-150, system.today());
SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, range);

if(res.getStatusCode() == 200){
    system.debug('code: ' + res.getStatuscode());
    SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
    system.debug('count: '+ searchResponse.totalResultCount);
    system.debug('scrollid: '+ searchResponse.scrollId);
    system.debug('list size: '+ searchResponse.records.size());
    string scrollId = searchResponse.scrollId;
    integer page = 1;

    while(scrollId != '-1'){
        page++;
        SF_Archive.ArchiverAccessorResponse secondPage =
        SF_Archive.ArchiverAccessor.getNextPage(searchResponse.scrollId);
        if(secondPage.getStatusCode() == 200){
            SF_Archive.ArchiverAccessorSearchResponse searchResponse2 = secondPage.getSearchResponseMap();
            scrollId = searchResponse2.scrollId;
            system.debug('count: '+ searchResponse2.totalResultCount);
            system.debug('scrollid: '+ searchResponse2.scrollId);
            system.debug('list size: '+ searchResponse2.records.size());
            system.debug('page number: '+ page);
        } else{
            system.debug('response is != 200: '+ secondPage.getStatusCode());
            system.debug('body: '+ secondPage.getBody());
            break;
            } 
        }
    } else {
        system.debug('status code erorr|: '+ res.getStatusCode());
        system.debug('status code message|: '+ res.getErrorMessage()); 
    }

Anvendelsessituation

Din forretning kræver, at Niveau 3-supportteamet har adgang til at se arkiverede sager med statussen Høj prioritet.

Dette eksempel viser, hvordan du:

• Opret en tilpasset Lightning Web-komponent (LWC).
• Hent arkiverede data ved brug af Apex.
• Anvend filteret (Høj prioritet).
  

  Bemærk Andre filtre kan tilpasses ved at referere til koden i Arkiver Apex – kodeeksempel.

  Dette eksempel er begrænset til 25 registreringer. Apex giver dig mulighed for at angive resultaterne til 1.000 pr. side. Standarden er 25 med mulighed for sideinddeling gennem resultaterne.

Komponent, der viser sager med høj prioritet

Eksempel på SdkUseCaseWidget.js

I dette kodeeksempel er parameteren AccountRecordId.

import { LightningElement, api, track } from 'lwc';
    import getCases from '@salesforce/apex/ArchiveSdk.getCases';
    export default class SampleSdkUseCaseWidget extends LightningElement {
    @api recordId;
    
    columns = [
    { label: 'Case Number', fieldName: 'caseNumber', type: 'text', cellAttributes: {alignment: 'center'}},
    { label: 'Subject', fieldName: 'subject', type: 'text' , cellAttributes: {alignment: 'center'}, },
    { label: 'Priority', fieldName: 'priority', type: 'text', cellAttributes: {alignment: 'center'}, },
    { label: 'Status', fieldName: 'status', type: 'text', cellAttributes: {alignment: 'center'}, }
    ];
    @track records;
    @track data
    @track _loading;
    
    async connectedCallback() {
    this._loading = true;
    try {
    const result = await getCases({parentId: this.recordId})
    this.records = result;
    this._loading = false;
    } catch (error) {
    this._loading = false;
    }}
}            

Eksempel på SdkUseCaseWidget.html

Den Apex, som LWC bruger, kalder Apex.

SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, fields, range);

Dette er opfordringen til Arkiver Apex. Den indeholder disse parametre.

• sObjectName – viser søgningen
• Filtre – Bruges til at hente data
• Felter – De projicerede felter, der skal returneres fra data.
• Område – Det datoområde, der bruges til at forespørge på dataene.

<template>
    <template if:true={_loading}>
        <lightning-spinner></lightning-spinner>
    </template>
    <lightning-datatable
        key-field="caseNumber"
        data={records}
        columns={columns}
        hide-checkbox-column>
    </lightning-datatable>
</template>

ArchiveSdk.cls

Denne kodeblok er Apex.

public with sharing class ArchiveSDK {
                
    @AuraEnabled
    public static List<CaseTableWrapperExample.CaseRecord> getCases(String parentId) {
    // Create an empty list to hold maps with String keys and Object values
    List<Map<String, Object>> totalRecords = new List<Map<String, Object>>();
    
    // Create a list to store search filter objects
    List<SF_Archive.SearchFilter> request = new List<SF_Archive.SearchFilter>();
    
    // Create a search filter for the 'AccountId' field with a given 'parentId' value
    SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('AccountId', parentId);
    
    // Create a search filter for the 'Priority' field with a given 'High' value
    SF_Archive.SearchFilter filter2 = new SF_Archive.SearchFilter('Priority', 'High');
    
    // Add the filters to the request list
    request.add(filter1);
    request.add(filter2);
    
    // Define the object name as 'Case'
    String sObjectName = 'Case';
    
    // Create a list of Strings representing field names to be retrieved from Archive DB
    List<String> fields = new List<String>{'CaseNumber', 'Subject', 'Priority', 'Status'};
    
    // Create the DateRange based on the created date
    SF_Archive.DateRange range = new SF_Archive.DateRange('CreatedDate', system.today() - 150, system.today());
    
    // Perform an initial global search and store the response
    SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, range);
    
    // Check if the HTTP response status code is 200 (success)
    if (res.getStatusCode() == 200) {
        system.debug('code: ' + res.getStatuscode());
        
        // Retrieve the initial search response map
        SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
        
        system.debug('count: ' + searchResponse.totalResultCount);
        system.debug('scrollid: ' + searchResponse.scrollId);
        system.debug('list size: ' + searchResponse.records.size());
        
        // Store the scroll ID for pagination
        String scrollId = searchResponse.scrollId;
        
        // Initialize the page number
        Integer page = 1;
        
        // Add the records from the initial search to the totalRecords list
        totalRecords.addAll(searchResponse.records);
        
        // Continue to fetch additional pages while the scroll ID is not '-1'
        while (scrollId != '-1') {
            page++;
            
            // Get the next page of search results using the UPDATED scrollId 
            SF_Archive.ArchiverAccessorResponse nextPageResponse = SF_Archive.ArchiverAccessor.getNextPage(scrollId);
            
            // Check if the HTTP response status code is 200 (success)
            if (nextPageResponse.getStatusCode() == 200) {
            
                // Retrieve the search response for the current page
                SF_Archive.ArchiverAccessorSearchResponse searchResponse2 = nextPageResponse.getSearchResponseMap();
                
                // CRITICAL FIX: Update the scrollId with the value from the new response 
                scrollId = searchResponse2.scrollId;
                
                system.debug('count: ' + searchResponse2.totalResultCount);
                system.debug('scrollid: ' + searchResponse2.scrollId);
                system.debug('list size: ' + searchResponse2.records.size());
                system.debug('page number: ' + page); 
                
                // Add the records from the current page to the totalRecords list
                totalRecords.addAll(searchResponse2.records);
            } else {
                // Output an error message if the HTTP response status code is not 200
                system.debug('response is != 200: ' + nextPageResponse.getStatusCode());
                system.debug('body: ' + nextPageResponse.getBody());
                
                // Break out of the loop if there is an error
                break;
            }
        } // End of while loop
    } else {
        // Handle error from initial search
        system.debug('status code error: ' + res.getStatusCode());
        system.debug('status code message: ' + res.getErrorMessage());
    }
    
    // Return the list of total records
    List<CaseTableWrapperExample.CaseRecord> result = new List<CaseTableWrapperExample.CaseRecord>();
    return CaseTableWrapperExample.getCasesTable(totalRecords);
    }
}

CaseTableWrapperExample.cls

Hjælperklasse til at formulere klasse fra Apex til LWC

public class CaseTableWrapperExample{
    public static List<caseRecord> getCasesTable(list<map<string,object>> cases){
    List<caseRecord> caseReturnList = new List<caseRecord>();
    for(Map<string,object> caseRecord: cases){
    caseRecord tempCase = new caseRecord();
    tempCase.caseNumber = String.valueOf(caseRecord.get('CaseNumber'));
    tempCase.id = String.valueOf(caseRecord.get('Id'));
    tempCase.origin = String.valueOf(caseRecord.get('Origin'));
    tempCase.status = String.valueOf(caseRecord.get('Status'));
    tempCase.subject = String.valueOf(caseRecord.get('Subject'));
    tempCase.priority = String.valueOf(caseRecord.get('Priority'));
        
    caseReturnList.add(tempCase);
    }
    return caseReturnList;
    }
    
    public class caseRecord {
    @AuraEnabled public string caseNumber;
    @AuraEnabled public string id;
    @AuraEnabled public string origin;
    @AuraEnabled public string status;
    @AuraEnabled public string priority;
    @AuraEnabled public string subject;
}}

Koden ovenfor beskriver et eksempelscenarie, hvor du kan føje LWC som en komponent til Lightning.

Hvis du vil se den faktiske Lightning-datatabel, skal du føje denne kode til sampleSdkUseCaseWidget.js-meta.xml-filen. Føj derefter komponenten Arkiver til Lightning.

<?xml version="1.0" encoding="UTF-8"?>
<LightningComponentBundle xmlns="<a href='http://soap.sforce.com/2006/04/metadata">;
    <apiVersion>55.0</apiVersion>
    <isExposed>true</isExposed>
    <targets>
    <target>lightning__RecordPage</target>
    <target>lightning__AppPage</target>
    </targets>
    <targetConfigs>
    <targetConfig targets="lightning__RecordPage">
    <supportedFormFactors>
    <supportedFormFactor type="Small" />
    <supportedFormFactor type="Large" />
    </supportedFormFactors>
    </targetConfig>
    <targetConfig targets="lightning__AppPage">
    <supportedFormFactors>
    <supportedFormFactor type="Small" />
    <supportedFormFactor type="Large" />
    </supportedFormFactors>
    </targetConfig>
    </targetConfigs>
</LightningComponentBundle>

Yderligere oplysninger findes i Apex-styringsbegrænsninger.

Anvendelsessituation

Din forretning kræver, at Niveau 3-supportteamet har adgang til at se arkiverede sager med statussen Høj prioritet.

Dette eksempel viser, hvordan du undgår en fejl, når antallet af arkiverede registreringer, der hentes via Apex, er for stort. Fejlen lyder: SF_Archive.ArchiverAccessor.ArchiverAccessorException: Exceeded time allotted for callout, please contact support.

Kode fra disse Apex opretter denne anvendelsessituation.

ArchiveSecondPageJob behandler sideinddelte data fra Arkiver ved brug af et rulle-id og foretager udkald efter behov. Den kører asynkront via Køgrænsefladen og sporer den samlede kørselstid for at undgå at overskride grænserne og sætter sig selv i kø til fortsat behandling, hvis det er nødvendigt. Klassen håndterer svar, opdaterer rulle-id'et og logfører detaljer om hver hentet dataside.

public class ArchiveSecondPageJob implements Queueable,Database.AllowsCallouts {
                          
       private String scrollId;
       private long totalTime;
       private integer pageNumber;

       public archiveSecondPageJob(String prevScrollId, integer pageNumber) {
           scrollId = prevScrollId;
           this.pageNumber = pageNumber;
       }

       public void execute(QueueableContext context) {
           system.debug('executing');
           doExecute();
       }
       private void doExecute() {
               SF_Archive.ArchiverAccessorSearchResponse searchResponse = null;
               integer page = 1;
               long totalTime = 0;
  
                       while(scrollId != '-1')
                       {       
                           //avoid 12000 ms limit
                           if(totalTime > 90000){
                               system.debug('Creating new task');
      archiveSecondPageJob q = new archiveSecondPageJob(scrollId,this.pageNumber);
                               System.enqueueJob(q);
                               return;
                           }
                           //Get the next page using the scrollId     
                           Long startTime = DateTime.now().getTime(); 
                           SF_Archive.ArchiverAccessorResponse nextPage = SF_Archive.ArchiverAccessor.getNextPage(scrollId); 
                           Long stopTime = DateTime.now().getTime();
                           totalTime += stopTime - startTime;
                           if(nextPage.getStatusCode() == 200){     
                               this.pageNumber++;
                               SF_Archive.ArchiverAccessorSearchResponse searchResponse2 =nextPage.getSearchResponseMap();      
                               scrollId = searchResponse2.scrollId;
                               system.debug('count: '+ searchResponse2.totalResultCount);    
                               system.debug('scrollid: '+ searchResponse2.scrollId); 
                               system.debug('list size: '+ searchResponse2.records.size());  
                               system.debug('body: '+ searchResponse2.records);  
                               system.debug('page: '+ pageNumber);  
                               system.debug('time: '+ totalTime); 
                           }       
                           else{           
                               system.debug('response is != 200: '+ nextPage.getStatusCode());           
                               system.debug('body: '+ nextPage.getBody());
                               return;
                           }           
                       }
       }
}
            

ArchiveSearch-klassen udfører en søgning på objektet Sag ved brug af specifikke filtre, henter resultaterne og logfører detaljer som f.eks. det samlede antal og rulle-id'et. Hvis søgningen returnerer et gyldigt rulle-id, der angiver flere resultatsider, sætter den archiveSecondPageJob til at behandle den næste side asynkront. Denne klasse initierer i det væsentlige søgningen og overfører yderligere behandling til de tidligere definerede archiveSecondPageJob.

Her er formatet på det indledende søgeopkald.

public class ArchiveSearch {
                    
    public void doSearch(){
        
        string sObjectName = 'Case';
        list<SF_Archive.SearchFilter> request = new list<SF_Archive.SearchFilter>();
    
        SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('Priority', 'High');
        request.add(filter1);
        
   
        list<string> fields = new list<string>{'CaseNumber', 'Id'};
        
        SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, fields);   
        if(res.getStatusCode() == 200){
           system.debug('code: ' + res.getStatuscode());
           SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
           system.debug('count: '+ searchResponse.totalResultCount);
           system.debug('scrollid: '+ searchResponse.scrollId);
           system.debug('list size: '+ searchResponse.records.size());
           string scrollId = searchResponse.scrollId;
           integer page = 1;   
           if(scrollId != '-1'){
               system.debug('calling next page');
               integer pageNumber = 2;
               archiveSecondPageJob q = new archiveSecondPageJob(scrollId, pageNumber);
               System.enqueueJob(q);
   }}}}

Hvis du ønsker yderligere oplysninger, kan du se Salesforce Apex Developer Guide.