Sample Flow to Extract and Store Text in Records

Map<String, String> requiredFields = new Map<String, String>();
requiredFields.put('Name', 'demoAccountRecord');
TransformDocument.transform('48tRM0000004CreYAE', 'a Employee\'s social security number',
              'Account', requiredFields);

public class TransformDocument {
    private static final String KEY_VALUE_PAIR = 'keyValuePair';
    private static final String TEXT = 'text';
    private static final String KEY = 'key';
    private static final String VALUE = 'value';
    public static void transform(String templateId, String key, String targetObjectApiName, Map<String, String> requiredFields) {
        // Get the OcrDocumentScanResult (ODSR) response for document uploaded in the template
        String odsrResponse = getOdsrResponseFromTemplateId(templateId);
        // Pass key for which value should be fetched
        String value = getValue(odsrResponse, key);
        // save the fetched value in target object
        saveExtractedValuesInTargetObject(value, targetObjectApiName, requiredFields);
    }
    /**
     * The following method gets the OcrDocumentScanResult (ODSR) response for the document uploaded in the template
     * 
     * It queries the objects in the following sequence:
     * Ocr Template -> Ocr Sample Document -> Content Asset -> Content Document -> Ocr Document ScanResult (ODSR)
     */
    private static String getOdsrResponseFromTemplateId(String templateId) {
        List<OcrTemplateSampleDocument> ocrTemplateSampleDocs = [SELECT OcrSampleDocumentId, OcrTemplateId FROM OcrTemplateSampleDocument WHERE OcrTemplateId =: templateId];
        String sampleDocumentId = ocrTemplateSampleDocs.get(0).OcrSampleDocumentId ;
        List<OcrSampleDocument> ocrSampleDocs = [SELECT ContentAssetId FROM OcrSampleDocument WHERE Id =: sampleDocumentId];
        String contentAssetId = ocrSampleDocs.get(0).ContentAssetId;
        List<ContentAsset> contentAssets = [SELECT ContentDocumentId FROM ContentAsset WHERE Id =: contentAssetId];
        String contentDocumentId = contentAssets.get(0).ContentDocumentId;
        List<OcrDocumentScanResult> ocrScanResults = [SELECT ExtractedValues FROM OcrDocumentScanResult WHERE ContentDocumentId =: contentDocumentId];
        return ocrScanResults.get(0).ExtractedValues;
    }
   /**
    * This method returns the value corresponding to the key in the response
    */ 
    private static String getValue(String response, String key) {
        Map<String, Object> jsonMap = (Map<String, Object>) JSON.deserializeUntyped(response);
        List<Object> keyValuePairList = (List<Object>) jsonMap.get(KEY_VALUE_PAIR);
        List<Map<String, Object>> keyValuePairMapList = new List<Map<String, Object>>();
        for (Object keyValuePair : keyValuePairList) {
            Map<String, Object> keyValuePairMap = (Map<String, Object>) keyValuePair;
            keyValuePairMapList.add(keyValuePairMap);
        }
        String value = '';
        for (Map<String, Object> keyValuePair : keyValuePairMapList) {
            Map<String, Object> keyMap = (Map<String, Object>) keyValuePair.get(KEY);
            if (keyMap.get(TEXT).equals(key)) {
                Map<String, Object> valueMap = (Map<String, Object>) keyValuePair.get(VALUE);
                value = (String) valueMap.get(TEXT);
                break;
            }
        }
        return value;
    }
    /**
    * This method creates a new record of objectType target object and saves values in one of 
    * the fields of the target object.
    * Since some target objects require mandatory fields for a record to be created,
    * we use requiredFields map that has keys as mandatory fields' API names
    * and values as per the usecase requirement.
    */
    private static void saveExtractedValuesInTargetObject(String value, String objectType, Map<String, String> requiredFields) {
        SObject newRecord = (SObject) Type.forName(objectType).newInstance();
        // Required field for record-creation
        for (String key : requiredFields.keySet()) {
            String val = requiredFields.get(key);
            newRecord.put(key, val);
        }
        newRecord.put('Description', value);
        insert newRecord;
    }
}