Loading
コードではなくてクリックによる Salesforce の拡張
目次
絞り込み条件 (0)追加
絞り込み条件を選択

          結果がありません
          結果がありません
          検索のヒントをいくつかご紹介します

          キーワードの入力ミスがないか確認する。
          より一般的な検索語を使用する。
          絞り込み条件を減らして、検索範囲を広げる。

            Salesforce ヘルプ全体を検索
            Salesforce ヘルプ全体を検索
            ユーザー、ロール、およびプロファイル入力規則の例

            詳細情報:

            1. Salesforce ヘルプ
            2. ドキュメント
            3. コードではなくてクリックによる Salesforce の拡張

            ユーザー、ロール、およびプロファイル入力規則の例

            カスタムユーザー、ロール、プロファイル項目を検証する方法の例。

            必要なエディション

            使用可能なインターフェース: Salesforce Classic および Lightning Experience の両方
            使用可能なエディション: Contact Manager Edition、Group Edition、Professional Edition、Enterprise Edition、Performance Edition、Unlimited Edition、Developer Edition、および Database.com Edition

            これらの例で使用する数式関数についての詳細は、「数式の演算子と関数」を参照してください。

            ロールに基づく割引率の制限

            項目 値
            説明: 商談の [割引率] というカスタム項目が、ユーザーのロールごとに異なる最大値を超えていないことを確認します。デフォルトの最大値は 15% です。
            数式: 
            Discount_Percent__c > VLOOKUP(
    $ObjectType.Role_Limits__c.Fields.Limit__c,
    $ObjectType.Role_Limits__c.Fields.Name, 
    $UserRole.Name
)
            エラーメッセージ: 割引率 (%) がロールに許可された制限を超えています。
            エラー表示場所: 割引率

            ユーザーの最大許容経費による経費の金額の制限

            項目 値
            説明: [経費金額] というカスタム項目を [最大許容支出] というカスタムユーザー項目に照らし合わせて確認します。
            数式: 
            Expense_Amount__c > $User.Max_Allowed_Expense__c
            エラーメッセージ: 最大許容経費を超えた金額は指定できません。
            エラー表示場所: 経費金額

            レコード所有者のみが項目を変更できるようにする

            項目 値
            説明: [個人目標] というカスタム項目をそのレコード所有者のみが変更できるようにします。
            数式: 
            AND(
   ISCHANGED( Personal_Goal__c ),
   Owner <> $User.Id 
)
            エラーメッセージ: [個人目標] を変更できるのは所有者のみです。
            エラー表示場所: 個人目標

            レコード所有者または管理者のみが項目を変更できるようにする

            項目 値
            説明: [個人目標] というカスタム項目は、ユーザーがそのレコード所有者であるか、「カスタム: システム管理者」のカスタムプロファイルを持つ場合にのみ変更できるようにします。
            数式: 
            AND(
    ISCHANGED( Personal_Goal__c ), 
    Owner <> $User.Id, 
    $Profile.Name <> "Custom: System Admin" 
)

            $Profile 差し込み項目は、Enterprise Edition、Unlimited Edition、Performance Edition、および Developer Edition でのみ使用可能です。
            エラーメッセージ: [個人目標] を変更できるのは所有者またはシステム管理者のみです。
            エラー表示場所: 個人目標

            管理者のみが商談完了日を過去の日付に変更できるようにする

            項目 値
            説明: 「カスタム: システム管理者」のカスタムプロファイルを持つユーザーを除き、商談の [完了予定日] が現在の月よりも前になっていないことを確認します。
            数式: 
            AND(
  OR (
     ISNEW(), 
     ISCHANGED( CloseDate )), 
  CloseDate < DATE( YEAR(TODAY()), MONTH(TODAY()), 1),
   $Profile.Name <> "Custom: System Admin"
)

            $Profile 差し込み項目は、Enterprise Edition、Unlimited Edition、Performance Edition、および Developer Edition でのみ使用可能です。
            エラーメッセージ: 完了予定日には今月以降の月を指定してください。
            エラー表示場所: 完了予定日
             
            読み込み中
            Salesforce Help | Article