Loading
Salesforce から送信されるメールは、承認済ドメインからのみとなります続きを読む
コードではなくてクリックによる Salesforce の拡張
目次
絞り込み条件 (0)追加
絞り込み条件を選択

          結果がありません
          結果がありません
          検索のヒントをいくつかご紹介します

          キーワードの入力ミスがないか確認する。
          より一般的な検索語を使用する。
          絞り込み条件を減らして、検索範囲を広げる。

            Salesforce ヘルプ全体を検索
            Salesforce ヘルプ全体を検索
            商談管理の入力規則の例

            詳細情報:

            1. Salesforce ヘルプ
            2. ドキュメント
            3. コードではなくてクリックによる Salesforce の拡張

            商談管理の入力規則の例

            商談のカスタム項目やその他の項目を検証する方法の例。

            必要なエディション

            使用可能なインターフェース: Salesforce Classic と Lightning Experience の両方
            使用可能なエディション: Contact Manager Edition、Group Edition、Professional Edition、Enterprise Edition、Performance Edition、Unlimited Edition、Developer Edition、および Database.com Edition

            これらの例で使用する数式関数についての詳細は、「数式の演算子と関数」を参照してください。

            商談フェーズに基づく条件付き必須項目

            項目 値
            説明: [商談成立] または [最終交渉] フェーズまで進んだ商談に、[納品日] というカスタム項目があることを確認します。
            数式: 
            AND (
  OR (
     ISPICKVAL(StageName, "Closed Won"),
     ISPICKVAL(StageName, "Negotiation/Review")),
ISBLANK(Delivery_Date__c)
)
            エラーメッセージ: このフェーズには [納品日] が必要です。
            エラー表示場所: 納品日

            完了予定日への前月の指定の禁止

            項目 値
            説明: 商談の [完了予定日] が前月の 1 か月以内の日付になっていないことを確認します。この数式では、商談の作成中、または後に [完了予定日] 項目が変更されたときにだけ条件を調べるように ISNEW および ISCHANGED が使用されています。
            数式: 
            AND(
  OR (
     ISNEW(),
     ISCHANGED( CloseDate )),
  CloseDate < DATE( YEAR(TODAY()), MONTH(TODAY()), 1) )
            エラーメッセージ: 完了予定日には今月以降の月を指定してください。
            エラー表示場所: 完了予定日

            完了予定日が将来の日付であること

            項目 値
            説明: ユーザーが、商談の [完了予定日] を過去の日付に変更しないようにします。
            数式: 
            SampleDate < TODAY()
            エラーメッセージ: 完了予定日を過去の日付にすることはできません。
            エラー表示場所: 完了予定日

            商談における割引

            項目 値
            説明: 割引率のカスタムパーセント項目が 0 ～ 40% の範囲にあることを確認します。
            数式: OR(Discount_Rate__c < 0, Discount_Rate__c > 0.40)
            エラーメッセージ: 割引率は、40% 以内にしてください。
            エラー表示場所: 割引率

            重要商談の承認は完了予定日以前であること

            項目 値
            説明: 50,000 ドル以上の商談でフェーズを [商談成立] または [不成立] に変更するには、[承認済み] というカスタムチェックボックスがオンになっている必要があります。これを自動化するには、[承認済み] チェックボックスに項目レベルセキュリティを設定し、カスタム承認プロセスを介してのみ、チェックボックスをオンにできるようにします (Enterprise Edition、Unlimited Edition、または Performance Edition)。
            数式: 
            AND(
   OR(
      ISPICKVAL(StageName,"Closed Won"),
      ISPICKVAL(StageName,"Closed Lost")),
(Amount > 50000),
NOT(ISPICKVAL(Approval_Status__c ,"Approved")))
            エラーメッセージ: 重要商談はすべて承認されたときにだけクローズできます。[クローズ要求] ボタンをクリックしてください。
            エラー表示場所: ページの最上位

            1000 万ドルを超える商談金額の禁止

            項目 値
            説明: 商談の [金額] が正の数で 1000 万ドル以下であることを確認します。この制限は、入力ミスを防ぐために設けてあります。
            数式: 
            OR(
   Amount < 0,
   Amount > 10000000
)
            エラーメッセージ: 金額は 1000 万ドル以下で指定してください。
            エラー表示場所: 金額

            商談品目のチェック

            項目 値
            説明: ユーザーが商談に対する変更を保存する前に、その商談に商談商品が最低でも 1 つあることを確認します。
            数式: 
            NOT(OR(ISNEW(),HasOpportunityLineItem))
            エラーメッセージ: 保存する前に、この商談に商品を追加してください。
            エラー表示場所: ページの最上位

            「ニーズの把握」フェーズを過ぎた商談に商品を持たせる

            項目 値
            説明: [フェーズ] を「ニーズの把握」以降に進める前に、商談に商談商品があることを確認します。
            数式: 
            AND (
  CASE( StageName,
     "Value Proposition", 1,
     "Id. Decision Makers", 1,
     "Perception Analysis", 1,
     "Proposal/Price Quote", 1,
     "Negotiation/Review", 1,
     "Closed Won", 1,
     0) = 1,
  NOT(HasOpportunityLineItem)
)
            エラーメッセージ: 「ニーズの把握」フェーズ以降に進むには、商談商品が必要です。
            エラー表示場所: ページの最上位

            商談名の形式

            項目 値
            説明: 「[取引先] – [金額]」の形式での商談の命名規則を徹底するために、商談にハイフンが含まれていることを確認します。
            数式: 
            FIND( " - ", Name ) = 0
            エラーメッセージ: 商談名は「[取引先] – [金額]」の形式で指定してください。
            エラー表示場所: 商談名

            営業担当による商談フェーズの後退の禁止

            項目 値
            説明: カスタム承認プロセスを介して商談を受け付けた後に、営業担当が商談 [フェーズ] を「後退」させることを防ぎます。承認プロセスでは、カスタム [承諾フラグ] チェックボックスが「True」に設定されます。
            数式: 
            AND(
   Accepted_Flag__c,
   OR ( ISPICKVAL( StageName, "Stage 1"), ISPICKVAL( StageName, "Stage 2"))
)
            エラーメッセージ: 受け付けた商談には指定できないフェーズです。
            エラー表示場所: フェーズ

            成立商談の確度が 100% であること

            項目 値
            説明: 成立商談の確度が正しく 100% に設定されていることを確認します。この機能は、データを正確に保ち、レポートを作成するのに便利です。
            数式: 
            AND (
     ISPICKVAL( StageName, "Closed Won"),
     Probability <> 1)
            エラーメッセージ: 成立商談の確度には 100% を指定してください。
            エラー表示場所: 確度

            不成立の商談の確度が 0% であること

            項目 値
            説明: 不成立商談の確度が正しく 0% に設定されていることを確認します。この機能は、データを正確に保ち、レポートを作成するのに便利です。
            数式: 
            AND (
     ISPICKVAL( StageName, "Closed Lost"),
     Probability <> 0)
            エラーメッセージ: 不成立商談の確度には 0% を指定してください。
            エラー表示場所: 確度

            プロジェクト開始日

            項目 値
            説明: ある項目の値によって別の項目が入力必須項目になる場合に、その条件を満たしていることを確認します。この入力規則数式を使用して、成立した商談には [プロジェクト開始日] を必ず入力するようにします。
            数式: 
            AND(ISPICKVAL(StageName, "Closed Won"),
  ISNULL(Project_Start_Date__c))
            エラーメッセージ: 成立した商談には、[プロジェクト開始日] が必須です。
            エラー表示場所: プロジェクト開始日
             
            読み込み中
            Salesforce Help | Article