示例图像链接公式

有关使用这些示例包含的函数的详细信息，请参阅按上下文划分的公式运算符和函数。

Yahoo!Instant Messenger™ Image

该公式显示图像，指示联系人或用户是否登录到 Yahoo！Instant Messenger。单击该图像启动 Yahoo!Instant Messenger 窗口。本公式使用名为 Yahoo Name（Yahoo 名称）存储联系人或用户的 Yahoo!ID。

IF(ISBLANK(Yahoo_Name__c),"", HYPERLINK("ymsgr:sendIM?" & Yahoo_Name__c, 
IMAGE("http://opi.yahoo.com/online?u=" & Yahoo_Name__c & "&m=g&t=0", " ")))

用于个案优先级的标记

本公式显示绿色、黄色或红色标记图像以表示个案优先级。

IMAGE( 
CASE( Priority, 
"Low", "/img/samples/flag_green.gif",
"Medium", "/img/samples/flag_yellow.gif",
"High", "/img/samples/flag_red.gif", 
"/s.gif"), 
"Priority Flag")

个案帐龄的彩色正方形

本公式显示 30 x 30 像素的红色、黄色或绿色图像，这取决于 Case Age（个案帐龄）自定义数字字段的值。

IF( Case_Age__c > 20, 
IMAGE("/img/samples/color_red.gif", "red", 30, 30),
IF( Case_Age__c > 10,
IMAGE("/img/samples/color_yellow.gif", "yellow", 30, 30),
IMAGE("/img/samples/color_green.gif", "green", 30, 30)
))

用于状态的交通灯

本公式通过名为项目状态的自定义选项列表字段，显示绿色、黄色或红色交通灯图像以表示状态。使用列表视图中的此公式和报表创建“状态汇总”仪表板视图。

IMAGE( 
CASE(Project_Status__c, 
"Green", "/img/samples/light_green.gif",
"Yellow", "/img/samples/light_yellow.gif",
"Red", "/img/samples/light_red.gif", 
"/s.gif"), 
"status color")

用于评级的星

本公式显示一至五颗星以表示评级或分数。

IMAGE( 
CASE(Rating__c, 
"1", "/img/samples/stars_100.gif",
"2", "/img/samples/stars_200.gif",
"3", "/img/samples/stars_300.gif", 
"4", "/img/samples/stars_400.gif", 
"5", "/img/samples/stars_500.gif", 
"/img/samples/stars_000.gif"), 
"rating")

Consumer Reports™—用于评级的彩色样式圆形

本公式显示彩色圆形，以表示一至五的评级分数，其中实心红色是一、半圆红色是二、黑色轮廓是三、半圆黑色是四，同时实心黑色是五。

IMAGE( 
CASE(Rating__c, 
"1", "/img/samples/rating1.gif",
"2", "/img/samples/rating2.gif",
"3", "/img/samples/rating3.gif", 
"4", "/img/samples/rating4.gif", 
"5", "/img/samples/rating5.gif", 
"/s.gif"), 
"rating") 

表示得分的水平栏

本公式显示长度与数字得分成正比的水平彩色栏（白色背景为绿色）。在本示例中，栏的最大长度是 200 像素。

IMAGE("/img/samples/color_green.gif", "green", 15, Industry_Score__c * 2) & 
IMAGE("/s.gif", "white", 15, 
200 - (Industry_Score__c * 2))