Insights for Engagement

Here’s an example of a custom action to delete all activity from an Experience Cloud site member. This custom action is great for cleaning up thesite after a spam attack.

Create a custom controller extension using an Apex class and use it in your Visualforce page. The following DeleteAllActivityControllerExtension class is an example of a custom controller extension.

public with sharing class DeleteAllActivityControllerExtension {

    private List<Id> ids;
    private String retURL;
    private Database.DeleteResult[] deleteResult = null;
    private Map<String, String> resultMap;
    private String success = 'success';
    private String failure = 'failure';
    
    public DeleteAllActivityControllerExtension(ApexPages.StandardController controller) {
        resultMap = new Map<String, String>();
        /* The IDs you select on the Insights page are stored in a comma separated string of IDs. 
        This string is passed in a parameter called "idsList" */
        String idsList = ApexPages.currentPage().getParameters().get('idsList'); 
        //The return URL to the Insights page is passed in a parameter called "retURL"
        retURL = ApexPages.currentPage().getParameters().get('retURL');
        ids = idsList.split(',');
    }
    
    public PageReference deleteAllActivity() {
        deleteFeedPosts();
        deleteFeedComments();
        //Include these two lines of code to be redirected to the Insights page after you click the action.
        PageReference retPage = new PageReference(retURL);
        retPage.setRedirect(true);
        Integer failureCount = calculateFailureCount();
        Integer successCount = ids.size() - failureCount;
        retPage.getParameters().put(success, String.valueOf(successCount));
        retPage.getParameters().put(failure, String.valueOf(failureCount));
        return retPage;
   }
   
   private void deleteFeedPosts() {
        List<FeedItem> feedItems = [Select Id, CreatedById FROM FeedItem WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedItems, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedItems.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private void deleteFeedComments() {
        List<FeedComment> feedComments = [Select Id, CreatedById FROM FeedComment WHERE CreatedById IN :ids];
        deleteResult = Database.delete(feedComments, false);
        //Update the resultMap with failures to calculate the failureCount
        if(deleteResult != null) {
            for(Integer i=0;i < deleteResult.size();i++) {
                if (!deleteResult.get(i).isSuccess()) {
                    for(Database.Error error : deleteResult.get(i).getErrors()) {
                        resultMap.put(string.valueOf(feedComments.get(i).CreatedById), failure);
                    }
                }
            }
        }
   }
   
   private Integer calculateFailureCount() {
       Integer failureCount = 0;
       for (String result : resultMap.values()) {
            if (failure == result) {
                failureCount++;
            }
        }
        return failureCount;
   }
   
}

This code creates a Delete All Activity button in your Insights report. This button deletes all posts and comments for any selected members. If you wanted to delete all private messages and files too, you could expand the code.

Note

• This code example doesn’t include any permission checks. This custom action only works for admins.
• The IDs for the items you selected on the Insights report are passed to the Visualforce page using the idsList parameter.

<apex:page standardController="User" 
extensions="DeleteAllActivityControllerExtension" action="{!deleteAllActivity}" 
/>