Archiviazione di query sui dati Apex

È inclusa una chiamata getNextPage dopo (scrollId != -1) perché le dimensioni dei risultati sono limitate nella chiamata performArchiverGlobalSearch.

string sObjectName = 'Account';
list<SF_Archive.SearchFilter>request = new list<SF_Archive.SearchFilter>();
SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('Name', 'test');
request.add(filter1);
SF_Archive.dateRange range = new SF_Archive.dateRange('CreatedDate', system.today()-150, system.today());
SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, range);

if(res.getStatusCode() == 200){
    system.debug('code: ' + res.getStatuscode());
    SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
    system.debug('count: '+ searchResponse.totalResultCount);
    system.debug('scrollid: '+ searchResponse.scrollId);
    system.debug('list size: '+ searchResponse.records.size());
    string scrollId = searchResponse.scrollId;
    integer page = 1;

    while(scrollId != '-1'){
        page++;
        SF_Archive.ArchiverAccessorResponse secondPage =
        SF_Archive.ArchiverAccessor.getNextPage(searchResponse.scrollId);
        if(secondPage.getStatusCode() == 200){
            SF_Archive.ArchiverAccessorSearchResponse searchResponse2 = secondPage.getSearchResponseMap();
            scrollId = searchResponse2.scrollId;
            system.debug('count: '+ searchResponse2.totalResultCount);
            system.debug('scrollid: '+ searchResponse2.scrollId);
            system.debug('list size: '+ searchResponse2.records.size());
            system.debug('page number: '+ page);
        } else{
            system.debug('response is != 200: '+ secondPage.getStatusCode());
            system.debug('body: '+ secondPage.getBody());
            break;
            } 
        }
    } else {
        system.debug('status code erorr|: '+ res.getStatusCode());
        system.debug('status code message|: '+ res.getErrorMessage()); 
    }

Caso d'uso

L'azienda richiede che il team di assistenza di livello 3 disponga dell'accesso per visualizzare i casi archiviati con stato ad alta priorità.

Questo esempio mostra come:

• Creare un componente Web Lightning (LWC) personalizzato.
• Estrarre i dati archiviati utilizzando query sui dati Apex.
• Applicare il filtro (Alta priorità).
  

  Nota Altri filtri possono essere personalizzati con riferimento al codice in Archivia query Apex Data — Esempio di codice.

  Questo esempio è limitato a 25 record. Apex consente di impostare i risultati su 1.000 per pagina. Il valore predefinito è 25, con l'opzione di paginazione attraverso i risultati.

Componente che visualizza casi con priorità alta

Esempio di SdkUseCaseWidget.js

In questo esempio di codice, il parametro è AccountRecordId.

import { LightningElement, api, track } from 'lwc';
    import getCases from '@salesforce/apex/ArchiveSdk.getCases';
    export default class SampleSdkUseCaseWidget extends LightningElement {
    @api recordId;
    
    columns = [
    { label: 'Case Number', fieldName: 'caseNumber', type: 'text', cellAttributes: {alignment: 'center'}},
    { label: 'Subject', fieldName: 'subject', type: 'text' , cellAttributes: {alignment: 'center'}, },
    { label: 'Priority', fieldName: 'priority', type: 'text', cellAttributes: {alignment: 'center'}, },
    { label: 'Status', fieldName: 'status', type: 'text', cellAttributes: {alignment: 'center'}, }
    ];
    @track records;
    @track data
    @track _loading;
    
    async connectedCallback() {
    this._loading = true;
    try {
    const result = await getCases({parentId: this.recordId})
    this.records = result;
    this._loading = false;
    } catch (error) {
    this._loading = false;
    }}
}            

Esempio di SdkUseCaseWidget.html

Il controller Apex utilizzato da LWC chiama le query dati Apex.

SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, fields, range);

Questa è la chiamata per Archivia Apex. Include i seguenti parametri.

• sObjectName: rappresenta la ricerca
• Filtri: utilizzati per recuperare i dati
• Campi: i campi previsti da restituire dai dati.
• Intervallo: intervallo di date utilizzato per eseguire query sui dati.

<template>
    <template if:true={_loading}>
        <lightning-spinner></lightning-spinner>
    </template>
    <lightning-datatable
        key-field="caseNumber"
        data={records}
        columns={columns}
        hide-checkbox-column>
    </lightning-datatable>
</template>

ArchiveSdk.cls

Questo blocco di codice è il controller Apex.

public with sharing class ArchiveSDK {
                
    @AuraEnabled
    public static List<CaseTableWrapperExample.CaseRecord> getCases(String parentId) {
    // Create an empty list to hold maps with String keys and Object values
    List<Map<String, Object>> totalRecords = new List<Map<String, Object>>();
    
    // Create a list to store search filter objects
    List<SF_Archive.SearchFilter> request = new List<SF_Archive.SearchFilter>();
    
    // Create a search filter for the 'AccountId' field with a given 'parentId' value
    SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('AccountId', parentId);
    
    // Create a search filter for the 'Priority' field with a given 'High' value
    SF_Archive.SearchFilter filter2 = new SF_Archive.SearchFilter('Priority', 'High');
    
    // Add the filters to the request list
    request.add(filter1);
    request.add(filter2);
    
    // Define the object name as 'Case'
    String sObjectName = 'Case';
    
    // Create a list of Strings representing field names to be retrieved from Archive DB
    List<String> fields = new List<String>{'CaseNumber', 'Subject', 'Priority', 'Status'};
    
    // Create the DateRange based on the created date
    SF_Archive.DateRange range = new SF_Archive.DateRange('CreatedDate', system.today() - 150, system.today());
    
    // Perform an initial global search and store the response
    SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, range);
    
    // Check if the HTTP response status code is 200 (success)
    if (res.getStatusCode() == 200) {
        system.debug('code: ' + res.getStatuscode());
        
        // Retrieve the initial search response map
        SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
        
        system.debug('count: ' + searchResponse.totalResultCount);
        system.debug('scrollid: ' + searchResponse.scrollId);
        system.debug('list size: ' + searchResponse.records.size());
        
        // Store the scroll ID for pagination
        String scrollId = searchResponse.scrollId;
        
        // Initialize the page number
        Integer page = 1;
        
        // Add the records from the initial search to the totalRecords list
        totalRecords.addAll(searchResponse.records);
        
        // Continue to fetch additional pages while the scroll ID is not '-1'
        while (scrollId != '-1') {
            page++;
            
            // Get the next page of search results using the UPDATED scrollId 
            SF_Archive.ArchiverAccessorResponse nextPageResponse = SF_Archive.ArchiverAccessor.getNextPage(scrollId);
            
            // Check if the HTTP response status code is 200 (success)
            if (nextPageResponse.getStatusCode() == 200) {
            
                // Retrieve the search response for the current page
                SF_Archive.ArchiverAccessorSearchResponse searchResponse2 = nextPageResponse.getSearchResponseMap();
                
                // CRITICAL FIX: Update the scrollId with the value from the new response 
                scrollId = searchResponse2.scrollId;
                
                system.debug('count: ' + searchResponse2.totalResultCount);
                system.debug('scrollid: ' + searchResponse2.scrollId);
                system.debug('list size: ' + searchResponse2.records.size());
                system.debug('page number: ' + page); 
                
                // Add the records from the current page to the totalRecords list
                totalRecords.addAll(searchResponse2.records);
            } else {
                // Output an error message if the HTTP response status code is not 200
                system.debug('response is != 200: ' + nextPageResponse.getStatusCode());
                system.debug('body: ' + nextPageResponse.getBody());
                
                // Break out of the loop if there is an error
                break;
            }
        } // End of while loop
    } else {
        // Handle error from initial search
        system.debug('status code error: ' + res.getStatusCode());
        system.debug('status code message: ' + res.getErrorMessage());
    }
    
    // Return the list of total records
    List<CaseTableWrapperExample.CaseRecord> result = new List<CaseTableWrapperExample.CaseRecord>();
    return CaseTableWrapperExample.getCasesTable(totalRecords);
    }
}

CaseTableWrapperExample.cls

Classe Helper per formulare la classe da Apex a LWC

public class CaseTableWrapperExample{
    public static List<caseRecord> getCasesTable(list<map<string,object>> cases){
    List<caseRecord> caseReturnList = new List<caseRecord>();
    for(Map<string,object> caseRecord: cases){
    caseRecord tempCase = new caseRecord();
    tempCase.caseNumber = String.valueOf(caseRecord.get('CaseNumber'));
    tempCase.id = String.valueOf(caseRecord.get('Id'));
    tempCase.origin = String.valueOf(caseRecord.get('Origin'));
    tempCase.status = String.valueOf(caseRecord.get('Status'));
    tempCase.subject = String.valueOf(caseRecord.get('Subject'));
    tempCase.priority = String.valueOf(caseRecord.get('Priority'));
        
    caseReturnList.add(tempCase);
    }
    return caseReturnList;
    }
    
    public class caseRecord {
    @AuraEnabled public string caseNumber;
    @AuraEnabled public string id;
    @AuraEnabled public string origin;
    @AuraEnabled public string status;
    @AuraEnabled public string priority;
    @AuraEnabled public string subject;
}}

Il codice riportato sopra descrive uno scenario di esempio in cui è possibile aggiungere LWC come componente alla pagina Lightning.

Per visualizzare la tabella di dati Lightning effettiva, aggiungere questo codice al file sampleSdkUseCaseWidget.js-meta.xml. Aggiungere quindi il componente Archivia alla pagina Lightning.

<?xml version="1.0" encoding="UTF-8"?>
<LightningComponentBundle xmlns="<a href='http://soap.sforce.com/2006/04/metadata">;
    <apiVersion>55.0</apiVersion>
    <isExposed>true</isExposed>
    <targets>
    <target>lightning__RecordPage</target>
    <target>lightning__AppPage</target>
    </targets>
    <targetConfigs>
    <targetConfig targets="lightning__RecordPage">
    <supportedFormFactors>
    <supportedFormFactor type="Small" />
    <supportedFormFactor type="Large" />
    </supportedFormFactors>
    </targetConfig>
    <targetConfig targets="lightning__AppPage">
    <supportedFormFactors>
    <supportedFormFactor type="Small" />
    <supportedFormFactor type="Large" />
    </supportedFormFactors>
    </targetConfig>
    </targetConfigs>
</LightningComponentBundle>

Per ulteriori informazioni, vedere Apex Governor Limits.

Caso d'uso

L'azienda richiede che il team di assistenza di livello 3 disponga dell'accesso per visualizzare i casi archiviati con stato ad alta priorità.

Questo esempio mostra come risolvere un errore quando il numero di record archiviati recuperati tramite Apex è troppo elevato. L'errore è: SF_Archive.ArchiverAccessor.ArchiverAccessorException: Exceeded time allotted for callout, please contact support.

Il codice di queste classi Apex crea questo caso d'uso.

La classe ArchiveSecondPageJob elabora i dati impaginati da Archivia utilizzando un ID scorrimento, effettuando chiamate in base alle esigenze. Viene eseguito in modo asincrono tramite l'interfaccia Area di attesa, monitorando il tempo totale di esecuzione per evitare di superare i limiti e l'area di attesa per continuare l'elaborazione se necessario. La classe gestisce le risposte, aggiorna l'ID scorrimento e registra i dettagli di ogni pagina di dati recuperata.

public class ArchiveSecondPageJob implements Queueable,Database.AllowsCallouts {
                          
       private String scrollId;
       private long totalTime;
       private integer pageNumber;

       public archiveSecondPageJob(String prevScrollId, integer pageNumber) {
           scrollId = prevScrollId;
           this.pageNumber = pageNumber;
       }

       public void execute(QueueableContext context) {
           system.debug('executing');
           doExecute();
       }
       private void doExecute() {
               SF_Archive.ArchiverAccessorSearchResponse searchResponse = null;
               integer page = 1;
               long totalTime = 0;
  
                       while(scrollId != '-1')
                       {       
                           //avoid 12000 ms limit
                           if(totalTime > 90000){
                               system.debug('Creating new task');
      archiveSecondPageJob q = new archiveSecondPageJob(scrollId,this.pageNumber);
                               System.enqueueJob(q);
                               return;
                           }
                           //Get the next page using the scrollId     
                           Long startTime = DateTime.now().getTime(); 
                           SF_Archive.ArchiverAccessorResponse nextPage = SF_Archive.ArchiverAccessor.getNextPage(scrollId); 
                           Long stopTime = DateTime.now().getTime();
                           totalTime += stopTime - startTime;
                           if(nextPage.getStatusCode() == 200){     
                               this.pageNumber++;
                               SF_Archive.ArchiverAccessorSearchResponse searchResponse2 =nextPage.getSearchResponseMap();      
                               scrollId = searchResponse2.scrollId;
                               system.debug('count: '+ searchResponse2.totalResultCount);    
                               system.debug('scrollid: '+ searchResponse2.scrollId); 
                               system.debug('list size: '+ searchResponse2.records.size());  
                               system.debug('body: '+ searchResponse2.records);  
                               system.debug('page: '+ pageNumber);  
                               system.debug('time: '+ totalTime); 
                           }       
                           else{           
                               system.debug('response is != 200: '+ nextPage.getStatusCode());           
                               system.debug('body: '+ nextPage.getBody());
                               return;
                           }           
                       }
       }
}
            

La classe ArchiveSearch esegue una ricerca sull'oggetto Caso utilizzando filtri specifici, recupera i risultati e registra dettagli come il conteggio totale e l'ID scorrimento. Se la ricerca restituisce un ID scorrimento valido, che indica più pagine di risultati, l'area di attesa archiveSecondPageJob per elaborare la pagina successiva in modo asincrono. Questa classe avvia essenzialmente la ricerca e passa l'elaborazione successiva al archiveSecondPageJob definito in precedenza.

Di seguito è riportato il formato della chiamata di ricerca iniziale.

public class ArchiveSearch {
                    
    public void doSearch(){
        
        string sObjectName = 'Case';
        list<SF_Archive.SearchFilter> request = new list<SF_Archive.SearchFilter>();
    
        SF_Archive.SearchFilter filter1 = new SF_Archive.SearchFilter('Priority', 'High');
        request.add(filter1);
        
   
        list<string> fields = new list<string>{'CaseNumber', 'Id'};
        
        SF_Archive.ArchiverAccessorResponse res = SF_Archive.ArchiverAccessor.performArchiverGlobalSearch(sObjectName, request, fields);   
        if(res.getStatusCode() == 200){
           system.debug('code: ' + res.getStatuscode());
           SF_Archive.ArchiverAccessorSearchResponse searchResponse = res.getSearchResponseMap();
           system.debug('count: '+ searchResponse.totalResultCount);
           system.debug('scrollid: '+ searchResponse.scrollId);
           system.debug('list size: '+ searchResponse.records.size());
           string scrollId = searchResponse.scrollId;
           integer page = 1;   
           if(scrollId != '-1'){
               system.debug('calling next page');
               integer pageNumber = 2;
               archiveSecondPageJob q = new archiveSecondPageJob(scrollId, pageNumber);
               System.enqueueJob(q);
   }}}}

Per ulteriori informazioni, vedere Salesforce Apex Developer Guide.